---

Hallo Zusammen,

im Internet habe ich eine schönes Beispiel für den SelectionSet gefunden.

Hier der Code:
----------------------------------------------------

Sub AusAuswahlEntfernen()

Dim objSset As AcadSelectionSet
Dim objEnt As AcadEntity

On Error Resume Next

    'Auswahlsatz löschen, falls vorhanden

    For Each objSset In ThisDrawing.SelectionSets
      If objSset.Name = "NeuerAuswahlsatz" Then
      objSset.Delete
      End If
    Next

    Set objSset = ThisDrawing.SelectionSets.Add("NeuerAuswahlsatz")
    objSset.SelectOnScreen

    'Alle Kreise aus Auswahl entfernen
    For Each objEnt In objSset
      If objEnt.ObjectName = "AcDbCircle" Then
        objSset.RemoveItems objEnt
      End If
    Next objEnt

End Sub

---------------------------------------------------

Dieses Progrämmchen läuft auch sehr gut, ABER nur das erste Mal.
Beim zweiten Aufruf kommt bei mir die Fehlermeldung:

Systemfehler: Unhandled Access Violation Reading
              0x0000 Excption at 78a33abch

Ich bin kein Profi in Sachen VBA und kann mir dieses Verhalten nicht erklären.

Kann jemand mir hier weiter helfen 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

als erstes schalte mal deinen Errorhandler wieder ein ...

... und dann führe nochmal aus.
Jetzt siehst Du, dass er in der Zeile hängt:

Code:

---

objSset.RemoveItems objEn

---

Ein F1 auf 'RemoveItems' verrät:
Object = Variant (array of objects)

Ergo müsste dein Code dann irgendwie so in der Art aussehen:

Code:

---

    'Alle Kreise aus Auswahl entfernen
    Dim i&, arr() As AcadEntity
    i = -1
    Debug.Print objSset.Count
    For Each objEnt In objSset
      If objEnt.ObjectName = "AcDbCircle" Then
        i = i + 1
        ReDim Preserve arr(0 To i)
        Set arr(i) = objEnt
      End If
    Next objEnt
    objSset.RemoveItems arr
    Debug.Print objSset.Count

---

Schau Dir auch in Ruhe mal die Beispiele in der Hilfe an, zu:
- RemoveItems
- Erase
- Delete
Dann wird vieles klarer;-) 

Gruß Nancy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Nancy,

danke für deine schnelle Antwort. Ich habe deinen Code eingebaut, leider trat der Fehler immer noch auf. Der Hinweis auf den Errorhandler hat mir gezeigt, das der Fehler in dieser Schleife liegt:

    For Each objSset In ThisDrawing.SelectionSets
      If objSset.Name = "NeuerAuswahlsatz" Then
      objSset.Delete
      End If
    Next

Ich habe nach dem Delete ein Exit For eingebaut und nun läuft das Programm auch bei mehrfachem Aufruf.

Leider verstehe ich dieses Verhalten noch nicht.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

    

Zitat:

---

Original erstellt von ela-cad:
Der Hinweis auf den Errorhandler hat mir gezeigt, das der Fehler in dieser Schleife liegt:

Code:

---

For Each objSset In ThisDrawing.SelectionSets
  If objSset.Name = "NeuerAuswahlsatz" Then
    objSset.Delete
  End If
Next

---

---

Ohne jetzt Deinen geänderten Code zu kennen ... der Fehler liegt (ungetestet) garantiert NICHT! in dieser Abfrage;-)
Der Fehler liegt IMHO dabei, wo und wie Du mit 'On Error resume next' und mit 'On Error goto 0' umgehst.

Den Errorhandler brauchste schon bei Deinem Konstrukt, du musst ihn aber gezielt (hier beim Sset) einsetzen:

Code:

---

On Error Resume Next 'riskiern wir mal nen Crash und übergehen mögliche Errors im Sset einfach
'Auswahlsatz löschen, falls vorhanden
    For Each objSset In ThisDrawing.SelectionSets
      If objSset.Name = "NeuerAuswahlsatz" Then
      objSset.Delete
      End If
    Next
'jetzt ist in jedem Fall das Sset "NeuerAuswahlsatz" verwendbar, egal ob vorher vorhanden oder nicht
Set objSset = ThisDrawing.SelectionSets.Add("NeuerAuswahlsatz")
on error goto 0 'sinnvollerweise den Errorhandler nach dem Sset-Chrash-Test zurücksetzen

---

Wenn Du also vergisst mit 'On Error goto 0' die Hexerei namens 'On Error resume next' auszuschalten,
kannst du in Teufels Küche kommen;-)
Errorhandler (ein/aus) macht also - richtig platziert - Sinn.

Hab aber etwas das Gefühl, du steigst grade von fast Null bei (symbolisch) 'Lesson 37' ein?
Egal - untendran mal dein Code, wie er bei mir läuft, dafür verrätste aber mal wo man sowas aufgabelt;-):

> im Internet habe ich eine schönes Beispiel für den SelectionSet gefunden.

Gruß Nancy
--

Code:

---

Option Explicit

Sub AusAuswahlEntfernen()

   Dim objSset As AcadSelectionSet
   Dim objEnt As AcadEntity

   On Error Resume Next 'Errorhandler = AUS, Crashtest = EIN

    'Auswahlsatz löschen, falls vorhanden

    For Each objSset In ThisDrawing.SelectionSets
      If objSset.Name = "NeuerAuswahlsatz" Then
      objSset.Delete
      End If
    Next
    Set objSset = ThisDrawing.SelectionSets.Add("NeuerAuswahlsatz")
   
    On Error GoTo 0 'Errorhandler = EIN, Chrashtest = AUS
   
    objSset.SelectOnScreen

    'Alle Kreise aus Auswahl entfernen
    Dim i&, arr() As AcadEntity
    i = -1
    For Each objEnt In objSset
      If objEnt.ObjectName = "AcDbCircle" Then
        i = i + 1
        ReDim Preserve arr(0 To i)
        Set arr(i) = objEnt
      End If
    Next objEnt
    objSset.RemoveItems arr
End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP