---

Hallo,

Ich habe ein Baugruppe mit mehreren Bauteilen.
Die Bauteile haben verschiedene Arbeitsebenen.
Wie ist es möglich eine dieser Arbeitsebenen per VBA auszuwählen?
Der nachfolgende Code funktioniert leider nicht.

Code:

---

Dim objSubOcc As Inventor.ComponentOccurrence
Dim oDoc As PartDocument
Dim oDef As PartComponentDefinition
Dim objWorkPlane As Inventor.WorkPlane
Dim objSelectSet As SelectSet

Set objSubOcc = ThisApplication.ActiveDocument.SelectSet.Item(1)
Set oDoc = objSubOcc.Definition.Document
Set oDef = oDoc.ComponentDefinition
Set objWorkPlane = oDef.WorkPlanes("ArbeitsEbene1")

Set objSelectSet = ThisApplication.ActiveDocument.SelectSet
objSelectSet.Clear
Call objSelectSet.Select(objWorkPlane)

---

------------------
Gruß Jörn

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Du musst aus der Arbeitsebene im Bauteil einen Arbeitsebenenproxy im Kontext der Baugruppe erzeugen. Die Arbeitsebene selbst gibt es in der Baugruppe nicht.

Code:

---

Option Explicit

Private Sub SelWorkPlane()

Dim oApp As Inventor.Application
Set oApp = ThisApplication

Dim oAssDoc As AssemblyDocument
Set oAssDoc = oApp.ActiveDocument

Dim oOcc As ComponentOccurrence
Set oOcc = oApp.CommandManager.Pick(kAssemblyLeafOccurrenceFilter, "Bitte Bauteil auswählen")

If Not oOcc.DefinitionDocumentType = kPartDocumentObject Then
    Call MsgBox("Kein Bauteil gewählt.", vbCritical, "WorkPlaneProxy")
    Exit Sub
End If

Dim oOccDef As PartComponentDefinition
Set oOccDef = oOcc.Definition

Dim oWorkPlane As WorkPlane
Set oWorkPlane = oOccDef.WorkPlanes.Item("ArbeitsEbene1")

Dim oWorkPlaneProxy As WorkPlaneProxy
Call oOcc.CreateGeometryProxy(oWorkPlane, oWorkPlaneProxy)

Call oAssDoc.SelectSet.Clear
Call oAssDoc.SelectSet.Select(oWorkPlaneProxy)

End Sub

---

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank Ralf

------------------
Gruß Jörn

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP