---

Hallo SE Fans!

Wenn ich ein makro bereits einmal gestartet habe, es in "Minimalstellung" in die Taskleiste befördere, dann kann ich zwar mit:
if App.prevInstance = true then
feststellen, dass es bereits läuft, ich schaffe es aber nicht auf die laufende Instanz zuzugreifen und diese dann wieder
in den Vordergrund vorzuholen.

kann mir da jemand meine Scheuklappen von den Augen nehmen und mir
einen Tip geben?

Danke und Gruß
Wolfgang

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

mit App.PrevInstance weisst Du ja nur das dieses gleiche Programm bereits
laeuft. Um dieses anzusprechen benoetigst du den Prozess-ID der
anderen Instanz.

Aber wozu: das Programm stellt fest, dass es bereits min. 1 schon
aktiv ist, nur was ist der Zweck diese Instanz - 1 wieder zu maximieren
um sich dann zu beenden. Der Sinn der Abfrage App.PrevInstance sollte
ja darin liegen, dass nur 1 Instanz des Programms laeuft.

modeng

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Servus Wolfgang,

Code sollte funzen.

In deinen Code einbauen (Fenstercaption anpassen!!!!)

    Dim xhWnd As Long
    'Anwendung soll nur einmal gestartet werden, sonst bereits laufende Instanz in aktivieren
    If App.PrevInstance Then
        Me.Caption = "Cad Dateisuche (wird gestartet)"          'anderer Titel damit von Fenstersuche nichts gefunden wird
        xhWnd = FindWindow(vbNullString, "Cad Dateisuche")      'Fenster suchen
        Call ActivateWindow(xhWnd)                              'Fenster aktivieren
        End                                                    'Diese Instanz killen
    Else
        Me.Caption = "Cad Dateisuche"                          'Titel richtig stellen damit Fenster von nächster Instanz gefunden werden kann
    End If

und die APIs dazu

'wird benötigt damit bereits laufende Instanz aktiviert werden kann
Private Declare Function FindWindow Lib "user32" _
        Alias "FindWindowA" (ByVal lpClassName _
        As String, ByVal lpWindowName As String) _
        As Long
       
Private Declare Function GetWindowPlacement Lib _
        "user32" (ByVal hWnd As Long, lpwndpl As _
        WINDOWPLACEMENT) As Long
       
Private Declare Function SetWindowPlacement Lib _
        "user32" (ByVal hWnd As Long, lpwndpl _
        As WINDOWPLACEMENT) As Long
       
Private Declare Function SetForegroundWindow Lib _
        "user32" (ByVal hWnd As Long) As Long
       
Private Declare Function BringWindowToTop Lib _
        "user32" (ByVal hWnd As Long) As Long

Const SW_SHOWNORMAL = 1
Const SW_SHOWMINIMIZED = 2

Private Type POINTAPI
  x As Long
  y As Long
End Type

Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type

Private Type WINDOWPLACEMENT
  Length As Long
  flags As Long
  showCmd As Long
  ptMinPosition As POINTAPI
  ptMaxPosition As POINTAPI
  rcNormalPosition As RECT
End Type

Private Sub ActivateWindow(xhWnd As Long)
    Dim Result As Long
    Dim WndPlcmt As WINDOWPLACEMENT
    With WndPlcmt
      .Length = Len(WndPlcmt)
      Result = GetWindowPlacement(xhWnd, WndPlcmt)
      If Result Then
        If .showCmd = SW_SHOWMINIMIZED Then
          .flags = 0
          .showCmd = SW_SHOWNORMAL
          Result = SetWindowPlacement(xhWnd, WndPlcmt)
        Else
          Call SetForegroundWindow(xhWnd)
          Result = BringWindowToTop(xhWnd)
        End If
      End If
    End With
  End Sub

Jürgen

------------------
54* SEV15SR8, 4*SEV16.00.01.03

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Jürgen,

recht herzlichen Dank, Dein Code läuft so richtig gut -
Thanks und Gruß
Wolfgang

PS.: Ich hätte da ja noch ein weiteres offenes Problem:

Bei Parts und Sheetmetall kann ich die Größe des Teils ohne Schwierigkeit mit einem
SEDoc.Models(1).Body.GetRange(x,Y)
abfragen.
Für einen Schweißteil sollte dies laut Doku mit
SEDoc.Weldmentmodels(1).GetRangeByModel(SE...Models(1), x1,x2,x3,y1,y2,y3) ebenfalls funktionieren.
Ich bekomme dabei allerdings stets nur 0-Werte für alle x und y

Eine Idee?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP