---

Ich exportiere regelmäßig Dateien und dann immer als Step. Die Voreinstellung bei "Exportieren -  CAD-Format" ist aber dwg (glaub ich - wenn ich die Teile nacheinander öffne, dann merkt er sich das zuletzt genutzte, aber meistens öffne ich sie geichzeitig und muss dann jedes mal umstellen). Kann man das allgemein umstellen, dass die Voreinstellung step ist?
Danke!
Tabita

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,
da gibt es hier im Forum bestimmt jemanden der ein VBA Schnipsel hat, welches man dann unter den Benutzerbefehlen ablegen kann.
Gruß
Burkhard

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von TLipo:
Ich exportiere regelmäßig Dateien und dann immer als Step. Die Voreinstellung bei "Exportieren -  CAD-Format" ist aber dwg (glaub ich - wenn ich die Teile nacheinander öffne, dann merkt er sich das zuletzt genutzte, aber meistens öffne ich sie geichzeitig und muss dann jedes mal umstellen). Kann man das allgemein umstellen, dass die Voreinstellung step ist?
Danke!
Tabita

---

Komisch, habs jetzt schon länger nicht mehr gemacht, aber aus der Erinnerung gesagt geht das doch einfach "Datei/Kopie speichern unter/1x Format auswählen/enter und fertig.
Das gewählte Dateiformat bleibt erhalten, der Ablageort leider nicht.
Wenn man mehrere Dateien gleichzeitig offen hat und eine nach der anderen exportieren will, braucht man nach dem ersten Exportvorgang nur per Alt+Tab auf die nächste Datei springen und Enter (oder Leertaste) drücke für Befehlswiederholung.

------------------
mfg - Leo

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Code:

---

Public Sub ExportToSTEP()
    ' Get the STEP translator Add-In.
    Dim oSTEPTranslator As TranslatorAddIn
    Set oSTEPTranslator = ThisApplication.ApplicationAddIns.ItemById("{90AF7F40-0C01-11D5-8E83-0010B541CD80}")

    If oSTEPTranslator Is Nothing Then
        MsgBox "Could not access STEP translator."
        Exit Sub
    End If

    Dim oContext As TranslationContext
    Set oContext = ThisApplication.TransientObjects.CreateTranslationContext
    Dim oOptions As NameValueMap
    Set oOptions = ThisApplication.TransientObjects.CreateNameValueMap
   
    Dim oDoc As Inventor.Document
    Set oDoc = ThisApplication.ActiveDocument
   
    If oSTEPTranslator.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then
        ' Set application protocol.
        ' 2 = AP 203 - Configuration Controlled Design
        ' 3 = AP 214 - Automotive Design
        oOptions.Value("ApplicationProtocolType") = 3

        ' Other options...
        'oOptions.Value("Author") = Application.UserName
        'oOptions.Value("Authorization") = ""
        'oOptions.Value("Description") = ""
        'oOptions.Value("Organization") = ""

        oContext.Type = kFileBrowseIOMechanism

        Dim oData As DataMedium
        Set oData = ThisApplication.TransientObjects.CreateDataMedium
       
        Dim sExportFullFileName As String
        Dim sRev As String
       
        Select Case oDoc.DocumentType
        Case Is = kPartDocumentObject
            If oDoc.ComponentDefinition.IsiPartFactory Then
                'MsgBox "iPart-Factory - gehe durch die Instanzen ..."
               
                Dim oFactoryDoc As PartDocument
                Set oFactoryDoc = oDoc
               
                ' Set a reference to the component definition.
                Dim oCompDef As PartComponentDefinition
                Set oCompDef = oFactoryDoc.ComponentDefinition
               
                ' Set a reference to the factory.
                Dim oFactory  As iPartFactory
                Set oFactory = oFactoryDoc.ComponentDefinition.iPartFactory
               
                ' Get the number of rows in the factory.
                Dim iNumRows As Integer
                iNumRows = oFactory.TableRows.Count
   
                'MsgBox "Anzahl Varianten: " & CStr(iNumRows)
               
                ' Iterate through the rows
                Dim oRow As iPartTableRow
                Dim i As Long
                For Each oRow In oFactory.TableRows
                    i = i + 1
                    If InStr(1, oRow.PartName, "drw", vbTextCompare) = 0 Then
                        ' Make this the active row so the model will recompute.
                        oFactory.DefaultRow = oRow
                        sRev = Property_lesen(oDoc, "Revision Number")
                        If sRev = "" Then sRev = "0"
                       
                        sMsg = "Variante : " & oRow.Index & vbCrLf & _
                              "Dateiname: " & oRow.PartName & vbCrLf & _
                              "Revision : [" & sRev & "]" & vbCrLf & _
                            "."
                        MsgBox sMsg
                        Debug.Print sMsg
                        oData.FileName = CalcMemberFileName(oDoc, oRow.PartName) & ".stp"
                        Call oSTEPTranslator.SaveCopyAs(oDoc, oContext, oOptions, oData)
                       
                    End If
                Next
            Else 'no Factory
                oData.FileName = CalcFileName(oDoc) & ".stp"
                Call oSTEPTranslator.SaveCopyAs(oDoc, oContext, oOptions, oData)
            End If
        Case Is = kAssemblyDocumentObject
               
            If oDoc.ComponentDefinition.IsiAssemblyFactory Then
                MsgBox "Factory - nur aktive Variante wird exportiert ..."
               
                oData.FileName = CalcFileName(oDoc) & ".stp"
                Call oSTEPTranslator.SaveCopyAs(oDoc, oContext, oOptions, oData)
           
            Else 'no Factory
                oData.FileName = CalcFileName(oDoc) & ".stp"
                Call oSTEPTranslator.SaveCopyAs(oDoc, oContext, oOptions, oData)
            End If
       
        End Select
    End If
End Sub

---

HTH

------------------
mit freundlichem Gruß
aus der Burggemeinde Brüggen
Lothar Boekels

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

@Lothar
da fehlen noch diese Subs/Functions:

• Property_lesen
  
• CalcFileName
  
• CalcMemberFileName

Danke fürs Teilen!

------------------
Gruß KraBBy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke für die zwei Ideen! Beim VBA schließ ich mich KraBBy an. Und dann guck ich mal, dass ich ein bisschen mehr bei VBA durchsteige...

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Da rächt sich, dass ich nun doch eher ein Selfmade-Coder bin.
Ich such die mal zusammen.

------------------
mit freundlichem Gruß
aus der Burggemeinde Brüggen
Lothar Boekels

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Code:

---

Public Function Property_lesen(oDoc As Document, sPropName As String) As Variant
' Liest eine Property.
' Ist die Property nicht vorhanden, so wird "" zurückgegeben.

    Property_lesen = ""

If oDoc Is Nothing Then Return

    ' Obtain the PropertySets collection object
    Dim oPropSets As PropertySets
    Set oPropSets = oDoc.PropertySets

    Dim oProp As Property
   
    ' Iterate through all the PropertySets one by one using for loop
    Dim oPropSet As PropertySet
    For Each oPropSet In oPropSets
   
        For Each oProp In oPropSet
            'Debug.Print oProp.Name
            If oProp.name = sPropName Then
                Property_lesen = oProp.Value
                Exit For
            End If
        Next
       
    Next

End Function

Private Function CalcFileName(oDoc As Document) As String
        sRev = Property_lesen(oDoc, "Revision Number")
        If sRev = "" Then sRev = "0"
        sTitle = Property_lesen(oDoc, "Title")
        sPath = FilePath(oDoc.FullFileName)
        sFileName = FileName(oDoc.FullFileName)
      ' Debug.Print sPath
        'Debug.Print sFileName
        sExportFullFileName = sExportFullFileName & sPath
        sExportFullFileName = sExportFullFileName & sFileName
        sExportFullFileName = sExportFullFileName & "[" & sRev & "]"
        sExportFullFileName = sExportFullFileName & sTitle
        'sExportFullFileName = sExportFullFileName & ".stp"
        Debug.Print sExportFullFileName
        'Debug.Print FileName
        CalcFileName = sExportFullFileName
End Function
Private Function CalcMemberFileName(oDoc As Document, sMemberName As String) As String
        sRev = Property_lesen(oDoc, "Revision Number")
        If sRev = "" Then sRev = "0"
        sTitle = Property_lesen(oDoc, "Title")
        sPath = FilePath(oDoc.FullFileName)
        sFileName = FileName(sMemberName)
      ' Debug.Print sPath
        'Debug.Print sFileName
        sExportFullFileName = sExportFullFileName & sPath
        sExportFullFileName = sExportFullFileName & sFileName
        sExportFullFileName = sExportFullFileName & "[" & sRev & "]"
        sExportFullFileName = sExportFullFileName & sTitle
        'sExportFullFileName = sExportFullFileName & ".stp"
        Debug.Print sExportFullFileName
        'Debug.Print FileName
        CalcMemberFileName = sExportFullFileName
End Function

---

------------------
mit freundlichem Gruß
aus der Burggemeinde Brüggen
Lothar Boekels

[Diese Nachricht wurde von Lothar Boekels am 19. Mai. 2022 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP