---

hallo,
hab ein problem und natürlich eine frage, die sich daraus ergibt. für ein projekt an der uni verwende ich die topologieoptimierung von ansys. es handelt sich dabei um einen relativ einfachen solid. sämtliche bedingungen sind eingegeben und auch die optimierung ist schon gerechnet, allerdings versuche ist nun schon seit tagen, mir den optimierten zustand als geometrie und nicht als density - plot  anzeigen zu lassen.
also die frage ist, ob es möglich ist, nur die optimierte geometrie darzustellen , und diese dann zu exportieren um daran weiterzuarbeiten.
leider konnte ich in der documentation nichts finden und auch sonst konnte mir keiner weiterhelfen.
danke im voraus,
chris

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Das Ergebnis der Optimierung ist eine Hilfe für den Konstrukteur bei der Konstruktion. Die gesuchte Exportmöglichkeit gibt es nicht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

in Linie mit wosch's Hinweis siehe auch
http://ww3.cad.de/foren/ubb/Forum101/HTML/000348.shtml#000001
dritter Beitrag.

------------------
Gruesse,
Frank Exius

IFE Deutschland  www.ife-ansys.de 
Telefon +49 (0)2642 980409  Mo-Fr 9:00-18:00 Uhr durchgaengig 
Dienstleistung in ANSYS  Simulation Berechnung - Digital Prototyping

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Mir wäre dazu eingefallen (aber ist ja eh schon mal irgendwo in Forum beschrieben):
Elemente mit Dichte selektieren, in Prep7 Oberfläche vernetzen, Oberflächenelmente in Dreiecksflächen umwandeln, Geo mergen und als Iges exportieren - das dann als Konsturktionshilfe im CAD drüberlegen.

Schade, dass das nicht besser geht. Andererseits gut, dann gibts Abeitsplätze am CAD. 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hallo,
hatte mir schon gedacht, daß das nicht so einfach werden würde. tja, kann man nichts machen, trotzdem danke für die antworten.

grüße,
chris

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hi chris,

vielleicht hast du an deiner hochschule zugang zu weiterentwickelten optimierern als in ansys wie msc.construct oder tosca. dort ist eine glättung der topologie mit anschliessendem export möglich. die ergebnisse sind dann durchaus brauchbar für neuvernetzung, berechnung, anpassung der volumenreduktion hinsichtlich max. spannungen etc.

ansonsten hatte ich mit ansys mal dasselbe prob wie beschrieben, wenn du dir folgenden "code" für deinen etype anpasst, kannst du zumindest eine "gewürfelte" topologie nach .stl exportieren.

viel erfolg.

Gruss, Meijer

---schnipp---

Below is a script I use to output STL files of deformed geometries.  Many CAD packages support the import of STL files.  However, this script assumes you have a solid model (SOLID185, SOLID186, and/or SOLID187). It uses UPGEOM to update the geometry, then covers the exterior with some MESH200 area elements.  It uses these to extract the facets for the STL file. The script can probably be modified for use with your model, though I have no idea if STL supports line entities.

================================================

/NOPR

/PREP7
ALLSEL
*DIM,jobname,STRING,256,1
/INQUIRE,jobname,JOBNAME
UPGEOM,,,,%jobname(1,1)%,rst
*GET,maximumElementType,ETYP,,NUM,MAX
stlElementType = maximumElementType+1
ET,stlElementType,MESH200
KEYOPT,stlElementType,1,6
ESEL,S,STIF,,185,187
NSEL,S,EXT
TYPE,stlElementType
ESURF

ESEL,S,TYPE,,stlElementType
NSLE
*GET,numberOfElements,ELEM,,COUNT
*DIM,nodeNumbers,ARRAY,4
*DIM,facetConnectivity,ARRAY,(2*numberOfElements),3
elementNumber = 0
numberOfFacets = 0
*DO,i,1,numberOfElements,1
elementNumber = ELNEXT(elementNumber)
*DO,j,1,4,1
nodeNumbers(j) = NELEM(elementNumber,j)
*ENDDO
numberOfFacets = numberOfFacets+1
facetConnectivity(numberOfFacets,1) = nodeNumbers(1)
facetConnectivity(numberOfFacets,2) = nodeNumbers(2)
facetConnectivity(numberOfFacets,3) = nodeNumbers(3)
*IF,nodeNumbers(4),NE,nodeNumbers(3),THEN
numberOfFacets = numberOfFacets+1
facetConnectivity(numberOfFacets,1) = nodeNumbers(1)
facetConnectivity(numberOfFacets,2) = nodeNumbers(3)
facetConnectivity(numberOfFacets,3) = nodeNumbers(4)
*ENDIF
*ENDDO

*CFOPEN,deformed,stl
*VWRITE
solid DEFORMED
*DO,i,1,numberOfFacets,1
n1 = facetConnectivity(i,1)
n2 = facetConnectivity(i,2)
n3 = facetConnectivity(i,3)
normX = NORMNX(n1,n2,n3)
normY = NORMNY(n1,n2,n3)
normZ = NORMNZ(n1,n2,n3)
*VWRITE,normX,normY,normZ
facet normal  %16.9e  %16.9e  %16.9e
*VWRITE
outer loop
*DO,j,1,3,1
n1 = facetConnectivity(i,j)
*VWRITE,NX(n1),NY(n1),NZ(n1)
vertex  %16.9e  %16.9e  %16.9e
*ENDDO
*VWRITE
endloop
*VWRITE
endfacet
*ENDDO
*VWRITE
endsolid DEFORMED
*CFCLOS
/GOPR

---schnipp---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

vielen dank, das hilft mir schon sehr weiter. die ungefähre ausgabe der optimierten geometrie reicht mir eigentlich auch fürs erste.
wir hätten an der uni noch msc patran, damit kann man wohl - hab ich mir sagen lassen - ebenfalls optimierungen durchführen. werde aber erst mal bei ansys bleiben.

vielen dank nochmal,
chris

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP