---

Hallo miteinander,

ich habe eine VB.net-Methode geschrieben, mit der ich alle Attributdefinitionen aus einem Block auslesen kann:

Code:

---

    Private Sub Test(ByVal activedoc As Document, ByVal blockid As String)
        Using oAcadDocLock As DocumentLock = activedoc.LockDocument
            Using oTransaction As Transaction = activedoc.TransactionManager.StartTransaction
                Dim oBlockTable As BlockTable = oTransaction.GetObject(activedoc.Database.BlockTableId, OpenMode.ForRead)
                Dim oBlockAttribute As AttributeDefinition

                If (oBlockTable.Has(blockid) = True) Then 'Wenn der Block vorhanden ist...
                    Dim oBlockTableRecord As BlockTableRecord, oBlockElementId As ObjectId, oBlockElement As DBObject

                    oBlockTableRecord = oTransaction.GetObject(oBlockTable(blockid), OpenMode.ForRead)

                    For Each oBlockElementId In oBlockTableRecord 'Für alle Block-Elemente...
                        oBlockElement = oTransaction.GetObject(oBlockElementId, OpenMode.ForRead)
                        If (TypeOf (oBlockElement) Is AttributeDefinition) Then 'Wenn es sich um ein Block-Attribut handelt...
                            oBlockAttribute = oBlockElement

                            Debug.Print(oBlockAttribute.Tag & ";" & oBlockAttribute.TextString & ";" & oBlockAttribute.Prompt & ";" & oBlockAttribute.Constant)
                        End If
                    Next oBlockElementId
                End If
            End Using
        End Using
    End Sub

---

Ausgabe der Methode beim Aufruf mit dem Block "MH-SCHRIFTFELD":

Code:

---

Tag;TextString;Prompt;Constant
GEN-TITLE-SCA;;Maßstab:;False
GEN-TITLE-SIZ;;Blattformat:;False
EINBAUZEICHNUNG;;Einbauzeichnung (E):;False
ERSATZ_FÜR;;;True
ENTSTANDEN_AUS;578132;;True
ERSETZT_DURCH;;;True
VON;;;True
ÜBERSCHRIFT1;Ident-Nr.;;True
ZEICHNUNGSNUMMER;;;True
NENNMASSZEILE;ø180 / 140 x 1900;;True
BENENNUNG;Stielzylinder;;True
ZEICHNER;Gie;;True
ZEICHNUNGSDATUM;11.11.2009;;True

---

Eine ähnliche Funktion benutze ich zum Schreiben der Attribute. So haben wir bei uns das Ausfüllen der Schriftfelder realisiert.

Jetzt enthält unser Schriftfeld aber auch ein paar Eingabefelder (Prompt), wo der Benutzer etwas eingeben muss bzw. AutoCAD Mechanical Werte einträgt (GEN-TITLE-SCA, GEN-TITLE-SIZ).

Den „Prompt“-String (also was der Benutzer als Frage angezeigt bekommt) von diesen Attributen kann ich auslesen, aber „TextString“ ist leider leer. Wie komme ich an den Wert, den der Benutzer eingetragen hat? Ich würde so nämlich auch gerne Maßstab und Blattgröße auslesen.

Ich hoffe, ihr könnt mir helfen. Vielen Dank schon mal im Voraus!

Mit freundlichen Grüßen,
Tim Gerundt

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

du darft da auch nicht in der Blockdefinition gucken ... da gibts die Attributsdefinitionen mit den Vorgaben ..... sondern in der Blockreferenz im Layout .... da hängen die Attribute dran

------------------
  - Thomas -          
"Bei 99% aller Probleme ist die umfassende Beschreibung des Problems bereits mehr als die Hälfte der Lösung desselben."

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Tim,

Grundproblem: die Unterscheidung zwischen 'Blockdefinition' und 'Blockreferenz'!

Die Blockdefinition gibt es (für z.B. Block 'Planrahmen') nur einmal in der Zeichnung, in dieser Definition wird festgelegt, wie so ein Symbol auszusehen hat und welche Attributsdefinitionen es gibt.

Die Blockreferenz gibt es so oft in der Zeichnung, wie der Anwender (oder Dein Programm) es im Modellbereich, in Layouts (oder auch verschachtelt in anderen Blockdefinitionen) eingesetzt ist.

Bleiben wir beim Beispiel mit dem Blattrahmen, dann kann in 5 Layouts eine solche Blockreferenz eingesetzt sein. Und hier kann der Anwender auch seine Attributswerte eingetragen haben, also TextString ausgefüllt haben.

Du suchst in der Blockdefition und nicht in den Blockreferenzen!

- alfred -

------------------
www.hollaus.at

---

Danke für die schnellen Antworten!

Habt ihr wohl Beispiel-Quelltext wie ich die Blockreferenzen auslesen kann?

Tim

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

nur lisp ... net hab ich keine Ahnung

------------------
  - Thomas -          
"Bei 99% aller Probleme ist die umfassende Beschreibung des Problems bereits mehr als die Hälfte der Lösung desselben."

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

findest Du aber schon auch im ObjectARX-Kit, muss nicht hier abgeschrieben werden, oder?  

[EDIT] Zugriff auf AttributeReference findest Du auch >>>hier<<< [/EDIT]

- alfred -

------------------
www.hollaus.at

---

So, es hat ein bisschen gedauert, weil ich mich noch nicht sogut mit ObjectARX auskenne und AutoCAD eigentlich nur installieren und nicht bedienen muss. ;-)

Code:

---

    Private Sub Test2(ByVal activedoc As Document, ByVal blockid As String)
        Using oTransaction As Transaction = activedoc.TransactionManager.StartTransaction
            Dim oBlockTable As BlockTable = oTransaction.GetObject(activedoc.Database.BlockTableId, OpenMode.ForRead)

            If oBlockTable.Has(blockid) Then 'Wenn die Block-Definition vorhanden ist...
                Dim oBlockTableRecord As BlockTableRecord = oTransaction.GetObject(oBlockTable(blockid), OpenMode.ForRead)

                For Each oBlockReferenceId As ObjectId In oBlockTableRecord.GetBlockReferenceIds(True, False) 'Für alle Block-Referenzen...
                    Dim oBlockReference As BlockReference = oTransaction.GetObject(oBlockReferenceId, OpenMode.ForRead)

                    For Each oAttributeReferenceId As ObjectId In oBlockReference.AttributeCollection 'Für alle Attribute-Referenzen...
                        Dim oAttributeReference As AttributeReference = oTransaction.GetObject(oAttributeReferenceId, OpenMode.ForRead)

                        Debug.Print(oAttributeReference.Tag & "=" & oAttributeReference.TextString)
                    Next oAttributeReferenceId
                Next oBlockReferenceId
            End If
        End Using
    End Sub

---

Ich suche erst die Definiton des Blocks und lasse mir dann alle Referenzen zurückgeben. In diesen Referenzen kann ich dann die Attribute auslesen.

Viellen Dank noch mal für eure Hilfe!

*WinkeWinke*

Tim

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP