---

Hallo,
ich will den Eindringvorgang einer nicht verformbaren Kugel in einen Körper (Würfel) mit Ansys elastisch simulieren. (Ich bringe mir das Programm gerade selbst bei, also nachsicht wenn ich voll daneben liege)
Dazu muss ich doch mit contact elements arbeiten.
Gibt es eine Reihenfolge oder ein Rezept nachdem man vorgehen kann.

Ich gehe so vor und so klappts nicht:
- Geometrie erstellen
- Volumen meshen / Kugel nicht
- element types bestimmen (10 node 92 für die Volumen und targe 170 und conta 174 für das Kontaktpaar)
- mit dem contact wizard bestimme ich target (rigid, Kugel) und contact (oberseite des Volumens
- real constant set1 für die Kontaktelemente
- Material Models, linear elastisch, isotrop
- dann lege ich Spannung auf die obere Schale der Kugel und setze die untere seite des volumens in xyz fest
- dann löse ich current ls ... zwei warnunge kommen und ich weiss auch nicht wie ich das ergebnis sehen kann.... mit plot results.. deformed shape sieht alles aus wie vorher... plot von mise ist alles rot..

währe nett wenn mir einer helfen könnte.

gibts eigentlich ein aktuelles handbuch oder sowas zu ansys 10

Danke Mitch

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo
da hast du dir ja gleich das schönste Thema ausgesucht um Ansys zu lernen.
Also zu deiner Vorgehensweise:
prinzipiell sollte das richtig sein, aber um ein rigid Target zu definieren musst du auch die Kugel vernetzen und auf der Oberfläche die entsprechenden Targetelemente mit der entsprechenden Keyoption definieren. Für das Volumen würde ich einen solid45 oder solid185 nehmen. Dann kann es sinnvoll sein den Kontakt durch eine kleine Verschiebung zu initialisieren. Es gibt in der Ansys Hilfe unter VM191 einen ähnlichen Fall als Beispiel. Sonst kann man nur FEM für Praktiker empfehlen.

Es gibt bzw. gab im Forum schon einige Beiträge zum Thema Kontakte, einfach mal die Suchfunktion bemühen.

Gruß Sören

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Wenn es nur um den Bereich in der Nähe der Kugel geht, lässt sich das auch zweidimensional rechnen.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Hurricane
jeden Tag eine gute Tat!!!

/PREP7
! Elementtype
ET,1,SOLID185
ET,2,CONTA173,,1
ET,3,TARGE170
!Materialkennwert Stahl

MP,EX,1,2E5
MP,NUXY,1,0.3
TB,BISO,1
TBDATA,1,200,1000

rad=50 !Radius der Kugel

!Reals
R,2,rad

!Geometrie
blc4,0,0,100,100,100
esize,10
VMES,ALL
local,11,0,50,50,100
*GET,NMAX,NODE,,NUM,max
Pilot1=Nmax+1
n,pilot1,,,rad

!Target festelgen
TYPE,3
REAL,2
TSHAP,SPHE
E,Pilot1,
nsel,s,loc,z,0
TYPE,2
ESURF

ALLS

/SOLU
NLGEOm,ON
SOLCON,ON
NEQIT,50
EQSLV,FRONT
NSUB,50,200
OUTRES,ALL,-5
CSYS

NSEL,S,LOC,Z
D,ALL,all
ALLS
D,Pilot1,ALL
D,Pilot1,UZ,-10
ALLS
SOLVE

/POST1
/EDGE,,1
/VIEW,,3,1,1
ESEL,U,TYPE,,2,3
EPLO
SET,LAST
/DSCA,,1
/GRA,FULL
PLNS,S,EQV

viel spass

------------------
Jens Friedrich
Institut für Leichtbau und Kunststofftechnik
TU-Dresden

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Na danke ich schon mal schön,

mal sehen wie weit ich jetzt komme... Die nächsten Fragen kommen sicher nächste Woche !!!

Mitch

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Was bedeutet den "Nähe". Ich will alle Spannungen darstellen, die durch die Kugel auftreten. Also alles unterhalb des Kugeleindrucks.
Die Kugel soll maximal zu einem Drittel eindringen.  Geht das auch in 2D ?
Und nochwas... wie bringe ich denn am Besten die Kraft auf. Als Spannung auf die untere oder obere Kugelhälfte ? Oder eher las Kraft ?

Gruß,
Mitch

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielleicht kann ich hierdurch erfahren, was an meiner Version nicht korrekt ist.

Code:

---

!Kugel wird in Zylinder gedrückt 2D
!Variation der Datei von Jens Friedrich
rad=50  !Radius der Kugel
raz=120 !Radius Zylinder
hoz=80  !Höhe Zylinder
weg=10  !Eindringweg

/PREP7
! Elementtype
ET,1,plane182,,,1
ET,2,CONTA171,,,1
ET,3,TARGE169
!Materialkennwert Stahl
MP,EX,1,2E5
MP,NUXY,1,0.3
TB,BISO,1
TBDATA,1,200,1000
mp,ex,2,2e5
mp,nuxy,2,0.1
!---Geometrie----
rectng,0,raz,0,-hoz
cyl4,0,rad,rad,-90,,0
!----Vernetzung------
esize,raz/10
type,1
mat,1
amesh,1
mat,2
amesh,2
!---Kontakte----
lsel,s,,,3
nsll,s,1
type,2
esurf
!-------------------
lsel,s,,,5
nsll,s,1
type,3
esurf
!----Randbedingung-----
nsel,s,loc,y,-hoz 
d,all,uy,0
nsel,s,loc,x,0
d,all,ux,0
!---Lasten-----
nsel,s,loc,y,rad
d,all,uy,-weg
ALLS

/SOLU
NLGEOm,ON
SOLCON,ON
NEQIT,50
EQSLV,FRONT
NSUB,50,200
OUTRES,ALL,all
CSYS

ALLS
SOLVE

/POST1
/EDGE,,1
/DSCA,,1
PLNS,S,EQV

/eof

/edge
/plopts,minm,0
/expand,27,axis,,,10
/view,,1,1,1
/repl

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

In 2D ist die Eindringung einer unverformbaren Kugel auch möglich!
Hier eine Lösung die auf Woschs input aufbaut, wobei die kugel ein starrkörper ist:
Damit kommt man mit deutlich weniger aufwand zu einer sehr guten Lösung unter der Annahme das man den Würfel als Zylinder "verschmieren" kann!

!Kugel (unverformbar) wird in Zylinder gedrückt 2D
!Variation der Datei von Wosch
rad=50  !Radius der Kugel
raz=120 !Radius Zylinder
hoz=80  !Höhe Zylinder
weg=10  !Eindringweg

/PREP7
! Elementtype
ET,1,plane182,,,1
ET,2,CONTA171 !,,,1
ET,3,TARGE169
!Materialkennwert Stahl
MP,EX,1,2E5
MP,NUXY,1,0.3
TB,BISO,1
TBDATA,1,200,1000
! mp,ex,2,2e5
! mp,nuxy,2,0.1
!---Geometrie----
rectng,0,raz,0,-hoz
cyl4,0,rad,rad,-90,,0
!----Vernetzung------
esize,raz/10
type,1
mat,1
amesh,1
! mat,2
! amesh,2
!---Kontakte----
type,3
TSHAP,ARC
lmesh,5
*GET,NMAX,NODE,,NUM,max
Pilot1=Nmax+1
n,pilot1,,rad
TSHAP,PILOT
e,Pilot1

!-------------------
lsel,s,,,3
nsll,s,1
type,2
esurf
!----Randbedingung-----
nsel,s,loc,y,-hoz
d,all,uy,0
nsel,s,loc,x,0
d,all,ux,0
!---Lasten-----

d,pilot1,uy,-weg
ALLS

/SOLU
NLGEOm,ON
SOLCON,ON
NEQIT,50
EQSLV,FRONT
NSUB,50,200
OUTRES,ALL,all
CSYS

ALLS
SOLVE

/POST1
/EDGE,,1
/DSCA,,1
PLNS,S,EQV

Gruss
Jens

------------------
Jens Friedrich
Institut für Leichtbau und Kunststofftechnik
TU-Dresden

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo ich hab mal was anderes Versucht und aufbauend auf dem oben erwähnten Beispiel einen Zylinder in eine Kugel eintreten lassen, leider vergeblich.
Was muss ich ändern?

finish
/clear
/PREP7
! Elementtype
ET,1,SOLID185
ET,2,CONTA173,,1
ET,3,TARGE170
!Materialkennwert Stahl

MP,EX,1,2E5
MP,NUXY,1,0.3
TB,BISO,1
TBDATA,1,150,1500

rad=20 !Radius der Kugel

!Reals
R,2,rad

!Geometrie
SPHERE,0,100,0,360
esize,10
mshape,1,3d
mshkey,0
vmesh,all
VMES,ALL
local,11,0,,,100
*GET,NMAX,NODE,,NUM,max
Pilot1=Nmax+1
Pilot2=Nmax+2
n,pilot1,,,0
n,pilot2,,,50
!Target festelgen
TYPE,3
REAL,2
TSHAP,cyli
E,Pilot1,Pilot2
csys,2
nsel,s,loc,x,100
csys,0
nsel,r,loc,z,100,0
TYPE,2
ESURF

ALLS

/SOLU
NLGEOm,ON
SOLCON,ON
NEQIT,100
EQSLV,FRONT
NSUB,150,400
OUTRES,ALL,-10
CSYS
csys,2
nsel,s,loc,x,100
nsel,r,loc,z,-80,-100
D,ALL,all
ALLS
D,Pilot1,ALL
D,Pilot1,UZ,-5
D,Pilot2,ALL
D,Pilot2,UZ,-5
ALLS
SOLVE

/POST1
/EDGE,,1
/VIEW,,3,1,1
ESEL,U,TYPE,,2,3
EPLO
SET,LAST
/DSCA,,1
/GRA,FULL
PLNS,S,EQV

------------------
B. Niemann

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von Jens.Friedrich:
Hallo Hurricane
jeden Tag eine gute Tat!!!

/PREP7
! Elementtype
ET,1,SOLID185
ET,2,CONTA173,,1
ET,3,TARGE170
!Materialkennwert Stahl

MP,EX,1,2E5
MP,NUXY,1,0.3
TB,BISO,1
TBDATA,1,200,1000

rad=50 !Radius der Kugel

!Reals
R,2,rad

!Geometrie
blc4,0,0,100,100,100
esize,10
VMES,ALL
local,11,0,50,50,100
*GET,NMAX,NODE,,NUM,max
Pilot1=Nmax+1
n,pilot1,,,rad

!Target festelgen
TYPE,3
REAL,2
TSHAP,SPHE
E,Pilot1,
nsel,s,loc,z,0
TYPE,2
ESURF

ALLS

/SOLU
NLGEOm,ON
SOLCON,ON
NEQIT,50
EQSLV,FRONT
NSUB,50,200
OUTRES,ALL,-5
CSYS

NSEL,S,LOC,Z
D,ALL,all
ALLS
D,Pilot1,ALL
D,Pilot1,UZ,-10
ALLS
SOLVE

/POST1
/EDGE,,1
/VIEW,,3,1,1
ESEL,U,TYPE,,2,3
EPLO
SET,LAST
/DSCA,,1
/GRA,FULL
PLNS,S,EQV

viel spass

---

Hallo,

ich stehe momentan vor einer ähnlichen Problemstellung.
Ich möchte eine nicht verformbare Kugel auf einen anderen Körper wirken lassen. Einziger Unterschied, die Kugel soll nicht in einen Würfel eindringen, sondern ein ringsherum eingespanntes Blech (quadratisch) verformen/durchbiegen. Das alles in 3D.
Ich habe nun mehrmals versucht die oben zitierte Befehlskette nach meinen Anforderungen abzuwandeln. Doch trotz geänderter Lagerung erhalte ich keine Verformung. Ich befürchte, dass ich die Materialeigenschaften des Würfels/Blechs anders definieren muss bzw. ein anderes Element wählen muss.

Hat jemand eine Idee?

Grüße
flahn

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Flan,

ich versteh das Problem nicht! Ein Blech ist doch nix anderes als ein "flacher" Würfel. Damit musst doch nur die Geometrie des flexiblen Körpers ändern. Das sollte mit etwas nachdenken auch für jeden möglich sein. Du brauchst weder zwingend ein anderes Material noch zwingend andere Elemente. Für dünne Bleche sind Schalen und Solsh-Elemente sicher besser geeignet. Für mich hört sich das so als ob der Kontakt nicht gefunden wird. Ev. mal am Pinball was ändern.

Gruß
Jens

------------------
Jens Friedrich
TU-Dresden

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke,

habs jetzt endlich hinbekommen. Keine Ahnung wo mein Fehler lag...

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

ich beschäftige mich noch immer mit dem Eindringvorgang einer nicht verformbaren Kugel in einen Körper. Ich möchte den Körper zusätzlich außen mit einer Kraft vorspannen, was auch kein Problem darstellt.
Nun würde ich jedoch gerne ein unterschiedliches Dehnungsverhalten für den Körper in x- und y-Richtung definieren, so dass bei gleicher Belastung in y-Richtung bspw. nur 50% der Verformung im Vergleich zur x-Richtung auftreten. Nur wie mache ich das?
Sorry, die Frage ist für einige evtl. banal...

Grüße
flahn

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

mittels orthotropen materialgesetz

------------------
Jens Friedrich
TU-Dresden

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Testfile.txt

Ok, vielen Dank!

Leider habe ich jetzt schon wieder eine Frage.

Ich habe nun meinen Körper - wo die Kugel eindrückt - außen mit Kräften vorbelastet.
Doch bevor der Kugeleindruck erfolgt, möchte ich die durch die Vorspannkräfte hervorgerufene Verformung des Körpers fixieren (nur an den Knoten an denen auch die Kräfte angreifen).
Das Auswählen der betreffenden Knoten und die Lagerung sollte kein Problem darstellen.
Mich interessiert nur, wie ich vorgehen muss, um erst die Vorspannkräfte samt Verformung zu realisieren und anschließend die Knoten zu lagern und somit die Verformung beizubehalten.
Muss ich z.B. mehrere Solve-Befehle anwenden?

PS.: die genauen Materialkennwerte sind mir noch nicht bekannt. Es geht vorerst nur ums Prinzip.

Ich hab mein Textfile mal angehängt...

Grüße
flahn

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von flahn:
Ok, vielen Dank!

Leider habe ich jetzt schon wieder eine Frage.

Ich habe nun meinen Körper - wo die Kugel eindrückt - außen mit Kräften vorbelastet.
Doch bevor der Kugeleindruck erfolgt, möchte ich die durch die Vorspannkräfte hervorgerufene Verformung des Körpers fixieren (nur an den Knoten an denen auch die Kräfte angreifen).
Das Auswählen der betreffenden Knoten und die Lagerung sollte kein Problem darstellen.
Mich interessiert nur, wie ich vorgehen muss, um erst die Vorspannkräfte samt Verformung zu realisieren und anschließend die Knoten zu lagern und somit die Verformung beizubehalten.
Muss ich z.B. mehrere Solve-Befehle anwenden?

PS.: die genauen Materialkennwerte sind mir noch nicht bekannt. Es geht vorerst nur ums Prinzip.

Ich hab mein Textfile mal angehängt...

Grüße
flahn

---

...hat niemand eine Idee?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP