---

Hallo,
habe schon einiges unter Samples gefunden.

Ich möchte aber z.B das Feld "Titel" in Eigenschaften über ein VBA-Makro ansprechen.

Das Feld "Thema" kann ich mit
_____________________________
Dim oDoc As PartDocument
Set oDoc = ThisApplication.ActiveDocument

oDoc.PropertySets("{F29F85E0-4FF9-1068-AB91-08002B27B3D9}").Item(kTitleSummaryInformation).Value = "test Thema"
___________________________

ansprechen und es erscheint => test Thema    in Eigenschaften Registerkarte Übersicht Feld Thema

Ich Frage mich jedoch was (kTitleSummaryInformation) mit Thema zu tun hat, ich dachte es würde das Feld "Titel" angesprochen

Welchen Namen hat das Feld "TITEL"  , "Material"
z.B. k.......SummaryInformation

und welchen CODE
z.B.("{F29F85E0-4FF9-1068-AB91-08002B27B3D9}")
oder {32853F0F-3444-11d1-9E93-0060B03C1CA6}:

Wer hat sich damit schon beschäftigt?

MfG
K. W.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo VOSTA1,

nimm doch mal folgendes:

Dim mydoc As Document
Set mydoc = ThisApplication.ActiveDocument

Dim myPropertySets As PropertySets
Set myPropertySets = mydoc.PropertySets

Dim myPropertySet As PropertySet
Set myPropertySet = myPropertySets.Item("{F29F85E0-4FF9-1068-AB91-08002B27B3D9}")

myPropertySet.ItemByPropId(kTitleSummaryInformation).Value = "mein Text"

Soweit ich das erkennen kann greifts Du die Items auf der falschen Ebene an. Dein Index kTitleSummaryInformation hat den Wert 2; daraus ergibt sich der Zugriff auf das 2te Item welches "Thema" ist. Wenn Du ItemByPropId benutzt sollte das ganze korrekt funktionieren.

------------------
Gruß, Peter

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi VOSTA1,

ich stimme den Raistlin zu, und ergänze es hiermit:

Code:

---

Public Sub test_property()

Dim mydoc As Document
Set mydoc = ThisApplication.ActiveDocument

Dim myPropertySets As PropertySets
Set myPropertySets = mydoc.PropertySets

Dim myPropertySet As PropertySet
Dim i As Double
'****** Du kannst auch die "for each myPropertySet in myPropertySets" benutzen, aber so ist es deutlicher ***
For i = 1 To myPropertySets.Count
  Set myPropertySet = myPropertySets.Item(i)
  Debug.Print "Item " & i & "  " & myPropertySet.DisplayName & "--" & myPropertySet.InternalName
Next

'****************************************************************************************************
'Item 1  Inventor - Zusammenfassungsinformationen--{F29F85E0-4FF9-1068-AB91-08002B27B3D9}

Set myPropertySet = myPropertySets.Item(1)
myPropertySet.ItemByPropId(kTitleSummaryInformation).Value = "Mein Projekt"              ' Value 2
myPropertySet.ItemByPropId(kSubjectSummaryInformation).Value = "daywa1k3r's Thema"        ' Value 3
myPropertySet.ItemByPropId(kAuthorSummaryInformation).Value = "daywa1k3r"                ' Value 4
myPropertySet.ItemByPropId(kKeywordsSummaryInformation).Value = "Meine Keywords"          ' Value 5
myPropertySet.ItemByPropId(kCommentsSummaryInformation).Value = "Mein Kommentar"          ' Value 6
myPropertySet.ItemByPropId(kRevisionSummaryInformation).Value = "Meine Revisions Nummer"  ' Value 9

'****************************************************************************************************

'****************************************************************************************************
'Item 2  Inventor - Zusammenfassungsinformationen für Dokument--{D5CDD502-2E9C-101B-9397-08002B2CF9AE}

Set myPropertySet = myPropertySets.Item(2)
myPropertySet.ItemByPropId(kCategoryDocSummaryInformation).Value = "Meine Kategorie"        ' Value 2
myPropertySet.ItemByPropId(kManagerDocSummaryInformation).Value = "natürlich daywa1k3r  " ' Value 14
myPropertySet.ItemByPropId(kCompanyDocSummaryInformation).Value = "daywa1k3r's"            ' Value 15

'****************************************************************************************************
'***... Und so weiter, und so weiter,...
 
End Sub

---

Vielleicht bringt es doch ein bisschen mehr Licht in die Dunkelheit.

Bis dahin...

------------------
Grüße daywa1k3r

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP