Standardblattformate (Autodesk/Inventor)

Hallo Martin,

Druckdateien wie bei Autocad suchst du bei Inventor vergeblich.

Du könntest dir jedoch für deine Blattformate Makros zum Drucken erstellen, bei denen das Blattformat und die Ausrichtung voringestellt ist.

Code:

Sub DruckenA4hoch()
'Get the active document and check whether it is a drawing document
If Not ThisApplication.ActiveDocument.DocumentType = kDrawingDocumentObject Then
Exit Sub
End If

Dim oDrgDoc As DrawingDocument
Set oDrgDoc = ThisApplication.ActiveDocument

' Set reference to drawing print manager
' DrawingPrintManager has more options than PrintManager
' as it's specific to drawing document

Dim oDrgPrintMgr As DrawingPrintManager
Set oDrgPrintMgr = oDrgDoc.PrintManager

'----------------------------------------------------------------------------------
' Set the printer name
' comment this line to use default printer or assign another one
'----------------------------------------------------------------------------------
oDrgPrintMgr.Printer = "HP LaserJet 4050 Series PCL6"

'----------------------------------------------------------------------------------
' Set the printers ColorMode
'----------------------------------------------------------------------------------
' kPrintColorPalette Print using color
' kPrintDefaultColorMode Default setting for color mode
' kPrintGrayScale Print using a gray scale
'----------------------------------------------------------------------------------
oDrgPrintMgr.ColorMode = kPrintDefaultColorMode

'----------------------------------------------------------------------------------
' Set the printers scale-mode
'----------------------------------------------------------------------------------
' kPrintBestFitScale Print using a best-fit scale for the Drawing
' kPrintCurrentWindow Print the contents of the window as-is
' kPrintCustomScale Print usign the custom scale specified elsewhere
' kPrintFullScale Print using full scale of the Drawing
'----------------------------------------------------------------------------------
oDrgPrintMgr.ScaleMode = kPrintBestFitScale

'----------------------------------------------------------------------------------
' Gets/Sets the scale of the print.
' Meaningless when the ScaleMode is not kPrintCustomScale
'
' if you need to plot as drawing as 1/4 scale, this property should be set to 0.25.
' If you need to plot at twice the scale this property should be set to 2.
' If the paper is smaller than the specified sheet size, a portion of the sheet will not print.
'
'----------------------------------------------------------------------------------
Dim dScale As Double
dScale = 1
oDrgPrintMgr.[Scale] = dScale

'----------------------------------------------------------------------------------
' Set the paper size.
'----------------------------------------------------------------------------------
' kPaperSize10x14
' kPaperSize11x17
' kPaperSizeA2
' kPaperSizeA3
' kPaperSizeA4
' kPaperSizeA4Small
' kPaperSizeA5
' kPaperSizeB4
' kPaperSizeB5
' kPaperSizeCSheet
' kPaperSizeCustom
' kPaperSizeDefault
' kPaperSizeDSheet
' kPaperSizeESheet
' kPaperSizeExecutive
' kPaperSizeFolio
' kPaperSizeLedger
' kPaperSizeLegal
' kPaperSizeLetter
' kPaperSizeQuarto
'----------------------------------------------------------------------------------
oDrgPrintMgr.PaperSize = kPaperSizeA4

'----------------------------------------------------------------------------------
' Change the paper size to a custom size. The units are in centimeters.
' only valid if PaperSize is set to custom size
'----------------------------------------------------------------------------------
oDrgPrintMgr.PaperHeight = 15
oDrgPrintMgr.PaperWidth = 10

'----------------------------------------------------------------------------------
' Set the orientation
'----------------------------------------------------------------------------------
' kDefaultOrientation
' kLandscapeOrientation
' kPortraitOrientation
'----------------------------------------------------------------------------------
oDrgPrintMgr.Orientation = kPortraitOrientation

'----------------------------------------------------------------------------------
' Read-write property that gets and sets whether the drawing should be
' rotated 90 degrees when printed. This property only applies to drawing documents.
' It is initialized to False.
'----------------------------------------------------------------------------------
oDrgPrintMgr.Rotate90Degrees = False

'----------------------------------------------------------------------------------
' Read-write property that gets and sets which sheets to print.
'
' kPrintCurrentSheet the active sheet will be printed.
' kPrintAllSheets all sheets will be printed.
' kPrintSheetRange the sheets defined using SetSheetRange will be printed.
'
'----------------------------------------------------------------------------------
oDrgPrintMgr.PrintRange = kPrintAllSheets

'----------------------------------------------------------------------------------
' Get and set the current sheet range.
'----------------------------------------------------------------------------------
' Dim iFromSheet As Long
' Dim iToSheet As Long
' Call oDrgPrintMgr.GetSheetRange(iFromSheet, iToSheet)
' MsgBox "Current sheet range is " & iFromSheet & " to " & iToSheet & Chr(13) & _
"Setting to print sheets 1-2."

'----------------------------------------------------------------------------------
' Change the print range to print sheets 1 through 2.
'----------------------------------------------------------------------------------
' oDrgPrintMgr.PrintRange = kPrintSheetRange
' Call oDrgPrintMgr.SetSheetRange(1, 2)

' Change the number of copies to 1.
Dim iNumberOfCopies As Long
iNumberOfCopies = 1
oDrgPrintMgr.NumberOfCopies = iNumberOfCopies

' Submit the print.
oDrgPrintMgr.SubmitPrint
End Sub

Einfach für die Einzelnen Formate kopieren und anpassen

------------------
Gruß, Gandhi
It's not a bug, it's a feature!
CAD-RPG - Anleitungen IVNGWC

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP