---

Hallo,

ich möchte das alle geöffneten Dateien als STEP abgespeichert werden. Hat einer den passenden Syntax dafür?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

der Code könnte in etwa so aussehen:

VBA:

Code:

---

Public Sub ExportToSTEP()
    Dim Doc As Document
   
    For Each Doc In ThisApplication.Documents
        Doc.Activate
        ' Get the STEP translator Add-In.
        Dim oSTEPTranslator As TranslatorAddIn
        Set oSTEPTranslator = ThisApplication.ApplicationAddIns.ItemById("{90AF7F40-0C01-11D5-8E83-0010B541CD80}")
   
        If oSTEPTranslator Is Nothing Then
            MsgBox "Could not access STEP translator."
            Exit Sub
        End If
   
        Dim oContext As TranslationContext
        Set oContext = ThisApplication.TransientObjects.CreateTranslationContext
        Dim oOptions As NameValueMap
        Set oOptions = ThisApplication.TransientObjects.CreateNameValueMap
        If oSTEPTranslator.HasSaveCopyAsOptions(ThisApplication.ActiveDocument, oContext, oOptions) Then
            ' Set application protocol.
            ' 2 = AP 203 - Configuration Controlled Design
            ' 3 = AP 214 - Automotive Design
            oOptions.Value("ApplicationProtocolType") = 3
   
            ' Other options...
            'oOptions.Value("Author") = ""
            'oOptions.Value("Authorization") = ""
            'oOptions.Value("Description") = ""
            'oOptions.Value("Organization") = ""
   
            oContext.Type = kFileBrowseIOMechanism
                   
            Dim oDoc As Document
            Set oDoc = ThisApplication.ActiveDocument
            Dim strName As String
            Dim strNumber As String
            strName = oDoc.PropertySets.Item("Design Tracking Properties").Item("Description").Value
            strNumber = oDoc.PropertySets.Item("Design Tracking Properties").Item("Part Number").Value
           
            Dim oData As DataMedium
            Set oData = ThisApplication.TransientObjects.CreateDataMedium
            oData.FileName = "D:\" & strNumber & " - " & strName & ".stp"
   
            Call oSTEPTranslator.SaveCopyAs(ThisApplication.ActiveDocument, oContext, oOptions, oData)
        End If
    Next
End Sub

---

iLogic:

Code:

---

Dim Doc As Document

For Each Doc In ThisApplication.Documents
    Doc.Activate
    ' Get the STEP translator Add-In.
    Dim oSTEPTranslator As TranslatorAddIn
    oSTEPTranslator = ThisApplication.ApplicationAddIns.ItemById("{90AF7F40-0C01-11D5-8E83-0010B541CD80}")

    If oSTEPTranslator Is Nothing Then
        MsgBox ("Could not access STEP translator.")
        Exit Sub
    End If

    Dim oContext As TranslationContext
    oContext = ThisApplication.TransientObjects.CreateTranslationContext
    Dim oOptions As NameValueMap
    oOptions = ThisApplication.TransientObjects.CreateNameValueMap
    If oSTEPTranslator.HasSaveCopyAsOptions(ThisApplication.ActiveDocument, oContext, oOptions) Then
        ' Set application protocol.
        ' 2 = AP 203 - Configuration Controlled Design
        ' 3 = AP 214 - Automotive Design
        oOptions.Value("ApplicationProtocolType") = 3

        ' Other options...
        'oOptions.Value("Author") = ""
        'oOptions.Value("Authorization") = ""
        'oOptions.Value("Description") = ""
        'oOptions.Value("Organization") = ""

        oContext.Type = kFileBrowseIOMechanism
               
        Dim oDoc As Document
        oDoc = ThisApplication.ActiveDocument
        Dim strName As String
        Dim strNumber As String
        strName = oDoc.PropertySets.Item("Design Tracking Properties").Item("Description").Value
        strNumber = oDoc.PropertySets.Item("Design Tracking Properties").Item("Part Number").Value
       
        Dim oData As DataMedium
        oData = ThisApplication.TransientObjects.CreateDataMedium
        oData.FileName = "D:\" & strNumber & " - " & strName & ".stp"

        Call oSTEPTranslator.SaveCopyAs(ThisApplication.ActiveDocument, oContext, oOptions, oData)
    End If
Next

---

Alle geöffneten Dokumente werden hier auf "D:\" als STEP abgelegt und bekommen einen Namen in der Form:
[Bauteilnummer] - [Bauteilbezeichnung]

Der Pfad und die Benennung können angepasst werden.
Der Code stammt aus dem Inventor API-Handbuch und wurde nur angepasst, damit er alle geöffneten Dokumente durchläuft.

Achtung: Es sollten natürlich nur Dokumente geöffnet sein, die sich auch als STEP exportieren lassen. Andernfalls wirft der Code einen Fehler.

------------------
Mit Besten Grüßen

Marcel

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP