---

Hallo zusammen,

wie ist es möglich per Makro (die erste Zeile) aller Texte in der geladenen Zeichnung abzugreifen.

Wäre echt super wenn Ihr mir helfen könntet.

Gruss - Tilman

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hallo,

INQ_SELECTED_ELEM SELECT GLOBAL TEXTS ALL CONFIRM
LOOP
EXIT_IF (INQ 14 = 0)
  DISPLAY (INQ 902)
  LOOP
    LET zweite (INQ 903)
  EXIT_IF (INQ 903 = "END-OF-LIST")
    DISPLAY zweite
  END_LOOP
  INQ_NEXT ELEM
END_LOOP

Mit der zweiten LOOP erhälst Du sogar die nächsten Zeilen.

Grüsse aus dem Schwarzwald : :
Andreas Baumgartner

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

herzlichen Dank.
Das war genau das was ich brauchte!

Gruss - Tilman

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo zusammen,

aufgrund des Tipp von H.Baumgartner konnte ich die Makroprozedur
erstellen.

Seltsames gibt es jedoch zu beobachten:
Schreibe ich alle enthaltenen Texte (nur jeweils die 1. Zeile)
in eine Datei und vergleiche den Unterschied bei der ME10-Version
10.5 contra 11 dann fehlt da einiges an Text.

Der fehlende Textblock ist in der Mitte der Datei.
Lösche ich gar Bestandteile der Zeichnung wird anschl. mehr Text gefunden!
Was macht ME10-V11 (mit akt. Patch) hier? Buggi-Version?

Vielleicht weiss ja einer Rat von Euch.

Gruss - Tilman

Hier mein Makro (gekürzt):

DEFINE KOT_WRITE_TEXT
INQ_SELECTED_ELEM SELECT GLOBAL TEXTS ALL CONFIRM
LET Kot_inforows (INQ 14)
IF (Kot_inforows>0)
DISPLAY_NO_WAIT 'Die Sache ist am kochen...'
LET Kot_file_name 'C:\Temp\Z-Text.txt'
OPEN_OUTFILE 1 DEL_OLD Kot_file_name
WRITE_FILE 1 ('Hier der Textinhalt (jeweils 1. Zeile) der Zeichnung'+(CHR 13))
LOOP
EXIT_IF (INQ 14 = 0)
  WRITE_FILE 1 ((INQ 902)+(CHR 13))
  INQ_NEXT_ELEM
END_LOOP
CLOSE_FILE 1
LET Kot_Startcode (WINEXEC ('Notepad.exe "'+Kot_file_name+'"'))
IF (Kot_Startcode<>NO_ERROR)
  BEEP
  EDIT_FILE Kot_file_name
END_IF
ELSE
  DISPLAY 'Kein Text auf Zeichnung vorhanden'
END_IF
END_DEFINE

KOT_WRITE_TEXT

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hallo,
wo soll da ein Problem sein. Ich habe Dein Makro so ähnlich an meinem ME10-PC programmiert und  es läuft doch unter ME10-V10 wie auch unter V11. Ich stelle hier keine Unterschiede zwischen V10 und V11 fest.

Sicherlich nicht Ursache Deines Prolbems, dennoch denke ich, Du solltest lokale Variablen definieren. Mir ist auch unklar, warum Du hinter jede Zeile ein (chr 13) gestellt hast. Ich veranstalte zwar ME10-Makrokurse und Workshops, bin aber gerne bereit auch zu lernen.

define ab_txt
  local startcode
  local datei

  let datei ("ab_texte.txt")
  inq_selected_elem select global texts all confirm
  if (inq 14 >0)
    open_outfile 1 del_old datei
    write_file 1 ('Hier der Textinhalt (jeweils 1. Zeile) der Zeichnung')
    loop
    exit_if (inq 14 = 0 )
      write_file 1 (inq 902)
      inq_next_elem
    end_loop
    close_file 1
    let startcode (WINEXEC ('Notepad.exe "' + datei +'"'))
    if (startcode = ERROR)
      edit_file datei
    end_if
  else
    display "kein Text in Zeichnung vorhanden"
  end_if
end_define

Güsse aus dem Schwarzwald 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

zu meinem beschriebenen Problem, daß eben nicht alle Texte gefunden werden:

Wie mir von CoCreate bestätigt wurde ist es ein Fehler in der Software.
Es wird zur Zeit daran gearbeitet und beim nächsten Patch behoben sein.

Gruss - Tilman

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo an Alle,

kann jemand o.g. Macro so ergänzen das es auch mehrzeilige Texte ausliest. Ich bin leider kein Me10 Macroprofi und bräuchte daher Hilfe.

Gruß Steffen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Bitte sehr

Code:

---

DEFINE Ab_txt
  LOCAL Startcode
  LOCAL Datei
  LET Datei ('ab_texte.txt')
  INQ_SELECTED_ELEM SELECT GLOBAL TEXTS ALL CONFIRM
  IF (INQ 14>0)
    OPEN_OUTFILE 1 DEL_OLD Datei
    WRITE_FILE 1 ('Hier der Textinhalt der Zeichnung')
    LOOP
    EXIT_IF (INQ 14=0)
      WRITE_FILE 1 (INQ 902)
      LOOP
      EXIT_IF (INQ 903='END-OF-LIST')
        WRITE_FILE 1 (INQ 903)
      END_LOOP
      INQ_NEXT_ELEM
    END_LOOP
    CLOSE_FILE 1
    LET Startcode (WINEXEC ('Notepad.exe "'+Datei+'"'))
    IF (Startcode=ERROR)
      EDIT_FILE Datei
    END_IF
  ELSE
    DISPLAY 'kein Text in Zeichnung vorhanden'
  END_IF
END_DEFINE

---

------------------
Gruss Friedhelm

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank

10 units sind unterwegs.

Gruß Steffen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Friedhelm,

habe in meiner Zeichnung unter anderem diesen mehrzeiligen Text.

- required ambient temperatures for chamber,
  and switch cabinet and air dryer : min.+10<Degree>C/max.+25<Degree>C
- temperature conditioning of the
  installation/machine/control room by customer

ausgeben wird aber nur dies.

Hier der Textinhalt der Zeichnung
- required ambient temperatures for chamber,
- temperature conditioning of the
END-OF-LIST

Irgend eine Ahnung an was das liegt. Wir benutzen die V17 M40.

Gruß Steffen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Entschuldige den "Kunstfehler" 
Wenn man die INQ 903 für die EXIT_IF Abfrage benutzt ist die Zeile ja weg.
Jetzt müsste es gehen.

Code:

---

DEFINE Ab_txt
  LOCAL Startcode
  LOCAL Datei
  LOCAL Str_2
  LET Datei ('ab_texte.txt')
  INQ_SELECTED_ELEM SELECT GLOBAL TEXTS ALL CONFIRM
  IF (INQ 14>0)
    OPEN_OUTFILE 1 DEL_OLD Datei
    WRITE_FILE 1 ('Hier der Textinhalt der Zeichnung')
    LOOP
    EXIT_IF (INQ 14=0)
      WRITE_FILE 1 (INQ 902)
      LOOP
        LET Str_2 (INQ 903)
      EXIT_IF (Str_2 ='END-OF-LIST')
        WRITE_FILE 1 (Str_2)
      END_LOOP
      INQ_NEXT_ELEM
    END_LOOP
    CLOSE_FILE 1
    LET Startcode (WINEXEC ('Notepad.exe "'+Datei+'"'))
    IF (Startcode=ERROR)
      EDIT_FILE Datei
    END_IF
  ELSE
    DISPLAY 'kein Text in Zeichnung vorhanden'
  END_IF
END_DEFINE

---

------------------
Gruss Friedhelm

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Friedhelm,

jetzt geht`s. Super.
Nochmals vielen Dank

Viele Grüße

Steffen

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP