---

Moin Moin...

einmal ganz schnell: Ich möchte in einem Makro die Funktion einbetten, dass die einzige vorhandene Stückliste in einer Baugruppenzeichnung aktiviert und ausgeblendet wird.

Hoffe ihr könnt mir helfen.

Danke und schon mal ein schönes Wochenende!

------------------
Menschen mit einer neuen Idee gelten so lange als Spinner, bis sich die Sache durchgesetzt hat. [Mark Twain]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Sonny

Variante 1

Code:

---

Sub HideAllSwBomTables()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swFeat As SldWorks.Feature
    Dim retval As Boolean

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swFeat = swModel.FirstFeature

    Do While Not swFeat Is Nothing
        If "BomFeat" = swFeat.GetTypeName Then
            retval = swFeat.Select2(False, -1)
            swApp.RunCommand swCommands_Hide_Table, Empty
        End If
        Set swFeat = swFeat.GetNextFeature
    Loop

End Sub

---

Variante2

Code:

---

Sub HideAllSwBomTables2()
   
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swDraw As SldWorks.DrawingDoc
    Dim swView As SldWorks.View
    Dim swTableAnn As SldWorks.TableAnnotation
    Dim swAnn As SldWorks.Annotation
    Dim vTableAnns As Variant
    Dim i As Integer
   
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swDraw = swModel
    Set swView = swDraw.GetFirstView
    vTableAnns = swView.GetTableAnnotations
    If IsEmpty(vTableAnns) = False Then
        For i = 0 To UBound(vTableAnns)
            Set swTableAnn = vTableAnns(i)
            If swTableAnn.Type = swTableAnnotation_BillOfMaterials Then
                Set swAnn = swTableAnn.GetAnnotation
                swAnn.Visible = swAnnotationVisibilityState_e.swAnnotationHidden
            End If
        Next i
    End If
End Sub

---

Gruss Andreas

------------------
21 ist nur die halbe Antwort.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP