---

Hi forum

Ich habe ein Makro um in einem part mit einem klick direkt die ausgewählte fläche in einer bestimmten farbe einzufärben

allerdings funktioniert dies leider nicht wenn ich das part in der baugruppe geöffnet habe. also doppelklick auf das teil. dann wird ja alles andere durchsichtig.

hier mal der code, villeicht kann mir ja jemand helfen dies so anzupassen 

Code:

---

Public Sub Passflächen()

    Dim strColorName As String

    strColorName = "RAL 1012 Zitronengelb"

 

    On Error Resume Next

    Dim oPartDoc As PartDocument

    Set oPartDoc = ThisApplication.ActiveDocument

    If Err Then

        MsgBox "A part document must be active."

        Exit Sub

    End If

 

    Dim oRenderStyle As RenderStyle

    Set oRenderStyle = oPartDoc.RenderStyles.Item(strColorName)

    If Err Then

        MsgBox "The specified render style """ & strColorName & """ does not exist."

        Exit Sub

    End If

    On Error GoTo 0

 

    ' Create a list of the selected faces.

    Dim oFaceCollection As FaceCollection

    Set oFaceCollection = ThisApplication.TransientObjects.CreateFaceCollection

    Dim i As Integer

    For i = 1 To oPartDoc.SelectSet.Count

        On Error Resume Next

        Dim oFace As Face

        Set oFace = oPartDoc.SelectSet.Item(i)

        If Err.Number = 0 Then

            oFaceCollection.Add oFace

        End If

    Next

    ' Set the color of the selected faces.

    For Each oFace In oFaceCollection

        Call oFace.SetRenderStyle(kOverrideRenderStyle, oRenderStyle)

    Next

End Sub

---

Danke schonmal
Dero

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Probier mal den:

Code:

---

Public Sub Passflächen()

    Dim oObject As Object
    Dim oBool As Boolean
    oBool = True
    While oBool = True
        Set oObject = ThisApplication.CommandManager.Pick(kPartFaceFilter, "Wähle eine Fläche ...")
        oBool = FlaecheFaerben(oObject)
        ThisApplication.ActiveView.Update
    Wend

End Sub

Public Function FlaecheFaerben(oFace As Face) As Boolean
   
    If oFace Is Nothing Then
        FlaecheFaerben = False
        Exit Function
    End If
   
    Dim strColorName As String
    strColorName = "RAL 1012 Zitronengelb"

    Dim oRenderStyle As RenderStyle
    Set oRenderStyle = ThisApplication.ActiveEditDocument.RenderStyles.Item(strColorName)
    If Err Then
        MsgBox "The specified render style """ & strColorName & """ does not exist."
        Exit Function
    End If
   
    On Error GoTo 0
   
    If TypeOf oFace Is FaceProxy Then
        Set oFace = oFace.NativeObject
    End If
   
    Call oFace.SetRenderStyle(kOverrideRenderStyle, oRenderStyle)
   
    FlaecheFaerben = True
   
End Function

---

Das spart dir auch gleich noch in jedes Bauteil per Doppelklick reingehen zu müssen. Einfärben geht auch direkt in der Baugruppe. Beenden der Schleife mit ESC.

EDIT: Und wie ich grad feststellen mußte, geht es auch in der Bauteilbearbeitung eine transparent geschaltete Fläche eines Nachbarbauteils zu färben.   

------------------
MfG
Ralf

[Diese Nachricht wurde von rkauskh am 15. Aug. 2012 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP