---

Hallo liebe Community,

ich habe es bereits geschafft über Excel-VBA, Inventor zu öffnen und die richtige Projektdatei zu aktivieren. Nun habe ich Schwierigkeiten, eine Baugruppe, auch über VBA in dem bereits geöffneten Inventor zu öffnen.

Der vorhandene Code lautet wie folgt aus:

        Dim strProgramName As String
        Dim strArgument As String
        Dim strArgument2 As String
       
        strProgramName = "C:\Program Files\Autodesk\Inventor 2022\Bin\Inventor.exe"
        strArgument = " /pf"
        strArgument2 = "C:\Konfigurator\Personenschutztor\Personenschutztor.ipj"
       
        Call Shell("""" & strProgramName & """" & strArgument & """" & strArgument2 & """", vbNormalFocus)

Könnt Ihr mir diesbezüglich helfen?

MfG
Olaf D

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Willkommen im Forum   

Du kannst deinen Shellaufruf zwar nutzen, musst dann aber in einer Warteschleife drehen bis Inventor gestartet ist und die laufende Instanz suchen. Alternative direkt aus Excel heraus eine Inventorinstanz erzeugen, Projektdatei einstellen und ein Baugruppendokument als zugreifbares Objekt in einer Variable zurückbekommen:

Code:

---

Dim invApp As Inventor.Application

'Open the Inventor Application
On Error Resume Next
Set invApp = GetObject(, "Inventor.Application") '<-- Get the Inventor Application if it's already open

If Err Then
    Set invApp = CreateObject("Inventor.Application") '<-- Create the Inventor Application if it's NOT open
    invApp.Visible = True
    Set invApp = GetObject(, "Inventor.Application") '<-- Activate the Inventor Application after it's open
End If

'Close any open documents
If invApp.Documents.Count > 0 Then
    invApp.Documents.CloseAll
End If

Dim oDesignProjectMgr As DesignProjectManager
Set oDesignProjectMgr = invApp.DesignProjectManager

' Get the project to activate
' This assumes that "C:\Temp\MyProject.ipj" exists.
Dim oProject As DesignProject
Set oProject = oDesignProjectMgr.DesignProjects.ItemByName("C:\temp\MyProject.ipj")

' Activate the project
oProject.Activate

Dim oAssDoc as AssemblyDocument
Set oAssDoc = invApp.Documents.Open("FullDocumentName", True)

---

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hey rkauskh,

vielen Dank für deine Antwort. Nach ein paar kleinen Anpassungen hat alles funktioniert.

Gruß

Olaf D 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP