Code:
finish
/clearpi = 3.1416
endzeit = 1/1000 ! 1000 Hz
schritte= 4
Strom = 1000
S_Ri = 10e-3 ! Spule: Radius innen
S_Ra = 20e-3 ! Spule: Radius außen
S_H = 60e-3 ! Spule: Höhe
L_R = 200e-3 ! Luft-Radius
Abst = 5e-3 ! Abstand Platte Spule
P_R = 100e-3 ! Runde PLatte: Radius
P_H = 15e-3 ! Höhe der Platte
A_Wi = (S_Ri-S_Ra)*S_H ! Wicklungsquerschnitt
St_D = Strom/A_Wi ! Stromdichte
elLF1 = 1/57e6 ! eletr. Leitfähigkeit CU
elLF2 = 1/10e6 ! eletr. Leitfähigkeit Fe
elLF3 = 1/37e6 ! eletr. Leitfähigkeit Al
/prep7
et,1,233,,,1,,1 ! Element 1 AZ (asy) LUFT
et,2,110,,,1 ! Element 2 Infin (asy) RAND
et,3,233,1,,1,,1 ! Element 3 AZ,volt (asy) SPULE
et,4,233,1,,1 ! Element 4 AZ,volt (asy) PLATTE
mp,murx,1,1 ! Material 1 CU
mp,mury,1,1
mp,rsvz,1,elLF1
mp,murx,3,1 ! Material 3 Luft
mp,mury,3,1
mp,murx,4,1 ! Material 4 Al
mp,mury,4,1
mp,rsvz,4,elLF3
pcirc,L_R,,0,90 ! LUFT A5
rectng,S_Ri,S_Ra,0+Abst+P_H,S_H+Abst+P_H ! SPULE A2
rectng,0,P_R,0,P_H ! PLATTE A4
aovlap,all
mshape,0 ! Mesh Spule
esize,2e-3
type,3
mat,1
amesh,2
esize,0.5e-3 ! Mesh Platte
type,4
mat,4
amesh,4
esize,5e-3 ! Mesh Luft
type,1
mat,3
amesh,5
csys,1 ! INF auf Rand
nsel,s,loc,x,L_R
esln
emodif,all,type,2
sf,all,inf
csys,0
esel,s,type,,3 ! SPULE
nsle,s
cp,1,volt,all
*get,n1,node,,num,min
allsel
esel,s,type,,4 ! PLATTE
nsle,s
cp,2,volt,all
allsel
/solu
antype,trans
outres,all,all
*do,i,0,Schritte,1
time,i*Endzeit/Schritte+1e-15
arg=sin(2*pi*i/Schritte)
f,n1,amps,Strom*arg
solve
*enddo
/post1
!esel,s,type,,4
!/dist,1,(0.75*(P_R/2)),0
!/focus,1,(P_R)/3,P_H/2
/seg,multi
*do,zeit,endzeit/schritte,endzeit,endzeit/schritte
set,,,,,zeit
etable,jz,nmisc,1
pletab,jz,avg
*enddo
anim,,1,1