Hallo liebe Ansys-Gemeinde,
ich habe ein Problem bezüglich der Kontaktbedingungen.
Ich habe zwischen den Bauteilen einen MPC-Algorithmus genutzt.
Ich möchte am Anfang die Klebeschicht mit 'ekill' ausschalten und nach
einer gewissen Zeit wieder einschalten. Dabei kommt es zum Aufklaffen des Kontaktes.
Die Rechnung erfolgt schwach gekoppelt, d.h. erst Temperaturfeldrechnung, danach Strukturrechnung.
Wenn ich ohne Birth und Death arbeite funktioniert der Kontakt....
Ich bin für jeden Hinweis dankbar.
Anbei das File:
FINISH
/CLEAR,nostart
/GRAPHICS,full !wichtig, sonst nur Spannungen-Resultate für Oberflächenknoten
/UNITS,si !Si-Einheiten
/NERR,0,99999999 !Programmabbruch von ANSYS nach 99999999 Warnungen/Fehlermeldungen
/UIS,msgpop,3 !nur Fehlermeldungen anzeigen, keine Warnungen
/PLOPTS,DATE,2 !Zeige Datum und Zeit in Legende
/TRIAD,ORIG ! Globales Koordinatenkreuz im Ursprung anzeigen
/TITLE,Diplomarbeit Aushaertung von Kleber
/FILNAME,templauf
tol_nummrg=1e-5 ! Selektiertoleranz beim Mergen
tol_select=1e-5 ! allgemeine Selektiertoleranz
r1=0 !Radius der Ziel-Geometrie
r2=0 !Radius der Ziel-Geometrie
fkn=10 !Kontaksteifigkeit in Normalenrichtung (default: 1.0)
fkt=10 !Kontaksteifigkeit in Tangentenrichtung (default: 1.0), mgl.: 1e8
ftoln=0.1 !Toleranzfaktor für Eindringung (default: 0.1)
icont=0 !Schließfaktor zu Beginn (default 0)
pinb=0.5 !für kleine Deformationen (NLGEOM,off) (default o.25),
!für große Deformationen (NLGEOM,on) (default o.5)
!beschreibt den Suchradius für die Kontaktfindung
cnof=0 !Verschiebung der Kontaktoberfläche
fkop=1 !Faktor für die Steifigkeit bei Kontaktöffnung
pmax=0 !untere Grenze für die anfängliche Durchdringung
pmin=0 !obere Grenze für die anfängliche Durchdringung
taumax=1e20 !maximale Reibspannung
cohe=0 !Kontakt-Kohäsion
tcc=0 !thermische Leitfähigkeit im Kontaktbereich
!wird bei Nutzung des MPC-Algorithmus ignoriert
gap=0
!-----Temperatur-Zeit-Funktion------------------------
anz=5
*DIM,zl1,array,anz
*DIM,tl1,array,anz
zl1(1)=0 $tl1(1)=25
zl1(2)=420 $tl1(2)=141
zl1(3)=1020 $tl1(3)=140
zl1(4)=3600 $tl1(4)=25
*STAT,zl1(1)
*STAT,tl1(1)
*DIM,zl2,array,anz
*DIM,tl2,array,anz
zl2(1)=0 $tl2(1)=25
zl2(2)=300 $tl2(2)=150
zl2(3)=1020 $tl2(3)=149
zl2(4)=1080 $tl2(4)=25
*STAT,zl2(1)
*STAT,tl2(1)
!Berechnung Wärmeübergangskoeffizienten
!Eigenschaften bei Stoffwerttemperaturen
anz=2
*DIM,spezifw,array,anz
*DIM,isobarv,array,anz
*DIM,lambda,array,anz
*DIM,kinvisk,array,anz
*DIM,pr,array,anz
spezifw(1)=1.0099e3 $isobarv(1)=2.8165e-3 $lambda(1)=2.9574e-2 $kinvisk(1)=2.1330e-5 $pr(1)=7.2266e-1 !Stoffwerttemp 82,5°C
spezifw(2)=1.0103e3 $isobarv(2)=2.7772e-3 $lambda(2)=2.9901e-2 $kinvisk(2)=2.1861e-5 $pr(2)=7.2271e-1 !Stoffwerttem 87,5°C
*STAT,spezifw(1)
*STAT,isobarv(1)
*STAT,waermel(1)
*STAT,kinvisk(1)
*STAT,pr(1)
lchar=1e-3
cstrom=20
erdbeschl=9.81
kt=1
!erzwungene Konvektion
*DIM,rey,array,anz
*DO,i,1,anz
rey(i)=(cstrom*lchar)/kinvisk(i)
*ENDDO
*STAT,rey(1)
*DIM,nu,array,anz
*DO,j,1,anz
nu(j)=0.664*(rey(j)**0.5)*(pr(j)**(1/3))*kt
*ENDDO
*STAT,nu(1)
*DIM,alpha,array,anz
*DO,k,1,anz
alpha(k)=nu(k)*(lambda(k)/lchar)
*ENDDO
*STAT,alpha(1)
!freie Konvektion
*DIM,gras,array,anz
*DO,l,1,anz
gras(l)=(1/kinvisk(l)**2)*(isobarv(l)*erdbeschl*(lchar**3)*115)
*ENDDO
*DIM,nuf,array,anz
*DO,m,1,anz
nuf(m)=kt*(0.11*((gras(m)*pr(m))**(1/3))+((gras(m)*pr(m))**0.1))
*ENDDO
*STAT,nuf(1)
*DIM,alphaf,array,anz
*DO,k,1,anz
alphaf(k)=nuf(k)*(lambda(k)/lchar)
*ENDDO
/PREP7
!Kupfer
MP,dens,3,8.9e3 ![kg/dm^3]
!MP,alpx,3,1.7e-5 ![K^-1]
MP,c,3,386 ![J/kgK]
MP,kxx,3,32.66 ![W/mK]
!Vectra LCP E820iPd
MP,dens,2,1.79e3
MP,c,2,123
MP,kxx,2,12
MP,kxx,1,5
MP,dens,1,4.4e3
MP,c,1,123
TOFFST,273.15 !Offset gegenüber absoluter Temperaturskala
SELTOL,tol_select
ET,1,solid70 !thermisch-elektrisches Koppelfeld-Volumenelement mit 8 Knoten
ET,2,targe170 !4-Knoten Zielelement für Kontaktdefinition
ET,3,conta173 !Kontaktelement ohne Mittelseitenknoten (4-Knoten-Element)
TSHAP,quad !Form der Target-Elemente quadratisch mit 4 Knoten
KEYOPT,2,5,1 !Randbedingung für Festkörper-Festkörper Kontakt
KEYOPT,3,1,2 !Freiheitsgrad TEMP
KEYOPT,3,4,2 !Lage des Kontaktfindungspunktes am Knoten in Normalenrichtung zur Kontaktoberfläche
KEYOPT,3,2,2 !Multipoint constraint - keine Iterationen nötig, spart viel Rechenzeit
KEYOPT,3,5,3 !CNOF/ICONT schließen den Spalt mit CNOF-Wert
KEYOPT,3,9,1 !anfängliche geometrische Durchdringung oder Spalt ausschließen
KEYOPT,3,12,5 !Kontakt durchgängig geklebt
R,1,r1,r2,fkn,ftoln,icont,pinb !Konstanten für die Kontaktdefinition
RMORE,pmax,pmin,taumax,cnof,fkop,fkt
RMORE,cohe,tcc
R,2,r1,r2,fkn,ftoln,icont,pinb !Konstanten für die Kontaktdefinition
RMORE,pmax,pmin,taumax,cnof,fkop,fkt
RMORE,cohe,tcc
RECTNG,0,50e-3,0,10e-3
RECTNG,0,50e-3,(10e-3)+gap,(20e-3)+gap
RECTNG,0,50e-3,(20e-3)+(2*gap),(30e-3)+(2*gap)
!kein 'glueing'
LESIZE,1,5e-3,,,
LESIZE,3,5e-3,,,
LESIZE,5,5e-3,,,
LESIZE,7,5e-3,,,
LESIZE,9,5e-3,,,
LESIZE,11,5e-3,,,
LESIZE,2,5e-3,,,0.5
LESIZE,4,5e-3,,,1.5
LESIZE,10,5e-3,,,1.5
LESIZE,12,5e-3,,,0.5
LESIZE,6,5e-3,,,
LESIZE,8,5e-3,,,
K,17,0,0,60e-3
LSTR,1,17
LESIZE,13,5e-3,,,
VDRAG,all,,,,,,13
TYPE,1
!REAL,2
MAT,3
VMESH,1
TYPE,1
!REAL,3
MAT,1
VMESH,2
TYPE,1
!REAL,4
MAT,2
VMESH,3
! Generate the target surface
ASEL,S,,,6
CM,_TARGET,AREA
TYPE,2
REAL,1
NSLA,S,1
ESLN,S,0
ESLL,U
ESEL,U,ENAME,,188,189
ESURF
CMSEL,S,_ELEMCM
! Generate the contact surface
ASEL,S,,,9
CM,_CONTACT,AREA
TYPE,3
REAL,1
NSLA,S,1
ESLN,S,0
ESURF
ALLSEL
! Generate the target surface
ASEL,S,,,14
!CM,_TARGET,AREA
TYPE,2
REAL,2
NSLA,S,1
ESLN,S,0
ESLL,U
ESEL,U,ENAME,,188,189
ESURF
CMSEL,S,_ELEMCM
! Generate the contact surface
ASEL,S,,,11
!CM,_CONTACT,AREA
TYPE,3
REAL,2
NSLA,S,1
ESLN,S,0
ESURF
ALLSEL
CNCHECK
!/PSYMB,esys,1
!----------------SOLUTION PROCESSOR-------------------------------------------------------------------------------------
/SOLU !Solution-Prozessor starten
TREF,25 !25°C Referenztemperatur
ANTYPE,trans !transiente Analyse
AUTOTS,on
EQSLV,sparse !Sparse-Gleichungslöser
OUTRES,all,all
TUNIF,25 !alle Knoten erhalten Starttemperatur 25°C
!Randbedingungen und thermische Last
ASEL,s,loc,x,0
ASEL,a,loc,x,50e-3
ASEL,a,loc,y,30e-3
ASEL,a,loc,z,0
ASEL,a,loc,z,60e-3
CM,aussen,area
!Lastfall 1
!stationaerer Anfangszustand
TIMINT,off
TIME,(zl1(1)+1e-6)
SFA,aussen,,conv,alpha(1),TL1(1)
ALLSEL
SOLVE
!Lastfall 2
TIMINT,on
AUTOTS,on
NSUBST,20,20,20
LNSRCH,auto !wird für Newton-Raphson-Verfahren benötigt
SOLCONTROL,on !optimale Werte für nichtlineare Rechnung verwenden
TIME,zl1(2)
OUTRES,all,all
SFA,aussen,,conv,alpha(1),TL1(2)
KBC,0
ALLSEL
SOLVE
!Lastfall3
TIME,zl1(3)
OUTRES,all,all
NSUBST,10,10,10
SFA,aussen,,conv,1,TL1(3)
KBC,0
ALLSEL
SOLVE
!Lastfall4
TIME,zl1(4)
OUTRES,all,all
NSUBST,10,10,10
SFA,aussen,,conv,alphaf(1),TL1(4)
KBC,0
ALLSEL
SOLVE
FINISH
SAVE
!-------------------------------------------------------------------
RESUME,templauf,db
!Strukturmechanik-Teil
!als Lasten werden die Temperaturverteilungen zugrundegelegt
/FILNAME,mechlauf
/PREP7
ETCHG,tts !Wechseln des Elemttypen von Thermischem Solid-Element auf Struktur Solid-Element
CWZDELE,1,0
ALLSEL
CWZDELE,2,0
TSHAP,quad !Form der Target-Elemente quadratisch mit 4 Knoten
KEYOPT,2,5,1 !Randbedingung für Festkörper-Festkörper Kontakt
KEYOPT,3,1,0 !Freiheitsgrade UX,UY,UZ
KEYOPT,3,4,2 !Lage des Kontaktfindungspunktes am Knoten in Normalenrichtung zur Kontaktoberfläche
KEYOPT,3,2,2 !Multipoint constraint - keine Iterationen nötig, spart viel Rechenzeit
KEYOPT,3,5,3 !CNOF/ICONT schließen den Spalt mit CNOF-Wert
KEYOPT,3,9,1 !anfängliche geometrische Durchdringung oder Spalt ausschließen
KEYOPT,3,12,5 !Kontakt durchgängig geklebt
! Generate the target surface
ASEL,S,,,6
!CM,_TARGET,AREA
TYPE,2
MAT,4
REAL,1
NSLA,S,1
ESLN,S,0
ESLL,U
ESEL,U,ENAME,,188,189
ESURF
!CMSEL,S,_ELEMCM
! Generate the contact surface
ASEL,S,,,9
!CM,_CONTACT,AREA
TYPE,3
MAT,4
REAL,1
NSLA,S,1
ESLN,S,0
ESURF
ALLSEL
! Generate the target surface
ASEL,S,,,14
!CM,_TARGET,AREA
TYPE,2
MAT,4
REAL,2
NSLA,S,1
ESLN,S,0
ESLL,U
ESEL,U,ENAME,,188,189
ESURF
!CMSEL,S,_ELEMCM
! Generate the contact surface
ASEL,S,,,11
!CM,_CONTACT,AREA
TYPE,3
MAT,4
REAL,2
NSLA,S,1
ESLN,S,0
ESURF
ALLSEL
CNCHECK
!Metall
MP,dens,3,8.9e3 ![kg/m^3]
MP,alpx,3,1.7e-5 ![K^-1]
MP,ex,3,1.3e11 ![N/m^2]
MP,nuxy,3,0.33 !dimensionslos
!Kunststoff
MP,dens,2,1.79e3
MP,ex,2,8.1e9
MP,nuxy,2,0.3
MPTEMP,1,20,40,60,80,120,150
MPDATA,alpx,2,1,25e-6,25e-6,31e-6,31e-6,35e-6,35e-6
MPDATA,alpy,2,1,67e-6,67e-6,67e-6,85e-6,108e-6,108e-6
MPDATA,alpz,2,1,65e-6,65e-6,65e-6,82e-6,82e-6,95e-6
!Kleber
MP,ex,1,8.9e9
MP,nuxy,1,.375
MP,dens,1,4.4e3
wlfc1=17.85 !WLF-Konstante C1
wlfc2=116.85 !WLF-Konstante C2
wlftr=85 !WLF-Referenztemperatur
anzpr=13 !Anzahl der Prony-Terme
!Prony-Koeffizienten Schermodul Gi
g1=0.12317
g2=0.12006
g3=0.10216
g4=0.08258
g5=0.07482
g6=0.08102
g7=0.08971
g8=0.09124
g9=0.08387
g10=0.05916
g11=0.03658
g12=0.01830
g13=0.00498
!Relaxationszeiten Schermodul Taui_G
tau1_g=2.47E-12
tau2_g=3.44E-11
tau3_g=5.33E-10
tau4_g=1.02E-08
tau5_g=2.28E-07
tau6_g=5.16E-06
tau7_g=1.00E-04
tau8_g=1.52E-03
tau9_g=2.47E-02
tau10_g=4.9978E-01
tau11_g=1.0221E+01
tau12_g=5.0781E+02
tau13_g=5.2465E+04
TB,prony,1,1,anzpr,shear !Materialnummer,Anzahl Temperaturen,Anzahl Prony-Terme
*DO,counter,1,anzpr
alpha%counter%_G=G%counter% !Prony-Koeffizienten
TBDATA,counter+(counter-1),alpha%counter%_G,Tau%counter%_G
*ENDDO
TB,shift,1,,3,1 !Shift-function
TBDATA,1,wlftr
TBDATA,2,wlfc1
TBDATA,3,wlfc2
temanz=9 ! Anzahl Materialien fuer Einschalttemperatur
offs=10 ! offset fuer Materialnummerierung
temmin=0 ! minimal vorkommende Temperatur
temmax=160 ! maximal vorkommende Temperatur
temref=-20 ! Referenztemperatur für mptemp
alpanz=9 ! Anzahl der Ersatzalphas
temgre=140 !Einschalttemperatur
alp1=5.31e-5
alp2=6.14e-5
alp3=7.52e-5
alp4=9.24e-5
alp5=1.05e-4
alp6=1.14e-4
alp7=1.21e-4
alp8=1.26e-4
alp9=1.31e-4
*SET,alpref
*DIM,alpref,array,temanz
*DO,i,1,temanz
alpref(i)=alp%i%
*ENDDO
*SET,alptem
*DIM,alptem,array,alpanz
*DO,i,1,alpanz
alptem(i)=temmin+((temmax-temmin)*((i-1)/(alpanz-1)))
MPTEMP,i,alptem(i)
*ENDDO
*DO,i,1,alpanz
alpers=alpref(i)*(1+((temref-temgre)/(alptem(i)-temref)))
MPDATA,alpx,1,i,alpers
*ENDDO
UIMP,1,REFT,,,-20
MPPLOT,alpx,1
FINISH
/SOLU
ANTYPE,trans
OUTRES,all,all
LNSRCH,auto !wird für Newton-Raphson-Verfahren benötigt
NROPT,full !Newton-Raphson-Näherungsverfahren
NLGEOM,on
!mechanische Randbedingungen
ALLSEL
NSEL,s,loc,y,30e-3
D,all,ux
D,all,uz
ALLSEL,below,node
NSEL,s,loc,y,0
D,all,uy
ALLSEL,below,node
!Elemente der Klebeschicht ausschalten
ESEL,s,mat,,1
EKILL,all
ALLSEL
!stationärer Lastfall
LDREAD,temp,,,1e-6,,templauf,rth
TIMINT,off
TIME,1e-6
NSUBST,1,1,1
ALLSEL
SOLVE
!Lastfall 2
*DO,i,1,20,1
*IF,i,eq,20,then
ALLSEL
ESEL,s,mat,,1
EALIVE,all
*ENDIF
LDREAD,temp,,,21*i,,templauf,rth
OUTRES,all,all
TIMINT,on
TIME,21*i
NSUBST,3,3,3
ALLSEL
SOLVE
*ENDDO
Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP
Foren auf CAD.de (alle Foren)
| 
