---

Hallo 

Ich würde gerne einen ein Meter langen Einfeldträger (statisch bestimmt, Materialgesetz linear elastisch isotrop, aber Theorie II. Ordnung) mit einem I-Profil, das durch eine konstante Flächenlast belastet wird, optimieren. Als Restriktion gibt es maximale Flansch- und Stegdicken und eine maximale Auflagerverschiebung sowie eine vorgegebene Höhe und Breite.

Kann ANSYS das und wenn ja, kann auch ich das?  Wie schwierig ist so eine Optimierung [maximal verfügbare Zeit: 3 Wochen]? Hat jemand vielleicht ein Beispiel dafür? Das wäre super!!!

Vielen Dank für die Bemühungen... 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

wieso benötigst du bei einem Einfeldträger der auf Biegung belastet wird die Theorie II Ordnung?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hier ein Eingabebeispiel für das Balkenelement Beam188.

Netzfeinheit=2
l= !Länge des Trägers
e_zahl=
/prep7

ET,1,BEAM188,0,0

MP,EX,1,Emodul

SECTYPE, 1, Beam, I, Profilname , Netzfeinheit
SECDATA, Gurtbreite Oben,Gurtbreite Unten,Profilhöhe h,Gurtdicke t,Gurtdicke t,Flanschdicke s

K,1
K,2,l
K,3,l/2,l
L,1,2

LATT,1,1,1,,3,3,1
LESIZE,1,,,e_zahl
LMESH,1

Die Parameter des Befehls SECDATA sind der Optimierung zu Grunde zu legen.
Für ein Beispiel einer Optimierung siehe:
http://www.femfuerpraktiker.de/Ansys61_Beispiele/Band1/B1Bsp23.pdf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo nochmal 

Also mit Theorie II. Ordnung meinte ich, dass große Verformungen zugelassen sind (Befehl: NLGEOM,ON). Die Eingabe brauche ich gar nicht, das ist bereits fertig - habe ein Iprofil über Keypoints definiert, mit Linien verbunden, extrudiert, mit SOLID95 vernetzt ("per Hand" über Einteilung in Elemente über die jeweilige Dicke), mit einer konstanten Flächenlast belastet, Randbedigungen vorgegeben und gelöst. Das funktioniert auch!

Aber nun suche ich die optimalen Geometrien dafür, dass das Profil wenig wiegt und viel Last aushält [Effektivität = Last/Flächengewicht] bei einer bestimmten zulässigen Auflagerverschiebung.

Vielen Dank schon mal für das Beispiel. Vielleicht hilft mir das ja weiter. Oder noch evtl. brauchbare Tipps auf Lager? 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Katrini,

ne optimierung funktioniert nur wenn du das modell parametrisch aufbaust.
d.h. du benötigst den input analog dem geposteten. dann muss man die optimierungsroutine von ansys laufen lassen.
dafür braucht ansys die angaben nach welcher größe minimiert werden soll (Masse!).
welche zwangsbedingungen herschen (z.B. Spannung < Fließspannung).
und welche die veränderbaren variablen sind.
am besten mal folgende beispiele durcharbeiten:
http://www.femfuerpraktiker.de/Ansys61_Beispiele/Band1/B1Bsp23.pdf http://www.femfuerpraktiker.de/Ansys61_Beispiele/Band1/B1Bsp24.pdf

noch näher kommt das beispiel der Ansyshilfe VM155
viel spass!

/COM,ANSYS MEDIA REL. 9.0 (10/15/2004) REF. VERIF. MANUAL: REL. 9.0
/VERIFY,VM155
JPGPRF,500,100,1            ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
*CREATE,SCRATCH  ! USED FOR INTERACTIVE USE
JPGPRF,500,100,1            ! MACRO TO SET PREFS FOR JPEG PLOTS
TK16=.25                        ! SET INITIAL VALUES OF DESIGN VARIABLES
TK27=.25                        ! THICKNESS AT ONE FOURTH LENGTH
TK38=.25                        ! THICKNESS AT ONE HALF LENGTH
TK49=.25                        ! THICKNESS AT THREE FOURTHS LENGTH
/PREP7
smrt,off
/TITLE,VM155: SHAPE OPTIMIZATION OF A CANTILEVER BEAM
/COM   
/COM   
/COM,  REF.  B. PRASAD AND R.T.HAFTKA   
/COM,          OPT. STRUCT. DESIGN WITH PLATE FINITE ELEMENTS     
/COM,          ASCE JOURNAL OF THE STRUCT. DIVISION   
/COM,          VOL. 105 (ST11) 1979 PP2367-2382       
/COM 
ET,1,PLANE42
MP,EX,1,10E6         
MP,NUXY,1,0.3
K,1
K,5,10
KFILL
K,6,,TK16                        ! DEFINE KEYPOINTS IN TERMS OF DESIGN VARIABLES
K,7,2.5,TK27       
K,8,5,TK38         
K,9,7.5,TK49       
K,10,10,.15       
SPLINE,6,7,8,9,10                ! DEFINE TOP EDGE WITH A SPLINE
L,1,6
*REPEAT,5,1,1
LSEL,S,LINE,,5,9
LESIZE,ALL,,,1
LSEL,ALL
A,1,2,7,6
*REPEAT,4,1,1,1,1
ESIZE,,4         
AMESH,ALL         
NSEL,S,LOC,Y
DSYM,SYMM,X
NSEL,S,LOC,X
DSYM,ASYM,Y
NSEL,ALL
FK,10,FX,1500                    ! APPLY END COUPLE TO KEYPOINT
DK,1,ALL,0                      ! FIX NODE AT KEYPOINT #1
FINISH 
/SOLU     
SOLVE
FINISH 
/POST1 
SET,LAST
ETABLE,VOLU,VOLU
PRNSOL,S,PRIN
NSORT,S,1                        ! GET MAXIMUM STRESS 
NSEL,S,LOC,X,0,9                ! IGNORE LOCAL STRESSES @ POINT OF LOAD
*GET,STRS,SORT,,MAX     
NSEL,ALL   
SSUM   
*GET,TVOL,SSUM,,ITEM,VOLU        ! TVOL = TOTAL VOLUME OF ELEMENTS     
TVOL=TVOL*2                      ! MULTIPLY BY TWO FOR SYMMETRY       
NSEL,S,LOC,X,9.9,10.1   
PRNSOL,U,Y
NSORT,U,Y,,1       
PRNSOL,U,Y
*GET,DEFL,SORT,,MAX
*status,parm
DEFL=ABS(DEFL)                  ! USE ABS. VALUE OF MAX END DEFLECTION 
/COM    DEFINE STATE VARIABLES TO ENSURE CONSISTENT TAPER         
DIF1=TK16-TK27
DIF2=TK27-TK38
DIF3=TK38-TK49
FINISH 
*END

*USE,SCRATCH ! RUN INITIAL ANALYSIS

/OPT
OPANL,SCRATCH ! ASSIGN OPT LOOP FILE   
OPVAR,TVOL,OBJ,,,.01            ! OBJECTIVE FUNCTION
OPVAR,STRS,SV,,30000            ! STATE VARIABLES
OPVAR,DEFL,SV,,0.50
OPVAR,DIF1,SV,0,.1 
OPVAR,DIF2,SV,0,.1 
OPVAR,DIF3,SV,0,.1 
OPVAR,TK16,DV,0.15,0.27,.001    ! DESIGN VARIABLES
OPVAR,TK27,DV,0.15,0.27,.001   
OPVAR,TK38,DV,0.15,0.27,.001   
OPVAR,TK49,DV,0.15,0.27,.001   
OPSAVE,INITIAL,OPT              ! SAVE INITIAL DESIGN
OPTYPE,SUBP                      ! OPT METHOD IS SUBPROBLEM APPROX.
OPSUBP,30                        ! OPTIMIZE FOR 30 ITERATIONS (MAX)
OPEXE                            ! PERFORM SUB-PROBLEM APPROX. OPTIMIZATION
VR1=TVOL
VR2=DEFL
VR3=STRS
PARSAV,,RSET1
OPLIST,ALL,,1                    ! LIST DESIGN SETS
/AXLAB,Y,VOLUME (TVOL)          ! OBJECTIVE FUNCTION ALONG Y-AXIS
PLVAROPT,TVOL                    ! PLOT OBJECTIVE CONVERGENCE
OPRESU,INITIAL,OPT              ! RESUME INITIAL DESIGN SET
OPVAR,DIF1,DEL                  ! DELETE ARTIFICIAL CONSTRAINTS
OPVAR,DIF2,DEL                  !  FOR FIRST ORDER METHOD
OPVAR,DIF3,DEL
OPTYPE,FIRST                    ! SPECIFY FIRST-ORDER METHOD
OPFRST,20                        !  WITH MAXIMUM OF 20 ITERATIONS
STATUS
OPEXE                            ! PERFORM FIRST-ORDER OPTIMIZATION
VR4=TVOL
VR5=DEFL
VR6=STRS
OPLIST,ALL,,1                    ! LIST DESIGN SETS
/AXLAB,Y,VOLUME (TVOL)          ! OBJECTIVE FUNCTION ALONG Y-AXIS
PLVAROPT,TVOL                    ! PLOT OBJECTIVE CONVERGENCE

------------------
Jens Friedrich
Institut für Leichtbau und Kunststofftechnik
TU-Dresden

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

topopti.txt

Ist hier vielleicht die Topologie-Optimierung gemeint?
Wenn ja, dann hängt hier ein Beispiel dran.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

OPTIPROF.txt

Das ist auch nicht schlecht, diese Topologieoptimierung, aber ich befürchte nicht genau das, was ich brauche!

Vielleicht ist jemandem da draussen ganz arg langweilig und hat Lust, einem armen kleinen verzweifelten Mädchen zu helfen... 

Würde gerne das I-Profil (Eingabe und Lösung siehe Anhang) so optimieren, dass ich möglichst wenig Material brauche und das Profil trotzdem viel Last trägt [logisch!  ]. Die Restriktionen habe ich so eingegeben (-> anhand des Beispieles Kapitel 1.8.3, ANSYS 9.0):

/opt
opanl,IPROFIL !Assign oploop file

! IDENTIFY OPTIMIZATION VARIABLES
opvar,ts,dv,0.7,2  ! DVs: Stegdicke
opvar,tfo,dv,0.7,2  ! obere Flanschdicke 
opvar,tfu,dv,0.7,2    ! Untere Flanschdicke
opvar,b,dv,28,32  ! Breite
opvar,dzmax,sv,,7.5 ! Verschiebung maximal 7,5mm

Im Postprozessor muss ich aber noch die Verschiebung des Punktes (0,-h,0) angeben lassen, da diese dzmax-Verschiebung maximal 7,5 mm betragen darf!!! Wie geht das? Im übrigen ist die Belastung in 10 Substeps aufgeteilt und eben genau die Last gesucht, bei der die maximal zulässige Verschiebung von 7,5 mm auftritt!

Im Anhang meine Eingaben - bis zum POSTPROCESSING läufts einwandfrei  aber dann...

... HILFEEEEEEEE!!! 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Das arme kleine Mädchen wird sich wohl selbst in das böse Ansys einarbeiten müssen! Was ist das denn für ne Tränennummer?!?
Du hast doch jetzt genügend beispiele. Das Problem kann man mit einfachen Balkenelementen z.B. Beam188 rechnen.

------------------
Jens Friedrich
Institut für Leichtbau und Kunststofftechnik
TU-Dresden

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,
sieht doch schon gar nicht schlecht aus.
Was m.E. fehlt ist die Objektfunktion, also das Optimierungsziel.
Also im Inputfile
nach der Modellierung Volumen bestimmen und einer Variablen zuordnen.
(*get) und bei der Optimierung
die Objektfunktion definieren:
OPVAR,Tr_volu,Obj,,,0.01

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo  Vielen Dank für die tolle Hilfe. Die Optimierung läuft jetzt! 

Das einzige, was mir noch fehlt ist die Restriktion für die maximale Verschiebung dzmax in z-Richtung des Knotens Nr. 4920! Hab es mit den Befehlen

NSEL,NODE,4920
NSOL,dzmax,NODE,u,z
*GET,dzmax,NODE,4920,u,z

versucht, bekomme allerdings die Fehlermeldung "Non-existent scalar parameter DZMAX has been created and initialized to DZMAX = 0.0"
Will dzmax benutzen, um bei der Optimierung

OPVAR,dzmax,sv,,7 ! Verschiebung dzmax maximal 7 mm

einzugeben!!! Was fehlt mir da? 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP