---

Hallo liebe Forenmitglieder

Ich versuche mein Problem mal an einem einfachen Beispiel zu erläutern. Ich habe eine Platte auf der im ersten Loadstep eine konstante Flächenlast aufgebracht ist.

/SOLU
SF,…
SOLVE

Im zweiten Loadstep wird dieselbe Fläche wiederum mit einer konstanten Flächenlast beaufschlagt.

SF,…
SOLVE

Somit kann ich mir im Postprocessing (Result Viewer) die entsprechenden Ergebnisse der beiden Loadsteps einzeln und unabhängig voneinander anschauen.

Ist es möglich eine Überlagerung der beiden Loadsteps zu erzeugen, z.B. in einem dritten Loadstep („frei nach dem Motto LS1+LS2=LS3"). Ich weis, dass ich, bezogen auf dieses einfache Beispiel, die Flächenlasten auch hätte vorher addieren können (sollte halt nur ein einfaches verständliches Bsp. zur Erklärung sein). Dennoch würde ich gerne wissen ob es möglich ist eine derartige Überlagerung zu realisieren. Vielen Dank für eure Hilfe!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Schau Dir das mal an:

!*************************************************************************************************************
!* Macro creates BC for the static load cases of FM2 and solves 
!*************************************************************************************************************
/solu
LSCLEAR,ALL
allsel

!*************************************************************************************************************
d,77085,all !* BC for all LC
d,231219,all
d,231255,all

!*************************************************************************************************************
acel,0,0,9.81 !* LC 1, gravity Z
lswrite,01

!*************************************************************************************************************
acel,9.81,0,0 !* LC 2, gravity X
lswrite,02

!*************************************************************************************************************
acel,0,9.81,0 !* LC 3, gravity Y
lswrite,03

!*************************************************************************************************************
acel,6.9367,0,6.9367 !* LC 4, gravity Z+X 45º
lswrite,04

!*************************************************************************************************************
acel,0,6.9367,6.9367 !* LC 5, gravity Z+Y 45º
lswrite,05

!*************************************************************************************************************
lssolve,1,5,1 !* Solve
finish

!*************************************************************************************************************
/post1
SET,1,1,,,,             !* Get load step 1
LCWRITE,1, , ,  !* Write load case

LCFACT,1,3, !* Set load case factor
LCZERO  !* Delete results from DB
LCOPER,ADD,1, , , !* Add to DB LC1*3
RAPPND,6,6, !* Create Load case 6 (survival gravity axial)

SET,2,1,,,,             !* Get load step 2
LCWRITE,2, , ,  !* Write load case

LCFACT,2,3, !* Set load case factor
LCZERO  !* Delete results from DB
LCOPER,ADD,2, , , !* Add to DB LC2*3
RAPPND,7,7, !* Create Load case 7 (survival gravity lateral X)

SET,3,1,,,,             !* Get load step 2
LCWRITE,3, , ,  !* Write load case

LCFACT,3,3, !* Set load case factor
LCZERO  !* Delete results from DB
LCOPER,ADD,3, , , !* Add to DB LC3*3
RAPPND,8,8, !* Create Load case 8 (survival gravity lateral Y)

finish

------------------
Grüsse, Torsten

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Besten Dank Torsten,

mit dieser Befehlsfolge:

/SOLU
  SF,…
SOLVE

  SF,…
SOLVE

/POST1
  SET,1
  LCWRITE,1
  LCFACT,1
  LCZERO
  LCOPER,ADD,1

  SET,2
  LCWRITE,2
  LCFACT,2
  LCOPER,ADD,1
  RAPPND,3

hat das Überlagern von zwei Loadsteps einwandfrei geklappt. Nochmals besten Dank und schönes Wochenende!!!

Mathias

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke für die Rückmeldung.

------------------
Grüsse, Torsten

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP