---

Hallo,

ich sitze zur Zeit an meinem FEM-Beleg und arbeite mich deswegen gerade in ANSYS ein.

Meine Aufgabe ist es auf den äußeren Rand einer Kreisringplatte ein Streckenmoment aufzutragen und den Ort der maximalen Spannung zu berechnen. Die Geometrie habe ich mittlerweile auch komplett erstellt. Jetzt muss ich mir ja ein ELEMENT suchen, mit dem gerechnet werden soll. Ich finde aber keines, bei den man Streckenmomente als Lasten angeben kann. Gibt es sowas vll garnicht?

Ich hatte vorher noch die Idee nur einen Teil der Kreisringplatte zu berechnen (in dem Kreisring sind noch gleichverteilt 3 Löcher). Nun muss man da ja Randbedingungen an den Schnitten festlegen. Meiner Meinung nach muss die Verschiebung senkrecht zum Schnitt =0 sein. Die Verschiebung in x- oder y-Richtung gleich 0 zu setzen bekomme ich ja hin aber wie mache ich das, wenn meine Kante schräg verläuft?

Vielen Dank schonmal 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

1. Streckenmoment
Randbedingungen, also auch Momente werden auf die Knoten aufgebracht. Der Befehl dazu heißt f,... Beachte, dass die aufgebrachten Momente im Knotenkoordinatensystem sind. Möglicherweise ist es günstig die Knotenkoordinatensysteme in ein zylindrisches Koordinatensystem zu drehen. Als Elemente kommen demnach prinzipiell alle strukturellen Elementtypen in Frage.

2. Symmetrie
In der WB kannnst Du einfach alle Freiheitsgrade senkrecht zu einer Fläche Null setzen. In der Classic ist es oft nötig, ein lokales Koordinatensysstem festzulegen, um bestimmte Randbedingungen aufzubringen.

Stichworte: local, clocal, cs, cswpla, csys, f, d

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe mal versucht alles so weit wie mir möglich war umzusetzen, wobei ich immer noch an ein paar Stellen hänge bzw. mir nicht sicher bin, ob das so passt.

Hier einfach mal mein Inputfile, wie er bis jetzt aussieht mit ein paar Kommentaren:

Code:

---

/prep7 !startet den Preprocessor

R1=200 !Eingabewerte für meine Geometrie in [mm]
R2=50
R3=160
D=40
H=8

M1=800 !Streckenmoment in [N]

E=2*10**5 !E-Modul in [N/mm^2]
V=0.3 !Querkontraktionszahl

!erstellt meinen Kreisscheiben auschnitt und die Bohrung
cyl4,0,0,R1,0,R2,60
cyl4,r3,0,D/2

!zieht Bohrung von der Kreisscheibe ab
asba,1,2

et,1,shell63 !definiert mein Elementtyp (sinnvoll?!)
mp,ex,1,E !E-Modul festlegen (muss ich das auch für ey und ez!?)
mp,prxy,1,V !Querkontraktionszahl festlegen (andere Richtungen?!)

!Real-Set ... hier bin ich aus der Hilfe nicht ganz schlau geworden.
!Ich vermute, ich habe hiermit die Dicke meiner Platte definiert.
r,1,H,H,H,H

!Freiheitsgrade ... Translation und Rotation in allen Richtungen
dof,ux,uy,uz,rotx,roty,rotz

esize, 10 !Platte vernetzen
amesh, all

!innerer Rand selektiert und als gelenkige Lagerung definiert
lsel,s,,,3
dl,all,,ux,0
dl,all,,uy,0
dl,all,,uz,0

!Schnittkante in eine Richtung und Freiheitsgrade
lsel,s,,,9,10
dl,all,,uy,0
dl,all,,rotx,0
dl,all,,rotz,0

!Hilfskoordinatensystem für die 2. Schnittkante bei 60°
local,11,0 ,0,0,0, 60,

!Freiheitsgrade werden hier definiert (warum nutzt ANSYS globales

Koordinatensysem?!)
lsel,s,,,2
dl,all,,uy,0
dl,all,,rotx,0
dl,all,,rotz,0

!alle Linien wieder auswählen
lsel,all

finish

!Lösungsprozessor starten
/solu

!in zylinderkoordinaten gehen
csys,1

!Nodes am äußeren Rand der zylinderscheibe auswählen (Kann man sagen "alle Nodes an Linie soundso auswählen"?!)
nsel,s,,,1,22

!Last aufbringen
!"M1/132", da 22 Punkte auf dem rand und das 1/6 des Umfangs ist
f,all,my,M1/132

solve

finish

---

Wie du siehst, sind da noch ein paar Sachen:
1. wieso nutzt ANSYS das globale Koordinatensystem, obwohl ich ein lokales definiert habe?
2. Beim Festlegen der Last möchte ich ja eigentlich, dass das Moment um die Tangente wirkt. Wie genau mach ich das? Muss ich da für jeden Punkt ein eigenes lokales Koordinatensystem definieren?
3. Passt das mit dem Real-Set? Wie gesagt, aus der Hilfe werde ich nicht schlau und in den Beispielen und Tutorials, die ich bis jetzt gefunden hab werden fast nur Balkentragwerke behandelt.

Um das postprocessing hab ich mich jetzt noch nicht gekümmert.

Ich würde mich sehr freuen, wenn da mal jemand drüber schaut 

Vielen Dank

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hallo dennyc

reals sind soweit ok. kannst aber auf r,1,DICKE reduzieren. ansys ist so schlau, dass die dicke am ersten knoten für die weiteren übernommen wird

dof kommando brauchst du an der stelle (glaube ich) nicht

um knoten auf ringen anzuwählen, via local ein zylinder-ko-system bauen ( bei dir auf 0,0,0) oder das vordefinierte  csys,1 wählen und dann
nsel,s,loc,x,AUSSEN_RADIUS  bzw nsel,s,loc,x,INNEN_RADIUS. (x=radius,y=winkel,z=höhe in zylinder-koord)

bzw um die radialen kanten anzuwählen (*afun,deg nicht vergessen)
nsel,s,loc,y,0
nsel,s,loc,y,60

zum neu-wählen vorher ein alls  (=allsel) einfügen, um bei der auswahl wieder "from full" zu sein. ( ist bei diesem kleinen modell nicht unbedingt erforderlich, aber wenns demnächst größere modelle gibt, ist das ganz sinnvoll)

wegen der momente: du willst doch eine art "umkrempel-moment" um den äußeren ring, oder? nrotat ist eine variante und die befehle von arnd. wenn das nicht hinhaut, meld dich nochmal

postprocessing (hilfe: 2.7 post1 command reference)
pldisp,1 oder ,2 oder ,3
/dscale... überhöhungsfaktor
plnsol,  plot nodal solu
prnsol,
prrsol,
und natürlich *get-befehle -> postprocessing entity items
rsys schaltet die ergebnisausgabe zwischen den vorher definierten ko-systemen hin und her

na dann: lock'n'load

gruß
ral

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke für die Antwort zu so später Stunde 

Das meiste ist mir jetzt klar. Allerdings weiß ich immer noch nicht, wie ich die Randbedingungen an der radialen Kante im 60°-Winkel mache. Dafür sollte ich ja idealerweise auch ein lokales Koordinatensystem nutzen aber das scheint er nicht zu machen.

Umkrempelmoment ist mal nen anschaulicher Name 
ich habe shcon oft überlegt, wie ich das möglichst gut beschreibe, was das da ist 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Die Randbedingungen werden im Konotenkoordinatensystem definiert. Du müsstest also die Knotenkoordinatensysteme noch in das lokale Koordinatensystem drehen:

NROTAT, NODE1, NODE2, NINC
Rotates nodal coordinate systems into the active system

Achtung: Auch die aufgebrachten Kräfte werden im Knotenkoordinatensystem definiert. Es reicht also nicht, einfach nur ein lokales Koordinatensystem zu definieren, sondern man muss immer auch die Knotenkoords drehen, wenn man Randbedingungen aufbringen will.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

ahh, ich glaube, ich habe nen passenden Befehl gefunden: dsym

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Dsym greift auch auf den nrot-Befehl zurück. Achte darauf, dass die Kräfte und Momente im Knotenkoordinatensystem aufgebracht werden.

Viel Spaß noch mit APDL!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hier nochmal der aktuelle Input-File

Code:

---

/prep7 !startet den Preprocessor

R1=200 !Eingabewerte für meine Geometrie in [mm]
R2=50
R3=160
D=40
H=8

M1=800 !Streckenmoment in [N]

E=2*10**5 !E-Modul 2*10^5 N/mm^2
V=0.3 !Querkontraktionszahl

!erstellt meinen Kreisscheiben auschnitt und die Bohrung
cyl4,0,0,R1,0,R2,60
cyl4,r3,0,D/2

!zieht Bohrung von der Kreisscheibe ab
asba,1,2

et,1,shell63 !definiert mein Elementtyp (sinnvoll?!)
mp,ex,1,E !E-Modul festlegen (muss ich das auch für ey und ez!?)
mp,prxy,1,V !Querkontraktionszahl festlegen (andere Richtungen?!)

!Real-Set ... hier bin ich aus der Hilfe nicht ganz schlau geworden.
!Ich vermute, ich habe hiermit die Dicke meiner Platte definiert.
r,1,H,H,H,H

!Freiheitsgrade ... Translation und Rotation in allen Richtungen
dof,ux,uy,uz,rotx,roty,rotz

esize, 10 !Platte vernetzen
amesh, all

csys, 1        !gelenkige Lagerung am Innenrand
nsel,s,loc,x,R2
d,all,ux,0
d,all,uy,0
d,all,uz,0

nsel,s,loc,y,0  !Symmetriebedingungen an der einen radialen Kante
dsym,symm,y,1

nsel,s,loc,y,60 !und an der anderen
dsym,symm,y,1

nsel,s,loc,x,R1 !Knotenkoordinaten am äußeren Rand in Zylinderkoordinaten
nrotat,all

nsel,all        !wieder alle Knoten anwählen

finish

!Lösungsprozessor starten
/solu

csys,1          !Last auftragen
nsel,s,loc,x,R1
f,all,my,M1/132

nsel, all

solve

finish

/post1

---

Meiner Meinung nach sollte das jetzt so passen. Zumindest sieht das Bild in AnSYS sehr vielversprechend aus. Qualitativ sieht die Lösung auch voll in Ordnung aus, allerdings gibt er mir als maximale verschiebung 0,0015 [mm] an und ich habe vorher bei einer Kreisringplatte ohne zusätzliche Löcher 13mm berechnet ... also einige Dimensionen drüber. Muss ich die Eingabewerte in ner bestimmten Einheit machen?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hallo dennyc
damit du weisst, ob du richtig bist, als fachliteratur: "statik der flächentragwerke" von meskouris. sollte in deiner hochschul-bib zu finden sein. da ist ne herleitung für die kreisringplatte drin und im anhang sind tabellen für standardlastfälle enthalten - auch für das krempelmoment. dann kannst du dein beispiel mit nem taschenrechner prüfen. 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Das hatte ich schon gemacht 
Ich habe jetzt einfach als Einheiten für die Eingabe [m], [N] und [N/m²] statt [mm], [N] und [N/mm²] genommen. Jetzt bekomme ich auf jeden Fall deutlich sinnvollere Ergebnisse raus. Danke trotzdem 

Ich werde mich jetzt erstmal mit dem Postprocessor beschäftigen. Ich brauche auf jeden Fall die maximale Radial- und Tangentialspannung und die maximale Verschiebung + den jeweiligen Ort. 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich habe jetzt im Postprozessor diese Befehle stehen:

Code:

---

rsys,1

plnsol,s,x,2

plnsol,s,y,2

---

Das sollte doch jetzt erst die Radialspannung und dann die Tangentialspannung sein, oder?
Gibt es eine Möglichkeit nur die Spannungen z.B. auf der Oberseite ausgeben zu lassen? Auf der Unterseite sind betragsmäßig ja die selben (bzw. sehr ähnliche) Spannungen.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

So, ich wollte hier einfach nochmal meine komplette Input-Datei reinstellen. Vielleicht hilft es ja jemand anders. Ich bin mit meinem Ergebnis jetzt zufrieden 

Code:

---

/show, win32c
/filname, FEM-Beleg
/title, Kreisringplatte
/units, si
/prep7

R1=.200        !Eingabewerte für meine Geometrie in [m]
R2=.050
R3=.160
D= .040
H= .008

M1=800          !Streckenmoment in [N]
E=200000000000  !E-Modul in N/m^2

V=0.3          !Querkontraktionszahl

PI=4*atan(1) !Pi

et,1,shell63 !Berechnungselement Shell63
mp,ex,1,E
mp,prxy,1,V
r,1,H
dof,ux,uy,uz,rotx,roty,rotz

cyl4,0,0,R1,0,R2,60 !Erzeugen der Geometrie
cyl4,r3,0,D/2
asba,1,2

esize, 0.008 !Erzeugen des meshs
amesh, all

clocal,11,1,R3 !am Loch verfeinern
nsel,s,loc,x,D/2
nrefine,all,,,,2,clean

csys, 1        !gelenkige Lagerung am Innenrand
nsel,s,loc,x,R2
d,all,ux,0
d,all,uy,0
d,all,uz,0

nsel,s,loc,y,0  !Symmetriebedingungen an der einen radialen Kante
dsym,symm,y,1
nsel,s,loc,y,60 !und an der anderen
dsym,symm,y,1

allsel !alle Knotenkoordinaten in Polarkoordinaten drehen
nrotat,all
finish

/solu

csys,1          !Last auftragen
nsel,s,loc,x,R1
*get,ANZAHL,node,0,count
f,all,my,(2*PI*R1*M1)/(ANZAHL*6-6)

allsel
solve
finish

/post1

/graphics, full !volle Farbpalette Nutzen
/contour,,128
rsys,1 !Ausgabe in Polarkoordinaten
shell, top !nur die Spannung an der Oberfläche betrachten

/angle,,-60,XS,1 !Verschiebung
plnsol,u,z,2

/angle,,60,XS,1 !Radialspannung
plnsol,s,x,0

plnsol,s,y,0 !Tangentialspannung

nsel, s, loc, x, R1 !Verscheibungen am äußeren Rand
prnsol,u,z

nsel, all !Spannungen am äußeren Rand
nsel, s, loc, x, R1
prnsol,s,comp

nsel, all !Spannungen am inneren Rand
nsel, s, loc, x, R2
prnsol,s,comp

allsel

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP