---

Hallo zusammen

Ich hab mal ne Frage über die Linienattribute:

Oft ist es bei mir der Fall, dass ich eine Geo zeichne und diese dann die falsche Linienart und/oder Farbe hat. Nun hätte ich gerne, dass wenn ich z.B. mit der mittleren Maustaste auf diese Geo klicke, dass ich dann auf ein Menü gelange, wo ich die Linienfarbe und Linienart ändern kann. Klar, ich kann die Befehle direkt mit den Maustasten belegen, habe diese aber schon mit +shift und +alt Funktionen schon komplett belegt. UNd die Befehle immer auszuwählen, geht mir einfach zu lange, mit dem Tablett ging das einfach besser.

Nun meine Frage, gibt es schon irgend so eine Funktion im ME10 (was ich aber nicht glaube) oder hat schon aml jemand ein Makro dafür geschrieben???

OSDD 11.60b win-Oberfläche

Gruss aus der CH
  Thömu

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

menu.jpg

hi thömu
meinst du so etwas (siehe bild)

gruss aus dem seeland

ändu

------------------
awi
André Weidmann

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Bild.jpg

Salut

Ich hab mal dein Bild angeschaut, hast ne menge Befehle in diesem Menü. Aber wenn ich es richtig sehe, kommst du von dort dann einfach auf das normale Linienänder-Menü, für dass bräuchte ich kein zusätzliches Menü.

Ich hab mir mal ein Bild gebastelt, wie ich das ungefähr meine. (die beiden Menüs für die ausgewählte Geo gekoppelt) Was auch möglich wäre, das z.B. nur 3 Auswahlmöglichkeiten vorhanden sind: Volllinie rot, Strich-Punkt-Linie gelb und Strichlinie gelb, also die sichtbare & unsichtbare Kante und Mittellinie.

EIn kleines Makro dafür basteln, dass sollte ich schon noch selber können, aber ich hab absolut keine Ahnung mit der grafischen Gestalltung, nur schon wie man ein solches Fenster erstellt und schon gar nicht, wie man eine Auswahlliste erstellt.

Ich hab bei dir auf dem Bild noch gesehen, dass du sehr viele Icon's um das Zeichnungsfenster herum hast. Dies ist natürlich auch eine Variante, doch für mich ist das Zeichnungsfenster nur schon durch die Mausversion sehr klein, mit der win-Oberfläche geht es noch, aber im klassischen Look, naja, da kommen halt die Kompromisse zum vorschein.

mfg Thomas

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hi thömu
kopieren in ein file deiner wahl.
input dein file
rechte maustaste
auswählen farbe und linienart
button ok klicken

gruss aus finsterhennen

TOOLBAR DEL_OLD 'tlb_thomu' END
TOOLBAR_ITEM OVER_WRITE 'com_ColorCbo' CAPTION (DGETTEXT 'me10lt' 'Color Cbo') ITEM_TYPE COMBO_LIST SUBTYPE 4 CATEGORY (DGETTEXT 'me10lt' 'Mixed') ON_RIGHT_CLICK '' ADD_TO_TOOLBAR 1 END
TOOLBAR_ITEM OVER_WRITE 'com_LineCbo' CAPTION (DGETTEXT 'me10lt' 'Line Cbo') ITEM_TYPE COMBO_LIST SUBTYPE 5 CATEGORY (DGETTEXT 'me10lt' 'Mixed') ON_RIGHT_CLICK '' ADD_TO_TOOLBAR 2 END
TOOLBAR_ITEM OVER_WRITE 'btn_OK' CAPTION 'OK' ON_ACTION 'thomuAction' ADD_TO_TOOLBAR 3 END
TOOLBAR CAPTION 'thomu' FLOAT 106 158 3 VISIBLE OFF END

define thomuAction
HIGHLIGHT_PRESELECTED off
preselect geo IDx and IDy confirm
inq_env 3
change_linetype linepattern (inq 301) pre_selected end
change_color rgb_color (x_of inq 201) (y_of inq 201) (z_of inq 201) pre_selected end
preselect end
HIGHLIGHT_PRESELECTED on
TOOLBAR 'tlb_thomu' VISIBLE OFF END

line linepattern SaveLineType end
color rgb_color (x_of SaveColor) (y_of SaveColor) (z_of SaveColor) end
end_define

define_mouse_key 3 plain 'RightMouseButton_plain1'#M

DEFINE call_tlb_thomu
LOCAL Tlb
LOCAL Tlb_x
LOCAL Tlb_y
LOCAL Intcursorpos
INQ_ENV 1
LET Intcursorpos (INQ 103)
LET Tlb_x (X_OF Intcursorpos)
LET Tlb_y (Y_OF Intcursorpos)
LET Tlb 'tlb_thomu'
INQ_ENV 10
LET Tlb_y ((Y_OF INQ 106) - ((Y_OF INQ 104)+(Y_OF INQ 105)) - Tlb_y)
TOOLBAR Tlb FLOAT Tlb_x Tlb_y 5 VISIBLE ON
END
END_DEFINE

DEFINE RightMouseButton_plain1
LOCAL Inq_2
LOCAL Intcursorpos
LOCAL Intvp
INQ_ENV 1
LET Intcursorpos (INQ 103)
LET Inq_2 (INQ 2)
LET Inq_104 (INQ 104)
INQ_ELEM
PICK_VP_PNT Inq_2 Inq_104
LET Intvp (INQ 5)

IF (INQ 403<>END)
IF ((INQ 403=LINE)
OR (INQ 403=CIRCLE)
OR (INQ 403=ARC)
OR (INQ 403=FILLET))

IF (INQ 403=LINE)
let IDx (inq 101)
let IDy (inq 102)
ELSE
let IDx (inq 102)
let IDy (inq 103)
END_IF

inq_env 3
let SaveLineType (inq 301)
let SaveColor (inq 201)
call_tlb_thomu
END_IF
END_IF
END_DEFINE

------------------
awi
André Weidmann

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hey André

Super, das Makro sieht echt toll aus. Ich wäre gar nicht auf diese einfache Lösung gekommen, ich hatte etwas komplizierteres im Kopf.

Aber leider habe ich ein Problem damit, mein ME10 erkennt den Befehl HIGHLIGHT_PRESELECTED nicht. Ist es möglich, dass dieser Befehl auf Version 11.60b noch gar nicht vorhanden ist??

Das Makro läuft sonst super (wenn ich HIGHLIGHT_PRESELECTED ausklammere), dass ist genau das, was ich mir vorgestellt habe. Mit HIGHLIGHT_PRESELECTED würde ja sonst das Ausgewählte Element noch sichtbar dargestellt, oder???

mfg Thömu

[Diese Nachricht wurde von Thömu am 04. Jun. 2004 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hi thömu

ja das kannst du weglassen. dient nur dazu das man sieht was ausgewähltworden ist. verschindet sowieso wenn man den befehl preselect noch einmal aufruft.

gruss aus dem seeland

------------------
awi
André Weidmann

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Ich habe es bereits so eingebaut, ohne das preselect.

Ich weiss nicht, aber ich denke, damit hast du nicht nur mir geholfen, sondern auch ein paar anderen Konstrukteuern auf der ganzen weiten Welt.

Nochmals, besten dank aus der mitlerweilen fast sonnigen Innerschweiz.

mfg Thömu

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP