---

Wie kann ich in VB6 feststellenob Autocad bereits gestartet ist?
Gibt es eine Möglichkeit über den Task-Manager?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi HJ,

zwei Vorschläge:
http://ww3.cad.de/foren/ubb/Forum259/HTML/000315.shtml
http://ww3.cad.de/foren/ubb/Forum110/HTML/000253.shtml

bzw. such halt auch mal im VB-Forum nach Prozess o.ä. ;-)

lg Nancy 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo HJ,

das von Nancy ist doch OK, sonst kannst auch das hier benutzen, ist etwas kürzer.

Code:

---

      Option Explicit

      Private Declare Function FindWindow Lib "user32" _
        Alias "FindWindowA" _
        (ByVal lpClassName As String, _
        ByVal lpWindowName As String) As Long

      Private Declare Function IsWindow Lib "user32" _
        (ByVal hwnd As Long) As Long

      Sub test()
     
        Dim hWindow As Long

        hWindow = FindWindow(vbNullString, "AutoCAD Map 2000i - [Zeichng1.dwg]")
        If IsWindow(hWindow) = 1 Then

            MsgBox "Das Programm ist gestartet!"
        Else

            MsgBox "Das Programm ist nicht gestartet!"
        End If
      End Sub

---

gefunden auf http://support.microsoft.com/default.aspx?scid=kb;en-us;176391&Product=vbb

Gruß TP

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank fÌr Eure UnterstÌtzung. Da ich "blutiger AnfÀnger" bin habe ich das Forum offensichtlich nicht richtig genutzt. Sorry !!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo HJ,

die Lösung die ich da gefunden hatte, hat mir nicht wirklich gefallen und hab ebend nochmal gesucht und bin über nachfolgenden Code gestolpert. Könnte evtl. besser sein nach der acad.exe zu suchen.

Code:

---

Public Declare Function CreateToolhelp32Snapshot Lib "Kernel32" _
        (ByVal lFlags As Long, ByVal lProcessID As Long) As Long

Private Declare Function ProcessFirst Lib "Kernel32" Alias _
        "Process32First" (ByVal hSnapShot As Long, uProcess _
        As PROCESSENTRY32) As Long

Private Declare Function ProcessNext Lib "Kernel32" Alias _
        "Process32Next" (ByVal hSnapShot As Long, uProcess _
        As PROCESSENTRY32) As Long

Private Declare Sub CloseHandle Lib "Kernel32" (ByVal hPass _
        As Long)

Const TH32CS_SNAPPROCESS As Long = 2&
Const MAX_PATH As Integer = 260

Private Type PROCESSENTRY32
  dwSize As Long
  cntUsage As Long
  th32ProcessID As Long
  th32DefaultHeapID As Long
  th32ModuleID As Long
  cntThreads As Long
  th32ParentProcessID As Long
  pcPriClassBase As Long
  dwFlags As Long
  szExeFile As String * MAX_PATH
End Type

Private Sub GetExeNames()
    Dim hSnapShot As Long, Result As Long
    Dim aa As String, bb As String
    Dim Process As PROCESSENTRY32

    hSnapShot = CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0&)
    If hSnapShot = 0 Then Exit Sub

    Process.dwSize = Len(Process)
    Result = ProcessFirst(hSnapShot, Process)
 
    Do While Result <> 0
        aa = Process.szExeFile
       
        If Left$(aa, InStr(aa, Chr$(0)) - 1) = "acad.exe" Then
            MsgBox "AutoCAD läuft"
        End If
       
        Result = ProcessNext(hSnapShot, Process)
    Loop
   
    Call CloseHandle(hSnapShot)
End Sub

---

gefunden bei  http://www.activevb.de/tipps/vb6tipps/tipp0273.html

Ganz unten das wichtigste ..  ... lief bei mir nicht unter NT, dafür aber in XP. Ansonsten mal unter der URL im QuellCode kucken, da steht nen Link zu Microsoft, die unterscheiden dort noch nach Betriebssystemen.

Gruß TP

[Diese Nachricht wurde von BloodyMess am 25. Aug. 2004 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Herzlichen Dank, tolles Programm.
Habe es ein wenig abgewndelt funktioniert einwandfrei.

Besser geht's nimmer.

Gruß

Hajo

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP