---

Hallo zusammen,

ich bin gerade dabei, Rahmen zu ändern. Ich weiß, dass in einigen Schriftfeldern Texte mit Verhältnis Breite/Höhe 0,8 drin sind, die aber eigentlich 1 sein sollten. Diese Texte sind jedoch nur mit einem Leerzeichen im Rahmen (dienen als Platzhalter und Vorlage). Gibt es eine Möglichkeit mir Infos von den Texten im Screen anzeigen zu lassen, ohne dass ich jeden Text editieren und ein Buchstabe/Wort schreiben muss?
Ich meine schonmal gelesen zu haben, dass es geht, finde es aber nicht mehr.

Vielen Dank.

Knuddeligen Gruß 

------------------
Das Leben ist kurz, weniger wegen der kurzen Zeit, die es dauert, sondern weil uns von dieser kurzen Zeit fast keine bleibt, es zu genießen! 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Knuddel

unten zwei Makros, die Dir Eigenschaften von Texten auslesen.
Beim ersten Makro musst Du den Text antippen, über den Du etwas erfahren willst.
Beim zweiten Makro kannst Du mehrere mit einem Rahmen auswählen.

DEFINE eva_test_1
LOCAL P
LOCAL TFormat
LOCAL TZeilenabstand
LOCAL TRatio
LOCAL TGroesse
LOCAL TNeigung
LOCAL TWinkel
LOCAL TFont1
LOCAL TFont2
LOCAL TRahmen
LOCAL TFuellung
LOCAL Textstring1
LOCAL Textstring2
  READ 'Punkt antippen' P
  INQ_ELEM P
  IF (INQ 403= TEXT)
    LET TFormat (INQ 3)
    LET Tzeilenabstand (INQ 4)
    LET TRatio (INQ 5)
    LET TGroesse (INQ 6)
    LET TNeigung (INQ 7)
    LET TWinkel (INQ 8)
    LET TFont1 ('"'+STR(INQ 302)+'"')
    LET TFont2 ('"'+STR(INQ 303)+'"')
    LET TRahmen (INQ 601)
    LET TFuellung (INQ 602)
    LET TextString1 ('"'+(STR(INQ 902))+'"')
    LET TextString2 ('"'+(STR(INQ 903))+'"')
    DISPLAY(Textstring1 + ' Ratio ' + STR TRatio + ' Groesse ' + STR TGroesse)
  END_IF
END_DEFINE

DEFINE eva_test_2
LOCAL P_ul
LOCAL P_or
LOCAL TFormat
LOCAL TZeilenabstand
LOCAL TRatio
LOCAL TGroesse
LOCAL TNeigung
LOCAL TWinkel
LOCAL TFont1
LOCAL TFont2
LOCAL TRahmen
LOCAL TFuellung
LOCAL Textstring1
LOCAL Textstring2
  READ 'Punkt unten links antippen' P_ul
  READ 'Punkt oben rechts antippen' RUBBER_BOX P_ul P_or
  INQ_SELECTED_ELEM SELECT BOX P_ul P_or CONFIRM END
  LOOP
    EXIT_IF (INQ 14=0)
    IF (INQ 403= TEXT)
      LET TFormat (INQ 3)
      LET Tzeilenabstand (INQ 4)
      LET TRatio (INQ 5)
      LET TGroesse (INQ 6)
      LET TNeigung (INQ 7)
      LET TWinkel (INQ 8)
      LET TFont1 ('"'+STR(INQ 302)+'"')
      LET TFont2 ('"'+STR(INQ 303)+'"')
      LET TRahmen (INQ 601)
      LET TFuellung (INQ 602)
      LET TextString1 ('"'+(STR(INQ 902))+'"')
      LET TextString2 ('"'+(STR(INQ 903))+'"')
      DISPLAY(Textstring1 + ' Ratio ' + STR TRatio + ' Groesse ' + STR TGroesse)
    END_IF
    INQ_NEXT_ELEM
  END_LOOP
END_DEFINE

Gruß Robert

------------------
Homepage: www.me10-makros.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Knuddel,

hier noch eine Variante, bei der bei den gewählten Texten
das Breiten-Höhen-Verhältnis auf 1 geändert wird,
wenn das Verhältnis Breite/Höhe ungleich 1 ist.
Falls Du andere Werte ändern willst, dürfte das Abändern
des Makros kein großes Problem sein.

DEFINE eva_test_3
LOCAL P_ul
LOCAL P_or
LOCAL TFormat
LOCAL TZeilenabstand
LOCAL TRatio
LOCAL TGroesse
LOCAL TNeigung
LOCAL TWinkel
LOCAL TFont1
LOCAL TFont2
LOCAL TRahmen
LOCAL TFuellung
LOCAL Textstring1
LOCAL Textstring2
  READ 'Punkt unten links antippen' P_ul
  READ 'Punkt oben rechts antippen' RUBBER_BOX P_ul P_or
  INQ_SELECTED_ELEM SELECT BOX P_ul P_or CONFIRM END
  LOOP
    EXIT_IF (INQ 14=0)
    IF (INQ 403= TEXT)
      LET TFormat (INQ 3)
      LET Tzeilenabstand (INQ 4)
      LET TRatio (INQ 5)
      LET TGroesse (INQ 6)
      LET TNeigung (INQ 7)
      LET TWinkel (INQ 8)
      LET TFont1 ('"'+STR(INQ 302)+'"')
      LET TFont2 ('"'+STR(INQ 303)+'"')
      LET TRahmen (INQ 601)
      LET TFuellung (INQ 602)
      LET TextString1 ('"'+(STR(INQ 902))+'"')
      LET TextString2 ('"'+(STR(INQ 903))+'"')
      IF (TRatio <> 1)
        TRAP_ERROR
          CHANGE_TEXT_RATIO 1 (INQ 101) END
        IF (CHECK_ERROR)
          DISPLAY('Fehler: Text ' + Textstring1 + ' konnte nicht geaendert werden')
        END_IF
      END_IF
    END_IF
    INQ_NEXT_ELEM
  END_LOOP
END_DEFINE

Gruß Robert

------------------
Homepage: www.me10-makros.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Knuddel,

hat sich die Sache erledigt ?

Gruß
Robert

------------------
Homepage: www.me10-makros.de

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP