---

Komponenteneigenschaften.jpg

Hallo zusammen

ich würde gerne in den Komponenteneigenschaften gern die darin enthaltene Komponentenbeschreibung (siehe roten Rahmen im Anhang) auslesen.
Kennt vielleicht jemand die dazugehörige API-Methode?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Komponentenbeschreibung.jpg

Hallo Scoopa,

als Komponentenbeschreibung wird die Dokumenteigenschaft verwendet, die in den Systemoptionen unter "Benutzerdefinierte Eigenschaft als Komponentenbeschreibung verwendet" angegeben ist (siehe Bild).
Diese kannst du mit:
%Eigenschaftsname% = SldWorks.GetUserPreferenceStringValue(swCustomPropertyUsedAsComponentDescription)
auslesen.

Den Wert selbst, liest du anschließend wie jede andere Dokumenteigenschaft aus dem ModelDoc2 der Komponente aus.
Zum Beispiel mit ModelDoc2.Extension.CustomPropertyManager.Get(%Eigenschaftsname%)

------------------
Mfg Daniel

www.MySldWorks.de - SolidWorks API Snippets

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo tbd

vielen Dank für die Antwort. Leider klappt die Ausführung noch nicht bei mir 
wo bekomme ich folgenden Wert her: swCustomPropertyUsedAsComponentDescription
im Objektkatalog wird angegeben:
Function GetUserPreferenceStringValue(UserPreference As Long) As String

was oder woher bekomme ich die UserPreference? 
komischerweise wird es mal als integer und mal als long gefordert? ist sicher ein fehler oder?

Code:

---

Visual Basic (Declaration) 
Function GetUserPreferenceStringValue( _
  ByVal UserPreference As Integer _
) As String

Visual Basic (Usage) Copy Code
Dim instance As IModelDoc
Dim UserPreference As Integer
Dim value As String

value = instance.GetUserPreferenceStringValue(UserPreference)

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Scoopa,

swCustomPropertyUsedAsComponentDescription ist Bestandteil der Klasse swconst.
Damit du diese verwenden kannst, benötigst du einen Verweis (Extras>Verweise) zur Bibliothek SolidWorks XXXX Constant type Library.

Ich habe dir mal ein kleines Makro gebastelt, das dir die Komponentenbeschreibung aus der ersten selektierten Komponente ermittelt:

Code:

---

Dim oSwApp As SldWorks.SldWorks
Dim oSwModel_Asm As SldWorks.ModelDoc2
Dim oSwSelMgr As SldWorks.SelectionMgr
Dim oSwModel_Com As SldWorks.ModelDoc2
Dim oSwComponent As SldWorks.Component2
Dim sComponentDescriptionValue As String
Dim sComponentDescriptionProperty As String

Sub main()

    'SolidWorks
    Set oSwApp = Application.SldWorks
    'Systemoption auslesen
    sComponentDescriptionProperty = oSwApp.GetUserPreferenceStringValue( _
                            swCustomPropertyUsedAsComponentDescription)
    'Aktive Baugruppe
    Set oSwModel_Asm = oSwApp.ActiveDoc
    'Selektionsmanager
    Set oSwSelMgr = oSwModel_Asm.SelectionManager
    'Erste selektierte Komponente
    Set oSwComponent = oSwSelMgr.GetSelectedObjectsComponent3(1, -1)
   
    If oSwComponent Is Nothing = False Then
        'ModelDoc der Komponente
        Set oSwModel_Com = oSwComponent.GetModelDoc
        'ModelDoc prüfen, wichtig bei z.B. reduziert geladenen Komponenten
        If oSwModel_Com Is Nothing = False Then
            'Dokumenteigenschaft auslesen
            sComponentDescriptionValue = _
                oSwModel_Com.Extension.CustomPropertyManager("").Get( _
                sComponentDescriptionProperty)
            MsgBox sComponentDescriptionValue
        End If
    End If

End Sub

---

------------------
Mfg Daniel

www.MySldWorks.de - SolidWorks API Snippets

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Vielen Dank.

Ich hoffe ich kann es nun in meinen Code passend einbauen. sollte aber hinhauen 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP