---

Ich vermisse die Drag & Drop Funktionalität für Zeichnungselemente für IV11 und IV 2008.
Speziell geht es um eine ausgefüllte und gestaltete Inventor Tabelle (kein Excel OLE Objekt) ohne Tabellenbezug, welche ich auf eine andere Zeichnung übernehmen möchte (lediglich ein Eintrag muss verändert werden).
Der Export/Import via Exceltabelle stellt mich dafür nicht zufrieden.
Hab ich was übersehen?

------------------
Mit freundlichem Gruß

Udo Hübner

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

      

Zitat:

---

Original erstellt von CAD-Huebner:
... Hab ich was übersehen? ...

---

Nein, Udo, du hast da nichts übersehen. Eine Tabellen-Objekt kann weder auf ein anderes Blatt verschoben, noch über die Zwischenablage kopiert werden. Nur wenn man das ganze Blatt oder das ganze Dokument kopiert, kommt die Tabelle mit.

Warum das so ist? Keine Ahnung. Wahrscheinlich hat die Projektleitung "Abgeben!" gerufen und der Entwickler war noch nicht ganz fertig.  

Genauso verstehe ich nicht, warum man ein Blatt nicht innerhalb des selben Dokumentes kopieren kann, sondern den Umweg über ein temporäres zweites Dokument wählen muss.

  

Zitat:

---

Original erstellt von CAD-Huebner:
... Der Export/Import via Exceltabelle stellt mich dafür nicht zufrieden. ...

---

Etwas besser als der Weg über Excel ist das Kopieren des Tabelleninhaltes über die Zwischenablage. Hierzu die Tabelle bearbeiten, die gesamte Tabelle markieren (obere linke Ecke des Grids anklicken) und mit STRG C kopieren (im Kontextmenü steht es nicht drin). Auf dem neuen Blatt eine Tabelle mit der selben Größe anlegen, bearbeiten, die erste Zelle oben links anklicken und STRG V.

Formatierung abweichend vom Stil? Pech gehabt!  

------------------
Michael Puschner
Autodesk Inventor Certified Expert
Scholle und Partner GmbH

 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

das Makro kopiert die selektierte Tabelle von einem Blatt auf das andere. Wenn ich ein wenig mehr Zeit habe, schreibe ich ein AddIn dafür, und gestallte es ein wenig komfortabler mit einer Benutzeroberfläche.

Code:

---

Sub FX64CopyCustomTable()
    Dim oDrawing As DrawingDocument
    Set oDrawing = ThisApplication.ActiveDocument
       
    Dim oSheet As Sheet
    Set oSheet = oDrawing.ActiveSheet

    ' ######### Selektierte Tabelle holen ##########
    Dim oTable As CustomTable
    On Error Resume Next
    Set oTable = oDrawing.SelectSet(1)
    If Err.Number <> 0 Then
        MsgBox "Bitte zuerst eine Tabelle selektieren", vbOKCancel, "Keine Selektion"
        Exit Sub
    End If
   
    Dim i As Integer
    Dim j As Integer
   
    ' ######### Spaltenbezeichnungen ###############
    Dim sColumnTitles() As String
    ReDim Preserve sColumnTitles(oTable.Columns.Count - 1)

    For i = 0 To oTable.Columns.Count - 1
        sColumnTitles(i) = oTable.Columns(i + 1).Title
    Next
   
    ' ######### Tabelleninhalt #####################
    Dim sContents() As String
    ReDim Preserve sContents((oTable.Rows.Count * oTable.Rows(1).Count) - 1)
   
    For i = 1 To oTable.Rows.Count
        For j = 0 To oTable.Rows(i).Count - 1
            sContents(((i - 1) * oTable.Columns.Count) + j) = oTable.Rows(i).Item(j + 1).Value
        Next
    Next
       
    ' ######### Spaltenbreite ######################
    Dim dColumnWidths() As Double
    ReDim Preserve dColumnWidths(oTable.Columns.Count - 1)
   
    For i = 0 To oTable.Columns.Count - 1
        dColumnWidths(i) = oTable.Columns(i + 1).Width
    Next
   
    ' ######### Zeilenhöhe #########################
    Dim dRowHeights() As Double
    ReDim Preserve dRowHeights(oTable.Rows.Count - 1)
   
    For i = 0 To oTable.Rows.Count - 1
        dRowHeights(i) = oTable.Rows(i + 1).height
    Next
   
    ' ######### Auf Blatt2 wechseln ################
    Dim oSheet2 As Sheet
    Set oSheet2 = oDrawing.Sheets(2)    ' <--- Hier die Zahl für das Zielblatt einfügen
    oSheet2.Activate                    ' Für Blatt 3 z.B. Set oSheet2 = oDrawing.Sheets(3)
   
    ' ######### Die neue Tabelle einfügen ##########
    Call oSheet2.CustomTables.Add(oTable.Title, _
                                    oTable.Position, _
                                    oTable.Columns.Count, _
                                    oTable.Rows.Count, _
                                    sColumnTitles, _
                                    sContents, _
                                    dColumnWidths, _
                                    dRowHeights)
    If Err.Number <> 0 Then
        MsgBox Err.Description, vbOKCancel, "Fehler"
    End If
End Sub

---

------------------
Grüße Igor

FX64 Software Solutions

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Igor,

Habe deine Makro eingesetzt, bekomme aber die Meldung "Die Methode 'Add' für das Objekt '_IRCustomTables' ist fehlgeschlagen'

Weist du vielleicht an was dass liegen kann?

------------------
Gruß Christian

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Christian,

die Funktion git es erst seit IV 2008.

------------------
Grüße Igor

FX64 Software Solutions

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Igor,

Danke dir für die Schnelle Antwort

------------------
Gruß Christian

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP