---

Hallo,

ich mache gerade eine Alu-Konstruktion die über iLogic gesteuert ist.

Nun zu meiner Frage:
"Kann man die Sichtbarkeit der Schweißnähte über iLogic steuern oder nicht, weil ich finde nichts wie ich dies machen könnte."

LG Philip

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

- Inhaltsloser Beitrag -

---

Hallo,

scheint wirklich nicht viel Info darueber zu bestehen wie man Schweiss-definitionen per iLogic manipulieren kann

man kann (von Hand) wohl die Sichtbarkeit der Schweissnaehte aus und einschalten. Das wirkt sich aber dann auf alle Schweissnaehte auf, man kann sie nicht einzeln steuern.

Aber anscheinend gibt es keine moeglichkeit das per iLogic oder VBA zu steuern.

wenn du noch weitersuchen willst, dann such unter den Begriff: "Weldment Component Definition"

Gruss
Ray

------------------
Barbarus hic ego sum, quia non intellegor ulli!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hallo Ray
Genau das ist das schlimme bei der Autodesk in der Richtung Inventor.
Die Entwickler können wirklich was dürfen aber nicht (Budgetplanung  )
Hier die Lösung
*******************************
Sub SuppressBead( _
  wcd As WeldmentComponentDefinition, wbn As BrowserNode)
  Dim name As String
  name = wbn.BrowserNodeDefinition.Label

  ' If the bead is already suppressed then its BeadFaces will be 0
  If wcd.Welds.WeldBeads(name).BeadFaces.count = 0 Then Exit Sub
 
  ' Get the CommandManager object
  Dim cm As CommandManager
  Set cm = ThisApplication.CommandManager
 
  ' Get the collection of control definitions
  Dim cds As ControlDefinitions
  Set cds = cm.ControlDefinitions
     
  ' Run the "Suppress" command
  ThisApplication.SilentOperation = True
  Call wbn.DoSelect
  Call cds("AssemblySuppressFeatureCtxCmd").Execute2(True)
  ThisApplication.SilentOperation = False
End Sub

Sub SuppressWeldBead()
  Dim weldName As String
  weldName = "Fillet Weld 1"

  ' Get document
  Dim doc As AssemblyDocument
  Set doc = ThisApplication.ActiveDocument
 
  Dim wcd As WeldmentComponentDefinition
  Set wcd = doc.ComponentDefinition
 
  ' Get "Model" browser
  Dim bp As BrowserPane
  Set bp = doc.BrowserPanes("AmBrowserArrangement")
 
  ' Get "Welds" node
  Dim wbn As BrowserNode
  For Each wbn In bp.TopNode.BrowserNodes
    If wbn.BrowserNodeDefinition.Label = "Welds" Then
      Exit For
    End If
  Next
 
  ' Get "Beads" node
  Dim bbn As BrowserNode
  For Each bbn In wbn.BrowserNodes
    If bbn.BrowserNodeDefinition.Label = "Beads" Then
      Exit For
    End If
  Next
 
  ' Get the Beads we want to suppress
  For Each wbn In bbn.BrowserNodes
    If wbn.BrowserNodeDefinition.Label = weldName Then
      Call SuppressBead(wcd, wbn)
    End If
  Next
End Sub

------------------
************************************
 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP