erstellt am: 23. Okt. 2005 14:48 Unities abgeben:
Hallo
Welches hast du dir runtergeholt?
Ich habe irgendwann nochmal die Beziehungen korrigiert.
Bei mir klappts mit deinen Werten.
Hier die aktuellen Beziehungen:/* VERSCHIEDENE GRUNDWERTE
ALPHA_EINGRIFF=ALFA
ALFA_T=ATAN((TAN(ALPHA_EINGRIFF))/(COS(BETA)))
IA=INNEN_AUSSEN
EVOLVENTEN_ERZEUGUNGS_WINKEL=45
KOPFSPIEL=0.25*MODUL
TEILKREIS_TEILUNG=MODUL*PI
TEILKREIS_DURCHM=(MODUL*ANZAHL_ZAEHNE/(COS(BETA)))
WKD=TEILKREIS_DURCHM+(X*MODUL*2)
FUSSKREIS_DURCHM=WKD-(2*(MODUL+KOPFSPIEL)*IA)
KOPFKREIS_DURCHM=WKD+(2*MODUL*IA)
GRUNDKREIS_DURCHM=TEILKREIS_DURCHM*COS(ALFA_T)
/*ZENTRIWINKEL AM TEILKREIS, NOTWENDIG FÜR DIE LÜCKENWEITE
WINKEL_HALFTE_ZAHN=(((PI-(4*X*(IA)*TAN(ALPHA_EINGRIFF)))/(2*ANZAHL_ZAEHNE)))*(\
180/PI)
/*ZUUWEISUNGEN
D0=GRUNDKREIS_DURCHM
D3=TEILKREIS_DURCHM
D7=WINKEL_HALFTE_ZAHN
D200=360/ANZAHL_ZAEHNE
P201=ANZAHL_ZAEHNE
D173=ZAHNBREITE
DKM=RD2-MESSKUGEL_DM
/*INNENVERZAHNUNG
IF INNEN_AUSSEN==-1
D178=KOPFKREIS_DURCHM
D176=D178+10*MODUL
D2=FUSSKREIS_DURCHM
D1=KOPFKREIS_DURCHM
ELSE
/*AUSSENVERZAHNUNG
D1=FUSSKREIS_DURCHM
D2=KOPFKREIS_DURCHM
D176=KOPFKREIS_DURCHM
D178=D176-10*MODUL
ENDIF
D184=TEILKREIS_DURCHM
/*FUSSRUNDUNG
FUSSRUNDUNG=0.38*MODUL
IF INNEN_AUSSEN==1
IF FUSSRUNDUNG>D367 /*DANN KOMMT VOLLRUNDUNG ZUR ANWENDUNG
D366=D367-0.01*MODUL
FUSSRUNDUNG = D366
ELSE
D366=FUSSRUNDUNG
ENDIF
ENDIF
IF INNEN_AUSSEN==-1
IF FUSSRUNDUNG>D367 /*DANN KOMMT VOLLRUNDUNG ZUR ANWENDUNG
D369=D367-0.01*MODUL
FUSSRUNDUNG=D369
ELSE
D369=FUSSRUNDUNG
ENDIF
ENDIF
/*MESSUNGEN, NUR ZUR KONTROLLE, WERDEN EIGENTLICH NICHT GEBRAUCHT
IF MESSKUGEL_DM>1.9*MODUL
MESSKUGEL_DM=2*MODUL /* NUR ZUR SICHERHEIT. ICH WEISS ES GEHT AUCH ANDERS
ENDIF
D362=MESSKUGEL_DM
D384=360/ANZAHL_ZAEHNE*(FLOOR(ANZAHL_ZAEHNE/2))
D340=MESSKUGEL_DM/2
D341=MESSKUGEL_DM/2
IF INNEN_AUSSEN==1
DKM=RD2+MESSKUGEL_DM
ELSE
DKM=RD2-MESSKUGEL_DM
ENDIF
Sieh mal nach, ob die identisch mit den deinen sind.
Überhaupt, sind die zwei letzten uploads von mir schon wieder mal vertauscht worden und gehören gar nicht zu diesem Beitrag.
Gruß
Olaf
------------------