---

Guten Morgen Zusammen,
Ich hab eine Frage zu meinem ersten "richtigen" API Programm
Wie kann ich per API in einer Drawing die Anzahl der Ansichten feststellen, und dann auch noch eine bestimmte auswählen? Also es sind z.B 5 Ansichten auf einem Blatt und will die 3. auswählen!
Über einen Hinweis oder ein paar Zeilen Code würde ich mich freuen, da ich im Moment ziemlich auf dem Schlauch sitze!

Vielen Dank im Voraus

Gruß
gismo

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi gismo,

um die Anzahl rauszukriegen mußt du einen Loop über alle Views machen. Dabei mußt du bedenken, dass das Blatt selbst immer (?) der erste View ist. um später eine bestimmte Ansicht zu aktivieren läufst du dann wieder die Schleife ab, bist du den View mnit dem passenden Namen hast.

Als Basis kannst du eine einfache Schleife nehmen:

Code:

---

Dim swApp As Object
Dim DrawingDoc as Object
Dim View as Object
Dim ViewName as String
Dim ViewCount as Long
Dim meldung as String

Sub main()
' erstmal SolidWorks ansprechen
Set swApp = CreateObject ("SldWorks.Application")

' an aktives Dokument anklinken, ggf. prüfen ob es auch eine
' Zeichnung ist, sonst abbrechen
Set DrawingDoc = swApp.ActiveDoc

' der erste View ist immer das Blatt selbst
Set View = DrawingDoc.GetFirstView

' zum durchblättern den Namen des Views mit dem gemerkten
' vom letzten View vergleichen, ansonsten den nächsten aufrufen

While View Is Not Nothing
' Namen des aktuellen Views merken
ViewName = View.Name
meldung = meldung & chr$(13) & chr$(10) & ViewName
ViewCount = ViewCount + 1
' nächster View aufrufen
Set View = View.GetNextView
Wend
Call Msgbox(meldung & chr$(13) & chr$(10) & "Anzahl: " & ViewCount)
End Sub

---

Ich hoffe du kommst damit einen Schritt weiter, ciao

Stefan

------------------
--
Inoffizielle Solidworks Hilfeseite
http://solidworks.cad.de
EMail: Stefan.Berlitz@solidworks.cad.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke Stefan,
es ist schon klasse, wie Du sowas aus dem Ärmel schüttelst.
Ich hab mir den ganzen Vormittag den Kopf zerbrochen, dabei ist das doch so einfach !!

Grüsse aus dem sonnigen Schwarzwald und
tschüss bis zum nächsten Problem

gismo

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,
ich bins nochmal. Stefan, Dein Beispiel funktioniert tadellos. Allerdings nur in einem Makro. Ich hab den Code in in ein VB6 Projekt eingefügt... und es tut sich nichts. Das Programm findet keine Ansichten
Vielleicht hab ich auch nur einen Fehler in meinem Code:

Dim ViewName As String
Dim View As Object
Dim ViewCount As Long
Dim Meldung As String
Dim SwApp As Object
Dim ModelDoc As Object
Dim DrawingDoc As Object

'Deklarationen aus der swconst.bas
Public Enum swDocumentTypes_e
swdocPart = 1
swDocASSEMBLY = 2
swdocDrawing = 3
End Enum

Private Sub Command1_Click()

'An das aktive Solidworks-Modell anklinken. Wenn noch kein SWX
'lief, wird eins geladen

Set SwApp = CreateObject("SldWorks.Application")

'Session sicherheitshaber sichtbar machen

SwApp.Visible = True
Set DrawingDoc = SwApp.activedoc

'wenn nichts geladen ist direkt wieder raus

If DrawingDoc Is Nothing Then
Call MsgBox("Keine Datei geöffnet!", vbOKOnly)
Exit Sub
End If

'jetzt überprüfen, ob das aktive Dokument eine Drawing ist

If DrawingDoc.gettype() <> swdocDrawing Then

'Keine Drawing, keine Arbeit

Call MsgBox("Aktives Dokument ist keine Drawing", vbOKOnly)
Exit Sub
End If

'der erste View ist das Blatt selbst

Set View = DrawingDoc.GetFirstView

'jetzt Ansichten zählen

While View Is Nothing
'Namen des aktuellen views merken
ViewName = View.Name
Meldung = Meldung & Chr$(13) & Chr$(10) & ViewName
ViewCount = ViewCount + 1
'nächsten view aufrufen
Set View = View.GetNextView
Wend
Call MsgBox(Meldung & Chr$(13) & Chr$(10) & "Anzahl: " & ViewCount)
End Sub

Danke fürs Reinschauen

Gruß
gismo

[Diese Nachricht wurde von gismo am 09. Juli 2001 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi gismo,

du hast beim Loop das Not vergessen:

Code:

---

...
While Not View Is Nothing
...

---

Frag mich nicht, warum in VB das Not vorne sein muss und im Makro hinten sein darf ...

Ciao,
Stefan

------------------
--
Inoffizielle Solidworks Hilfeseite
http://solidworks.cad.de
EMail: Stefan.Berlitz@solidworks.cad.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke Stefan,
Du bist einfach der beste
Tschüssle
gismo

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ist schon erstaunlich, was hier mittlerweile abgeht.
Das nenne ich Support und Schulung gleichzeitig, und dann auch noch kostenlos. Wo kriegt man das heute noch....

Armin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP