---

Hallo,

ich bin totaler OSDD-Neuling und habe mich in den letzten Tagen durch das Forum gekämpft, aber noch keine konkrete Lösung für mein Problem gefunden. Ich möchte eine Zeichnung aus Catia V5 als DXF exportieren und im OSDD mittels eines kleinen Makros aufbereiten.

weiße gestrichelte Linien --> grün
weiße strichpunktierte Linien --> gelb
Texte --> Schriftart 'hp_d17_v'
Bemaßungstexte --> gelb
Maßlinien --> grün
Stift- & Linienstärke --> 0

In einem Teil hab ich das schon teilweise hinbekommen, allerdings ist es mühsam das Makro in jedem einzelnen Teil auszuführen. Für Lösungsansätze und Hinweise wäre ich sehr dankbar.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

das Makro ist nicht getestet.

DEFINE Change_dxf

  LOCAL Zaehler
  LOCAL Z_max
  LOCAL Teil

  EDIT_PART TOP

  { GEO }
  DISPLAY_NO_WAIT "Geometrie-Farbe wird geÌndert. Bitte warten!"

  {weiße gestrichelte Linien --> grün }
  CHANGE_COLOR GREEN SELECT GLOBAL DASHED AND WHITE CONFIRM END

  { weiße strichpunktierte Linien --> gelb }
  CHANGE_COLOR YELLOW SELECT GLOBAL DOT_CENTER AND WHITE CONFIRM END
 
  { Stift- & Linienstärke --> 0 }
  CHANGE_LINESIZE 0 SELECT GLOBAL ALL CONFIRM END
  CHANGE_PENSIZE 0 SELECT GLOBAL ALL CONFIRM END

  { HATCH }
  DISPLAY_NO_WAIT "Schraffur-Farbe wird geÌndert. Bitte warten!"
  CHANGE_HATCH_COLOR WHITE SELECT GLOBAL ALL CONFIRM END

  { DIMENSIONS }
  DISPLAY_NO_WAIT "Bemassungs-Farbe wird geÌndert. Bitte warten!"
  EDIT_PART TOP
  CREATE_LTAB "Teileltab"
  PARTS_LIST TREE LTAB "Teileltab"
  LET Zaehler 0
  LET Z_max (LTAB_ROWS "Teileltab")
  LOOP
    LET Zaehler (Zaehler+1)
    EXIT_IF (Zaehler>Z_max)
    LET Teil (READ_LTAB "Teileltab" Zaehler 1)
    TRAP_ERROR
    EDIT_PART Teil
    { Maßlinien --> grün }
    CHANGE_DIM_COLOR GREEN SELECT DIMENSIONS ALL CONFIRM END
    { Bemaßungstexte --> gelb }
    CHANGE_DIM_TEXTS DIM_ALL YELLOW SELECT DIMENSIONS ALL CONFIRM END
    IF (CHECK_ERROR) END_IF
  END_LOOP

  { Texte --> Schriftart 'hp_d17_v' }
  Gdm_text_font_aendern

  EDIT_PART TOP
  WINDOW FIT

END_DEFINE

DEFINE Gdm_text_font_aendern
  LOCAL Zaehler
  LOCAL Z_max
  LOCAL Teil
  EDIT_PART TOP
  CREATE_LTAB 'Teileltab'
  PARTS_LIST TREE LTAB 'Teileltab'
  LET Zaehler 0
  LET Z_max (LTAB_ROWS 'Teileltab')
  LOOP
    LET Zaehler (Zaehler+1)
  EXIT_IF (Zaehler>Z_max)
    LET Teil (READ_LTAB 'Teileltab' Zaehler 1)
    EDIT_PART Teil
    TRAP_ERROR
    CHANGE_DIM_TEXTS DIM_ALL FONT 'hp_d17_v' SELECT DIMENSIONS ALL CONFIRM END
    IF (CHECK_ERROR)
      DISPLAY_NO_WAIT 'keine Bemassung gefunden'
    END_IF
    TRAP_ERROR
    INQ_SELECTED_ELEM GLOBAL TEXTS ALL
    END
    WHILE (INQ 14)
        CHANGE_TEXT_FONTNAME 'hp_d17_v' (INQ 101) END
      INQ_NEXT_ELEM
    END_WHILE
    IF (CHECK_ERROR)
      DISPLAY_NO_WAIT 'keine Texte gefunden'
    END_IF
  END_LOOP
  EDIT_PART TOP
  WINDOW FIT
END_DEFINE

------------------
Gruß,
Peter

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Wheeli,

der Konvertierer von ME10 kann dir schon ein wenig Arbeit abnehmen. Schau dir mal die Datei dxfdwg.con im entsprechenden Verzeichnis an.
Bei einem normalen neueren ME10 ist das etwa unter
C:\Programme\CoCreate\...\dxfdwg\ (Windows)
/opt/CoCreate/.../dxfdwg/ (UX)
Das ist eine Textdatei (mit Notepad.exe oder vi (unter UX) öffnen, in der man die Übersetzungsparameter ändern kann. In der Onlinehilfe ist eine recht gute Dokumentation der einzelnen Paramter.

HTH
Roman

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Peter,

das Makro funktioniert super. Eine echte Arbeitserleichterung. Vielen Dank für die schnelle und vor allem umfangreiche Hilfe. Gibt es Anleitungen/Dokumentation zur Makroprogrammierung? Mir fehlt einfach der Einstieg und der Syntax der Befehle.

Ich würde gern noch das Makro erweitern.
Maßzahlen --> Schriftgröße 3,5
Pfeilgröße der Maßlinien --> 3,5
Abstand der Maßlinie zur Geometrie --> 0
Länge der Maßhilfslinie --> 1

@ Roman: Vielen Dank für den Hinweis. Diesen Weg der Parametervoreinstellung werde ich auch mal näher unter die Lupe nehmen.

Viele Grüße wheeli

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Wheeli,

die Syntax findest Du unter
%ProgramFiles%\CoCreate\OneSpace Drafting 2007\locale\de\me_help\me_frame.htm

eine Einführung in die Makrosprache findest du in den Drafting Manuals
\Drafting_Manual_2007\htm\german\writemac\writemac_toc.html

------------------
Gruß,
Peter

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP