---

Hallo!

Ich versuche schon seit Tagen mit einem Makro eine Aufmassfläche zu erstellen! Wenn ich über "Makor Aufzeichnen" an die Befehle kommen will, wird beim Tool "Aufmaßfläche" überhaupt nichts aufgezeichnet. Welche Befehle muß ich benutzen? Hat jemand ein Beispiel-Makro?

------------------
Karin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Karin,
nimm das Makro von Jasiu aus dem Beitrag: http://ww3.cad.de/foren/ubb/Forum137/HTML/000321.shtml
Es wird hierbei eine Offset-Fläche auf eine bestehende Fläche mit dem Namen im Strukturbaum "Fläche.1" erstellt.

Hier nochmal ein korrigierte Version (läuft als CATScript unter R9SP4):

Sub CATMain()

Dim partDocument1 As PartDocument
Set partDocument1 = CATIA.ActiveDocument

Dim part1 As Part
Set part1 = partDocument1.Part

Dim hybridBodies1 As HybridBodies
Set hybridBodies1 = part1.HybridBodies

Dim hybridBody1 As HybridBody
Set hybridBody1 = hybridBodies1.Item("Geöffneter Körper.1")

Dim hybridShapes1 As HybridShapes
Set hybridShapes1 = hybridBody1.HybridShapes

Dim hybridShapeSplit1 As HybridShapeSplit
Set hybridShapeSplit1 = hybridShapes1.Item("Fläche.1")

Dim reference1 As Reference
Set reference1 = part1.CreateReferenceFromObject(hybridShapeSplit1)

Dim hybridShapeFactory1 As HybridShapeFactory
Set hybridShapeFactory1 = part1.HybridShapeFactory

Dim hybridShapeOffset1 As HybridShapeOffset
Set hybridShapeOffset1 = hybridShapeFactory1.AddNewOffset(reference1, 20, True, 0.01)

hybridBody1.AppendHybridShape hybridShapeOffset1

part1.InWorkObject = hybridShapeOffset1

part1.Update

End Sub

schöne grüße

Jens Hansen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke Jens!

Ich brauche allerdings keine Offset-Fläche sondern eine Aufmassfläche. Bei einer Offset-Fläche habe ich einfach eine zweite Fläche erzeugt, mit einer Aufmassfläche habe ich hinterher aber ein Solid, und genau den brauche ich. Aber trotzdem vielen Dank!

------------------
Karin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hallo Karin,
das selbe Problem habe ich auch (noch) -> siehe http://ww3.cad.de/foren/ubb/Forum137/HTML/000321.shtml

Wenn du es rausbekommst, lass es mich bitte wissen, wie !!

Danke

Jens Hansen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe gerade die Antwort bekommen, dass die Makroaufzeichnung "noch nicht ausgereift" ist und nur einfache Funktionen benutzt werden können...

------------------
Karin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Karin,
ich habe heute das Buch vom Hanser-Verlag über Makroprogrammierung in V5 bekommen. Dort steht genau dieses Problem drin. Hier das Script aus dem Buch:
Quelle: Hanser-Verlag; Effiziente Konstruktion mt Makros
Link zum Buch über die Hilfeseite (http://catia.cad.de/index1.htm)

' Makro:            Hanser-Verlag; Effiziente Konstruktion mit Makros
' Version:                1.0
' Code:                CATIA CATScript
' Zweck:                Beispiel für die Erzeugung eines Aufmaßkörpers
' Vorbereitung:        CATPart gemäß Beispiel 6.4
' Autor:                Dieter Ziethen

Sub CATMain ()

' Hauptkörper deklarieren und in Bearbeitung setzen ----------------
Dim Bauteil As Part
Set Bauteil = CATIA.ActiveDocument.Part
Dim HKoerper As Body
Set HKoerper = Bauteil.MainBody
Bauteil.InWorkObject = HKoerper

' Fläche deklarieren -----------------------------------------------
Dim HB As HybridBody
Set HB = Bauteil.HybridBodies.Item(1)
Dim Flaeche As AnyObject
Set Flaeche = HB.HybridShapes.Item("Fläche.1")
Dim Ref As Reference
Set Ref = Bauteil.CreateReferenceFromObject (Flaeche)

' Werkzeugkasten deklarieren ---------------------------------------
Dim Wzk3D As ShapeFactory
Set Wzk3D = Bauteil.ShapeFactory

' Aufmaßfläche erzeugen --------------------------------------------
Dim Thick As ThickSurface
Set Thick = Wzk3D.AddNewThickSurface (Ref, 1, 5, 5)

Bauteil.Update

End Sub

Schöne Grüße

Jens Hansen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Jens!

Danke für den Tipp, ich hab's ausprobiert, funktioniert aber leider nicht, da ich in der Produktumgebung arbeite, irgendwas stimmt da nicht. Inzwischen habe ich das Problem aber anders gelößt, ich habe erst einen geschlossenen Körper erzeugt und den dann ausgehölt. Das geht so:

'--Trichter fuellen--
'-Wichtig: Hauptkörper muss in Bearbeitung sein!-
part1.InWorkObject = body1
Set referenceVerbindung = part1.CreateReferenceFromObject(Verbindung)
Set closeSurface1 = shapeFactory1.AddNewCloseSurface(referenceVerbindung)
part1.Update

'--Schalenenlement--
Set referenceName = part1.CreateReferenceFromName("")
Set shell1 = shapeFactory1.AddNewShell(referenceName, Blechdicke, 0.000000)

Set referenceFace1 = part1.CreateReferenceFromBRepName("RSur Face Brp CloseSurface.1;(Brp GSMExtrude.1;1 Brp GSMCircle.1)));Brp GSMExtrude.2;1 Brp GSMCircle.2)))));None ));WithTemporaryBody;W ithoutBuildError;WithSelectingFeatureSupport)", closeSurface1)

Set referenceFace2 = part1.CreateReferenceFromBRepName("RSur Face Brp CloseSurface.1;(Brp GSMExtrude.3;1 Brp GSMCircle.3)));Brp GSMExtrude.4;1 Brp GSMCircle.4)))));None ));WithTemporaryBody;W ithoutBuildError;WithSelectingFeatureSupport)", closeSurface1)

shell1.AddFaceToRemove referenceFace1
shell1.AddFaceToRemove referenceFace2
part1.Update

------------------
Karin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Karin,
für die produktumgebung kannst du folgendes am Anfang eintrag / ersetzen:

Sub CATMain()

Dim documents1 As Documents
Set documents1 = CATIA.Documents

Dim partDocument1 As Document
Set partDocument1 = documents1.Item("Part1.CATPart")

Dim Bauteil As Part
Set Bauteil = partDocument1.Part
Dim HKoerper As Body
Set HKoerper = Bauteil.MainBody
Bauteil.InWorkObject = HKoerper
.
.
.
.
.

Schöne Grüße

Jens Hansen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP