---

Hallo Zusammen,
ich habe bemerkt, dass Bauteile die man als "Referenz" in der Stückliste definiert hat, in der idw einem entsprechendem Layer zugeordnet werden.

Kann man das für "gekauft" oder "phantom" auch einrichten?

Oder kann man Materialien( wie bei der Schraffur) Layer und somit Farben und Strichstärken zuordnen?

Wie geht man vor im Inventor, wenn man wie bei AutoCad Farben dem Linienstile benutzerdefiniert zuordnen möchte?

Grüße

------------------
Oli

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Oli

deine Layer kannst du Grundsätzlich im Stileditor ändern.
(Verwalten --> Stileditor)

------------------
Gruß, Gandhi
It's not a bug, it's a feature!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Morgen,

gekauft und Phantom und Material wird nicht von Hause auf extra behandelt werden können. herzlich

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von ovb:
Kann man das für "gekauft" oder "phantom" auch einrichten?

---

Nicht automatisch.
Aber du kannst ganze Bauteile über die Pickfilter auf benutzerdefinierte Layer setzen.

zu Linienstilen:  F1  

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke für die Antworten.

Heißt aber, man kann nur durch Nacharbeit der erstellten Zeichnungs-Schnitte jeden einzelnen Schnitt sich vornehmen und durch Handarbeit die Bauteilkanten (im Browser,Part auswählen,rechte Maus,Kanten wählen) auf benutzerdef. Layer legen 

Stört mich nur die Vorstellung, oder ist das was für 2014?

Grüße

------------------
Oli

[Diese Nachricht wurde von ovb am 22. Nov. 2012 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von ovb:
oder ist das was für 2014?

---

Nein, für 2014 ist die Tür schon zu, für 2015 am Schließen.
Aber wenn du eine genügend hohe Lizenzanzahl dahinterstellst, hast du eine Chance ab 2016.

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hat jemand mit VBA schon mal eine Routine für diesen Zweck geschrieben?
z.B. wie bei der Materialzugeordneten Schraffur ein Materialzugeordneter Layer für die idw.

Ich gebe so ungern auf 

Grüße

------------------
Oli

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Bild1.png

Hallo nochmal,
es geht mir immer noch um die Layerverwaltung
wenn man eine große Zeichnung mit 20 Schnitten erstellt hat und alle "Einkauf Artikel" farblich absetzen möchte, dann heißt das, dass man in jedem Schnitt die Bauteile auswählen muss, über rechte Maus "Auswahl als Kanten", und dann dem gewünschten Layer zuordnen muss????

Geht das denn wirklich nicht schneller??

------------------
Oli

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von ovb:
Geht das denn wirklich nicht schneller??

---

Doch, per Makro mit einem einfachen Knopfdruck.
Aber in dem dem mußt du vorher definieren, welches Bauteil auf welchen Layer soll und diesen auch anlegen.

Herr, laß es doch mal Hirn regnen 

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

Zitat:

---

Original erstellt von nightsta1k3r:

Doch, per Makro mit einem einfachen Knopfdruck.
Aber in dem dem mußt du vorher definieren, welches Bauteil auf welchen Layer soll und diesen auch anlegen.

---

bin der Meinung, dass dies oben schon definiert wurde, wie das Macro funktionieren soll...
http://ww3.cad.de/foren/ubb/Forum50/HTML/031498.shtml#000006

Auch ich würde eine solche Funktion begrüßen.

Gruß
SKYSURFER

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo nightsta1k3r,
wenn das doch alles so einfach ist dann hät ich gern das Makro. 

Layer ist angelegt...heißt "gekauft" und Bauteile sind Definiert durch "Gekauft"
------------------
Oli

[Diese Nachricht wurde von ovb am 12. Jan. 2013 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von ovb:
Kann man das für "gekauft" oder "phantom" auch einrichten?

---

Nein, und ich bezweifle auch, dass das ein gute Idee wäre. Was für eine Darstellung stellst Du Dir da vor? Genauso wie Referenz oder anders?

------------------
Roland  
www.Das-Entwicklungsbuero.de

It's not the hammer - it's the way you hit!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Die Layer sollten wie der Normteil Layer funktionieren. Dadurch kann man aber mit verschiedenen Linienstärken und Farben eine Zeichnung aufbauen. Ist für meinen Bereich als Schreiner sinnig, da die Lesbarkeit und Übersichtlichkeit gesteigert werden kann. So stell ich z.B. Mauerwerk mit einer dickeren Linienstärke dar, wie gesagt gekaufte Beschläge in rot und feiner Linienstärke, Glas in blau... Trotzdem sollte natürlich das Material in geschnittener Darstellung mit Schraffur sein.

------------------
Oli

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von ovb:
...gekaufte Beschläge in rot und feiner Linienstärke, Glas in blau...

---

Ich weiß ja nicht, wie es in Deiner Werkstatt zugeht, aber in den Werkstätten, die ich kenne, gibt es Dreck und Feuchtigkeit und Öl und hier mal hartes UV-Licht oder einfach helles Sonnenlicht und da mal zu wenig Licht und gelegentlich farbenblinde Personen obendrein. Zeichnungen, in denen die Farben eine Bedeutung haben, halte ich da für nicht so sinnvoll. Und über Tintenstrahldruck müssen wir hoffentlich gar nicht erst nicht diskutieren.

------------------
Roland  
www.Das-Entwicklungsbuero.de

It's not the hammer - it's the way you hit!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Werkstattzeichnung1.pdf Werkstattzeichnung.pdf

Moin,
ich mache Arbeitsvorbereitung für Schreinereien. Schreiner haben es mit Holz zu tun, welches beim zuschneiden, fräsen oder hobeln über Absauganlagen einen staub- und schmierfreien  Arbeitsplatz hinterlassen. Da es auch beim Schreiner um Millimeter geht sind die Kollegen auch nicht blind, noch farbenblind. Im Handwerk ist es auch oft üblich, dass ein Geselle sich um ein ganzes Objekt kümmert und nicht nur eine Maschine bedient. Somit ist eine Übergeordnete Zeichnung mit allen Schnitten sinnvoll und (ich will ja nicht eingefahren wirken) seit 18 Jahren gewünscht. Anregungen bestimmte Bereiche oder Bauteile farblich abzusetzen kamen von den Schreinereien und wurden von mir dann in MDT umgesetzt. Ich habe mal eine Zeichnung aus MDT als Bild beigefügt. Die Zeichnungen sind für die Werkstatt und vorher auch für den Kunden. Meine Arbeit soll die Vorstellungkraft des Kunden verbessern und anschließend der Werkstatt dienen. Der Zeitaufwand sollte aber nicht mehr als 5-6 Std betragen. Dies ist mir mit MDT gelungen. Die Schreinerprogramme sind mir Größtenteils zu eingeschränkt von Ihrer konstruktiven Flexibilität und auch die Parametrie von MDT hatte es mir angetan, so dass es mich nun zum Inventor geführt hat.
Als größtes Problem vom IV sehe ich diesen gewünschten Zwang zur Maschinenbau - Norm. Gibt es zwar bei uns Schreinern auch, aber wird nicht so aufgezwungen. Das "Problem" gab es auch bei MDT noch nicht.

Ich hoffe, dass ich meinen Standpunkt erklären konnte und keine Rückfragen mehr bekomme warum ich etwas erreichen möchte. Ich bin kein Maschbauer und bei mir macht das Sinn.

In der Hoffnung erfahrene IV- User können dem Neuling weiterhelfen

------------------
Oli

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Ich kenne die farbliche Darstellung im Holzbau für z.B. Umleimer, die sich sonst nur mit unverhältnismäßig hohem Aufwand konstruktiv darstellen lassen. Brian Ekins von Autodesk hat mal ein Makro für das Einfärben von Bauteilen entsprechend der Bauteilfarbe im 3D-Modell veröffentlicht. Ich hab den ein bißchen umgefrickelt, so daß er auf deine Anforderungen passen sollte. Bitte beachten, ändert man die Bauteile von Phantom oder Gekauft zurück auf Normal, ändert das Makro den Layer nicht zurück auf nach Norm. Die Layer Gekauft und Phantom muß du selbst vorher erstellen, sonst geht's in die Hose. Probier's mal aus.

Code:

---

Public Sub ChangeLayerOfOccurrenceCurves()
' Get the active drawing document.
Dim drawDoc As DrawingDocument
Set drawDoc = ThisApplication.ActiveDocument

Dim drawView As DrawingView
For Each drawView In drawDoc.ActiveSheet.DrawingViews

Dim docDesc As DocumentDescriptor
Set docDesc = drawView.ReferencedDocumentDescriptor

' Verify that the selected drawing view is of an assembly.
If docDesc.ReferencedDocumentType <> kAssemblyDocumentObject Then
MsgBox "The selected view must be of an assembly."
Exit Sub
End If

' Get the component definition for the assembly.
Dim asmDef As AssemblyComponentDefinition
Set asmDef = docDesc.ReferencedDocument.ComponentDefinition

' Process the occurrences, wrapping it in a transaction so the
' entire process can be undone with a single undo operation.
Dim trans As Transaction
Set trans = ThisApplication.TransactionManager.StartTransaction(drawDoc, "Change drawing view Layer")

' Call the recursive function that does all the work.
Call ProcessAssemblyColor(drawView, asmDef.Occurrences)
trans.End

Next
End Sub

Private Sub ProcessAssemblyColor(drawView As DrawingView, Occurrences As ComponentOccurrences)
' Iterate through the current collection of occurrences.
Dim occ As ComponentOccurrence
For Each occ In Occurrences
' Check to see if this occurrence is a part or assembly.
If occ.DefinitionDocumentType = kPartDocumentObject Then
' ** It's a part so process the BOM structure
Dim sLayer As String

' Get the layer name by BOM structure of the occurrence.
Select Case occ.BOMStructure
Case kPhantomBOMStructure: sLayer = "Phantom"
Case kPurchasedBOMStructure:  sLayer = "Gekauft"
End Select

If sLayer <> "" Then

' Get the TransientsObjects object to use later.
Dim transObjs As TransientObjects
Set transObjs = ThisApplication.TransientObjects

' Verify that a layer "gekauft" or "phantom" exists
Dim layers As LayersEnumerator
Set layers = drawView.Parent.Parent.StylesManager.layers

Dim drawDoc As DrawingDocument
Set drawDoc = drawView.Parent.Parent

On Error Resume Next
Dim oLayer As Layer
Set oLayer = layers.Item(sLayer)

If Not oLayer Is Nothing Then
' Get all of the curves associated with this occurrence.
On Error Resume Next
Dim drawcurves As DrawingCurvesEnumerator
Set drawcurves = drawView.DrawingCurves(occ)
If Err.Number = 0 Then
On Error GoTo 0

' Create an empty collection.
Dim objColl As ObjectCollection
Set objColl = transObjs.CreateObjectCollection()

' Add the curve segments to the collection.
Dim drawCurve As DrawingCurve
For Each drawCurve In drawcurves
Dim segment As DrawingCurveSegment
For Each segment In drawCurve.Segments
objColl.Add segment
Next
Next

' Change the layer of all of the segments.
Call drawView.Parent.ChangeLayer(objColl, oLayer)
End If
End If
On Error GoTo 0
End If
Else
' It's an assembly so process its contents.
Call ProcessAssemblyColor(drawView, occ.SubOccurrences)
End If
Next
End Sub

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Bild3.png

Hallo Ralf

Genial, vielen vielen Dank. 

Da ich nur VBA Leihe bin, verstehe ich den Code nur ansatzweise. Leider macht er nämlich (siehe Anhang) meine Rückwand Orange obwohl die Rw als Normal deklariert ist. Könntest Du mir da noch mal helfen?

------------------
Oli

[Diese Nachricht wurde von ovb am 13. Jan. 2013 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi

Mein Fehler, die Variable sLayer wird innerhalb der Schleife nicht zurückgesetzt. Deswegen bleibt der einmal gesetzte Wert erhalten. Ersetze bitte die komplette zweite Sub mit:

Code:

---

Private Sub ProcessAssemblyColor(drawView As DrawingView, Occurrences As ComponentOccurrences)
' Iterate through the current collection of occurrences.
Dim occ As ComponentOccurrence
Dim sLayer As String
For Each occ In Occurrences
' Check to see if this occurrence is a part or assembly.
If occ.DefinitionDocumentType = kPartDocumentObject Then
' ** It's a part so process the BOM structure

sLayer = ""

' Get the BOM structure of the occurrence.
Select Case occ.BOMStructure
Case kPhantomBOMStructure: sLayer = "Phantom"
Case kPurchasedBOMStructure:  sLayer = "Gekauft"
End Select

If sLayer <> "" Then

' Get the TransientsObjects object to use later.
Dim transObjs As TransientObjects
Set transObjs = ThisApplication.TransientObjects

' Verify that a layer "gekauft" or "phantom" exists
Dim layers As LayersEnumerator
Set layers = drawView.Parent.Parent.StylesManager.layers

Dim drawDoc As DrawingDocument
Set drawDoc = drawView.Parent.Parent

On Error Resume Next
Dim oLayer As Layer
Set oLayer = layers.Item(sLayer)

If Not oLayer Is Nothing Then
' Get all of the curves associated with this occurrence.
On Error Resume Next
Dim drawcurves As DrawingCurvesEnumerator
Set drawcurves = drawView.DrawingCurves(occ)
If Err.Number = 0 Then
On Error GoTo 0

' Create an empty collection.
Dim objColl As ObjectCollection
Set objColl = transObjs.CreateObjectCollection()

' Add the curve segments to the collection.
Dim drawCurve As DrawingCurve
For Each drawCurve In drawcurves
Dim segment As DrawingCurveSegment
For Each segment In drawCurve.Segments
objColl.Add segment
Next
Next

' Change the layer of all of the segments.
Call drawView.Parent.ChangeLayer(objColl, oLayer)
End If
End If
On Error GoTo 0
End If
Else
' It's an assembly so process its contents.
Call ProcessAssemblyColor(drawView, occ.SubOccurrences)
End If
Next
End Sub

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Ralf,
echt klasse, nochmals Danke für deine Mühe. Wo darf ich die Flasche Wein hinschicken?

Nur mal als Frage: Wenn man nicht Phantom und Gekauft ansprechen will sondern wie ganz oben im Thread ein Material. Ist das auch Möglich?
z.B.: das Mauerwerk immer als Material "Wand" definieren, dann für die Darstellung die Oberflächen anpassen. So handhabe ich das mit der Schraffur, dadurch muß ich in der idw nicht den ansi33 händisch einrichten.
Für die VBA Layersteuerung hieße das dann Material "Wand" = Layer "Wand"

------------------
Oli

[Diese Nachricht wurde von ovb am 13. Jan. 2013 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi

Ginge auch, hab den anderen Code drin gelassen, aber auskommentiert.

Code:

---

Private Sub ProcessAssemblyColor(drawView As DrawingView, Occurrences As ComponentOccurrences)
' Iterate through the current collection of occurrences.
Dim occ As ComponentOccurrence
Dim sLayer As String
For Each occ In Occurrences
' Check to see if this occurrence is a part or assembly.
If occ.DefinitionDocumentType = kPartDocumentObject Then
' ** It's a part so process the BOM structure

sLayer = ""

' Get the BOM structure of the occurrence.
'Select Case occ.BOMStructure
'Case kPhantomBOMStructure: sLayer = "Phantom"
'Case kPurchasedBOMStructure:  sLayer = "Gekauft"
'End Select

' Get the material name of the occurrence
Select Case occ.Definition.Material.Name
Case "Wand": sLayer = "Wand"
Case "Fenster": sLayer = "Fenster"
End Select

If sLayer <> "" Then

' Get the TransientsObjects object to use later.
Dim transObjs As TransientObjects
Set transObjs = ThisApplication.TransientObjects

' Verify that a layer "gekauft" or "phantom" exists
Dim layers As LayersEnumerator
Set layers = drawView.Parent.Parent.StylesManager.layers

Dim drawDoc As DrawingDocument
Set drawDoc = drawView.Parent.Parent

On Error Resume Next
Dim oLayer As Layer
Set oLayer = layers.Item(sLayer)

If Not oLayer Is Nothing Then
' Get all of the curves associated with this occurrence.
On Error Resume Next
Dim drawcurves As DrawingCurvesEnumerator
Set drawcurves = drawView.DrawingCurves(occ)
If Err.Number = 0 Then
On Error GoTo 0

' Create an empty collection.
Dim objColl As ObjectCollection
Set objColl = transObjs.CreateObjectCollection()

' Add the curve segments to the collection.
Dim drawCurve As DrawingCurve
For Each drawCurve In drawcurves
Dim segment As DrawingCurveSegment
For Each segment In drawCurve.Segments
objColl.Add segment
Next
Next

' Change the layer of all of the segments.
Call drawView.Parent.ChangeLayer(objColl, oLayer)
End If
End If
On Error GoTo 0
End If
Else
' It's an assembly so process its contents.
Call ProcessAssemblyColor(drawView, occ.SubOccurrences)
End If
Next
End Sub

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Bin begeistert. 

------------------
Oli

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP