---

Moin moin
nochmals die ganz konkrete FRAGE (auf die ich leider keine Antwort im Forum gefunden habe):

Wie kann ich den Druck-Befehl in SolidWorks (2006,2007) abfangen, so dass ich ein Makro automatisch ausführen lassen, bevor gedruckt wird?

Gruß Thomas

------------------
Jeder ist zu etwas nütze,
er kann immer noch als schlechtes Beispiel dienen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Bei bestimmten Aktionen freuert SW zu Beginn der Aktion ein Event (s. API-Hilfe), das man mit einem Event-Handler abfangen kann. Fürs Drucken kenne ich da keins, vielleicht gibt es das aber auch oder vielleicht im Windows, das genauso mit Events um sich wirft?!
Du könntest aber einen eigenen MakroKnopf einrichten, der alles tut, was vorher getan werden muß und dann das Drucken abschickt. Und die anderen Symbole und Menüleisten so bearbeiten, daß da kein anderes Drucken mehr zu sehen ist...

------------------
Lutz Federbusch
Mein Gästebuch
Der Mensch, Herr oder Sklave der Technik?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Thomas,

in SW2007 Sp2 ist eine neues Event namens PrintNotify dazu gekommen, vielleicht geht es damit ... hab ich aber noch nie gemacht und wüßte auch so keinen Weg, wie das funktionieren würde.

Ciao,
Stefan

------------------
Inoffizielle deutsche SolidWorks Hilfeseite    http://solidworks.cad.de

Member of CAD.de BOINC Team  -   | Seti@Home | CPDN | Einstein@Home

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke Lutz,

a b e r ... wie binde ich das "normale" Drucken in das Script mit ein?
Hast du ggf. mal ein Beispiel?

Gruß Thomas

------------------
Jeder ist zu etwas nütze,
er kann immer noch als schlechtes Beispiel dienen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Du könntest in der API-Hilfe nachsehen im Index bei Sachen, die mit Print anfangen. Wenn Deine Seiten korrekt eingerichtet sind, kannst Du mit ModelDoc2.PrintDirect auf dem Standarddrucker drucken, als ob Du in der Symbolleiste auf den Druckbefehlsknopf gedrückt hättest...

------------------
Lutz Federbusch
Mein Gästebuch
Der Mensch, Herr oder Sklave der Technik?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ok, nochmals für API-D***en:
Wie wende ich "ModelDoc2.PrintDirect" für das aktuelle Dokument an, dass wenn das Makro an dieser Stelle vorbei kommt, das Dokument auch einfach so gedruckt wird?
In der API Hilfe habe ich für mich leider nur ungenügend Informationen erhalten...

Vielen Dank!

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Gilbert,

was hast du genau vor, bzw. was möchtest du wann, wie Drucken?
Beschreibe bitte dein gewünschtes Zeil, damit ich dir evtl. mit einem kleinen Codeschnipsel helfen kann.

Vieleicht hilft dir auch unser kostenloses SolidWorks Tool SDA-QuickPrint weiter.
Mit Hilfe dieses Add-Ins kannst du unter anderem Dokumente mit einem Mausklick auf A3 und A4 oder alle Zeichnungen aus einem Ordner (Stapelverarbeitung) drucken.
Weiter Informationen, sowie den kostenlosen download findes du hier: SDA-QuickPrint.

------------------
Mfg Daniel

Lesen ist super. Nur die Buchstaben machen einen verrückt!
------------------

SolidWorks Programmierung | Tools | Makros | Software; Schuler Design Automation GmbH

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank tbd!
Ich werds gleich mal ausprobieren - Bei der nächsten Gelegenheit.

Was ich eigentlich vor hatte, war, durch alle geöffneten Dokumente gehen und jedes auf den Standaraddrucker (Direct.Print) zu drucken. Da wir den Drucker in der Vorlage definiert haben, ginge das Problemlos - wenn man wüsste wie! 

Ich reihe meine Fenster immer "Untereinander" an, wenn ich dann jedes einzelne drucke - CTRL+Tab, Print - CTRL+Tab, Print usw... geht 10x schneller als wenn die Zeichnungen maximiert auf dem Schirm liegen 

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Morgen Gilbert,

da müsste kein Problem sein.

Könnte heute zwischen dem Testen an einem Makro basteln. Melde mich wenn es soweit ist.

------------------
Mfg Daniel

Lesen ist super. Nur die Buchstaben machen einen verrückt!
------------------

SolidWorks Programmierung | Tools | Makros | Software; Schuler Design Automation GmbH

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Drucken.txt

Hallo Gilbert,

schon passiert:

Code:

---

Dim oSwApp As SldWorks.SldWorks
Dim oModelDoc As SldWorks.ModelDoc2

Sub main()
    'SolidWorks belegen
    Set oSwApp = Application.SldWorks
    'Erstes Dokument belegen
    Set oModelDoc = oSwApp.GetFirstDocument
    'Mal schauen was alles offen ist und die Dokumente drucken
    Do While Not oModelDoc Is Nothing
        Debug.Print (oModelDoc.GetTitle)
        'Dokument in SolidWorks aktivieren
        oSwApp.ActivateDoc (oModelDoc.GetTitle)
        'Dokument auf den Standarddrucker Drucken
        oModelDoc.PrintDirect
        'Nächstes Dokument
        Set oModelDoc = oModelDoc.GetNext
    Loop
End Sub

---

Bei Zeichnungen wird in diesem Makro die Blattgröße und Ausrichtung nicht berücksichtigt. Bei Bauteilen und Baugruppen funktioniert das aber wunderbar.

------------------
Mfg Daniel

Lesen ist super. Nur die Buchstaben machen einen verrückt!
------------------

SolidWorks Programmierung | Tools | Makros | Software; Schuler Design Automation GmbH

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ok! Vielen Dank!
Es druckt wie wild!

Doch ein "Problem"! Wenn ich ein paar Zeichnungen offen habe und das Makro starte, öffnet er mir auch die Modelle zur Zeichnung und druckt diese mit...?! Dies habe ich mir nicht ganz so gedacht. Er sollte nur die Zeichnungen (oder eben alle geöffneten Dokumente) drucken.

EDIT:
Debug-Print ist:

Ausstosserbrücke
Ausstosserdruckstück
Distanzring_02
94003286-3P-ST3-002 - Blatt1
94003286-3P-ST3-003 - Blatt1
94003286-3P-ST3-006 - Blatt1

Debug-Print soll:

94003286-3P-ST3-002 - Blatt1
94003286-3P-ST3-003 - Blatt1
94003286-3P-ST3-006 - Blatt1

------------------
   

[Diese Nachricht wurde von G. Dawg am 22. Mai. 2007 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Drucken.txt

Da bei einer Zeichnung bekanntlich auch ein Dokument angezeigt wird, ist dieses wie die Zeichnung in SolidWorks geöffnet. Das Dokument ist eben nur nicht sichtbat.
Genau das können wir in der Schleife abfragen:

Code:

---

Sub main()
    'SolidWorks belegen
    Set oSwApp = Application.SldWorks
    'Erstes Dokument belegen
    Set oModelDoc = oSwApp.GetFirstDocument
    'Mal schauen was alles offen ist und die Dokumente drucken
    Do While Not oModelDoc Is Nothing
        Debug.Print (oModelDoc.GetPathName)
        'Nur sichtbare Dokumente drucken
        If oModelDoc.Visible Then
            'Dokument in SolidWorks aktivieren
            oSwApp.ActivateDoc (oModelDoc.GetTitle)
            'Dokument auf den Standarddrucker Drucken
            oModelDoc.PrintDirect
        End If
        'Nächstes Dokument
        Set oModelDoc = oModelDoc.GetNext
    Loop
End Sub

---

Und siehe da, es werden nur noch sichtbare Dokumente gedruckt!

------------------
Mfg Daniel

Lesen ist super. Nur die Buchstaben machen einen verrückt!
------------------

SolidWorks Programmierung | Tools | Makros | Software; Schuler Design Automation GmbH

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

PERFEKT!!!! 
Ü's wurden soeben transferiert!

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe mir erlaubt, das Makro um ein Force.Rebuild zu ergänzen 

Code:

---

' http://ww3.cad.de/foren/ubb/Forum2/HTML/012488.shtml
' tbd - Mitglied - Softwareentwickler / Konstrukeur

Dim oSwApp As SldWorks.SldWorks
Dim oModelDoc As SldWorks.ModelDoc2
Dim bRet As Boolean

Sub main()
   
    'SolidWorks belegen
    Set oSwApp = Application.SldWorks
   
    'Erstes Dokument belegen
    Set oModelDoc = oSwApp.GetFirstDocument
   
    'Mal schauen was alles offen ist und die Dokumente drucken
    Do While Not oModelDoc Is Nothing
        Debug.Print (oModelDoc.GetPathName)
       
        'Nur sichtbare Dokumente drucken
        If oModelDoc.Visible Then
           
            'Dokument zwingen sich neu aufzubauen
            bRet = oModelDoc.ForceRebuild3(False)
       
            'Dokument in SolidWorks aktivieren
            oSwApp.ActivateDoc (oModelDoc.GetTitle)
           
            'Dokument auf den Standarddrucker Drucken
            oModelDoc.PrintDirect
        End If
       
        'Nächstes Dokument
        Set oModelDoc = oModelDoc.GetNext
    Loop
End Sub

---

------------------

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP