---

IV_001.JPG

Hallo zusammen,

ich möchte mit einem Macro Flächen und Featzure einfärben. Soll für den Bearbeiter sein, weil der nur Stepdaten verarbeiten kann.

Folgendes habe ich schon umgesetzt
Über ein Makro färbe ich die Flächen eines BT ein dies funktioniert soweit auch ganz gut.
Ich habe ein Formular erstellt auf den mehrere Buttons sind jeder Button steht für eine Farbe.
Jetzt möchte ich mit dem selben Button der die Flächen einfärbt auch Feature ( Bohrungen Extrusionen Reihenanordnungen usw.)einfärben.
Mir ist nur nicht klar wie ich das bewerkstelligen muß. Kann mir einer von euch einen Tipp geben?

im Voraus Danke für eure Bemühungen

Mein bissheriger Code und mein Formular:

Private Sub CommandButton1_Click()

Dim strColorName As String

    strColorName = "Glatt - Elfenbein"

    On Error Resume Next
    Dim oPartDoc As PartDocument
    Set oPartDoc = ThisApplication.ActiveDocument

    If Err Then

        MsgBox "A part document must be active."

        Exit Sub

    End If

    Dim oRenderStyle As RenderStyle
    Set oRenderStyle = oPartDoc.RenderStyles.Item(strColorName)

    If Err Then

        MsgBox "The specified render style """ & strColorName & """ does not exist."

        Exit Sub

    End If

    On Error GoTo 0

    ' Create a list of the selected faces.

    Dim oFaceCollection As FaceCollection
    Set oFaceCollection = ThisApplication.TransientObjects.CreateFaceCollection

    Dim i As Integer

    For i = 1 To oPartDoc.SelectSet.count

        On Error Resume Next

        Dim oFace As Face
       
        Set oFace = oPartDoc.SelectSet.Item(i)

        If Err.Number = 0 Then

            oFaceCollection.Add oFace

        End If

    Next

    ' Set the color of the selected faces.

    For Each oFace In oFaceCollection

        Call oFace.SetRenderStyle(kOverrideRenderStyle, oRenderStyle)

    Next

End Sub

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Normalerweise sollte es mit deinem Code schon gehen.

Wenn nicht, dann hilft dir das hier vielleicht weiter:

Code:

---

    Dim actPart As PartDocument
    Dim pfeature As PartFeature
    Dim oface As Face
    Dim renderstyle As renderstyle
   
    Set actPart = ThisApplication.ActiveDocument
    Set renderstyle = actPart.RenderStyles.Item("schwarz")
    Set pfeature = actPart.ComponentDefinition.Features.HoleFeatures.Item(1)
    Set oface = pfeature.Faces(1)
   
    Call oface.SetRenderStyle(kOverrideRenderStyle, renderstyle)

---

------------------
MFG

Chris

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

ich hoffe das ist nicht ganz am Thema vorbei:
In der Inventor API Hilfe gibts unter 'Sample Programs-Materials and Appearances - Appearances - Change color of part, features or faces' ein Beispiel zum Thema Farbänderung von Features. Hier muß man allerdings jedes Feature mit der gewünschten Farbe per Hand/Maus auswählen. Du wirst vermutlich die verschiedenen Feature-Typen automatisch mit vordefinierten Farben versehen wollen.

MFG
Helmut

Nachtrag: Um das Beispiel lauffähig zu bekommen, muß man den oberen Teil (bis zu den fünf Kommentarzeilen) in ein normales Modul kopieren und den unteren Teil (ab den fünf Kommentarzeilen) in ein neues Class Modul mit dem Namen 'clsColorChange' kopieren. Gestartet wird dann 'Sub ChangeAppearanceMiniToolbarSample()'

[Diese Nachricht wurde von Ticky72 am 25. Apr. 2016 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Ticky72

das war genau das was ich suche, muss es jetzt nur noch auf meine Anwendung anpassen.Hat mir weiter geholfen. Danke

Danke

Ps. habe das Bsp. in der APi nicht gesehen!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Zusammen

Dieses Beispiel funktioniert in IV2011 nicht da Masken und Symbole von neueren Versionen verwendet werden. Leider ist es mir nicht gelungen das ganze an IV2011 anzupassen. Für unsere Fertigung wäre es ein Vorteil wenn alle Elemente in einer bestimmten Farbe daher kommen, somit kann ihr CAM sie automatisch gruppieren.

Ich möchte gerne alle Features (Bohrungen,Extrusionen,Drehungen usw.) in (vorerst) einer Farbe einfärben.
Bin kein VBA Profi und hoffe auf eure Hilfe.

Mein Code bis jetzt:

Code:

---

Public Sub FeatureFarbe()

Dim oPartDoc As PartDocument
Set oPartDoc = ThisApplication.ActiveDocument

Dim oDef As PartComponentDefinition
Set oDef = oPartDoc.ComponentDefinition

Dim oPartFeature As PartFeature
Set oPartFeature = oDef.Features.Item(1)

Dim oRS As RenderStyles
Set oRS = Red

For Each oPartFeature In oPartDoc
Call oPartFeature.SetRenderStyle(kOverrideRenderStyle, oRS)
Next

End Sub

---

Ich bin dankbar für jede Hilfe.

[Diese Nachricht wurde von Luti91 am 06. Jun. 2016 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Zusammen

Habe das Problem mittlerweile selber lösen können.

Code:

---

Dim oPartDoc As PartDocument
Set oPartDoc = ThisApplication.ActiveDocument

Dim oDef As PartComponentDefinition
Set oDef = oPartDoc.ComponentDefinition

Dim oPartFeature As PartFeature
Set oPartFeature = oDef.Features.Item(1)

Dim oRS As renderstyle
Set oRS = oPartDoc.RenderStyles.Item("gelb")

For Each oPartFeature In oDef.Features
Call oPartFeature.SetRenderStyle(kOverrideRenderStyle, oRS)
Next

---

Was mir jetzt fehlt, ist der genaue Wert den ich eintragen muss, wenn ich die Elemente wieder gemäss dem Material oder der Bauteilfarbe einfärben möchte. Die Werte "Standard" und "Default" funktionieren nicht bzw. sie greifen nicht auf die ursprünglich gewählte Bauteilfarbe oder Materialfarbe zurück.

Weiss vielleicht jemand von euch was für Werte da eingetragen werden müssen?

Gruss + Danke
L91

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Hier bitte!

Code:

---

Public Sub RemovePartOverrides()

Dim partDoc As PartDocument
Set partDoc = ThisApplication.ActiveDocument

Dim obj As Object
For Each obj In partDoc.ComponentDefinition.AppearanceOverridesObjects

If TypeOf obj Is SurfaceBody Then
obj.AppearanceSourceType = kPartAppearance

ElseIf TypeOf obj Is PartFeature Then
obj.AppearanceSourceType = kBodyAppearance

ElseIf TypeOf obj Is Face Then
obj.AppearanceSourceType = kFeatureAppearance
Else
MsgBox "Unexpected type with appearance override: " & TypeName(obj)
End If
Next
End Sub

---

Gruß Berno

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Besten Dank Berno

Das hat mich auf die richtige Spur gebracht!
Jetzt hab ichs hinbekommen.

Gruss
L91

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP