---

Hallo zusammen,

weiß jemand, wie ich die Features, welche in einem linearen Feature Muster sind, mit VBA anfragen kann?

Z.B. Ich erstelle von "Bohrung1" und "Fase1" ein lineares Muster "Lineares Muster1". Später wähle ich manuel "Lineares Muster1" aus und ich will mit VBA die Features "Bohrung1" und "Fase1" in eine MsgBox schreiben.

Dankeschön.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Als Idee: Ich könnte mir vorstellen, daß Du, wenn Du die Eltern/Kind- Beziehungen mittels GetParents überprüfst, an die Ausgangsfeatures gelangen könntest.

------------------
Lutz Federbusch
Mein Gästebuch
Der Mensch, Herr oder Sklave der Technik?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Quick'n'dirty aus der API-Hilfe zusammengebastelt:

Code:

---

Dim swApp As SldWorks.SldWorks

Dim swModel As SldWorks.ModelDoc2
Dim swModelDocExt As SldWorks.ModelDocExtension
Dim swSelMgr As SldWorks.SelectionMgr
Dim swFeat As SldWorks.feature
Dim featName As String
Dim featType As String
Dim featParents As Variant

Dim boolstatus As Boolean
Dim longstatus As Long, longwarnings As Long

Dim n As Integer

Sub main()
Debug.Print " ---- Start -----------"
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc

Set swSelMgr = swModel.SelectionManager

Set swModelDocExt = swModel.Extension
' Get the selected feature
Set swFeat = swSelMgr.GetSelectedObject6(1, -1)
If swFeat Is Nothing Then
    MsgBox "Kein Feature ausgewählt"
    Exit Sub
End If

' Get the feature's type and name
featType = swFeat.GetTypeName()
Debug.Print "Feature type: " & featType

featName = swFeat.GetNameForSelection(featType)

' Print the feature's type and name
' to the Immediate window
Debug.Print "Feature name: " & featName
Debug.Print "------------"
featParents = swFeat.GetParents

  For n = 0 To UBound(featParents)

    featType = featParents(n).GetTypeName2()
    Debug.Print "- Feature type: " & featType

    featName = featParents(n).GetNameForSelection(featType)
    Debug.Print "- Feature name: " & featName

  Next n
End Sub

---

Aus den Debug.Print-Anweisungen musst du dir halt die passende Ausgabe basteln (MsgBox, eigene Form...)
Achtung: featType wird blöderweise durch die Funktion GetNameForSelection verändert! Also immer vorher abfragen, wenn du den wissen willst.

------------------
Klaus

www.al-ko.com | mein Gästebuch

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP