---

Hallo zusammen,

ich möchte per VBA ein Bauteil in eine Baugruppe einfügen und dies an eine vorgegebene Position verschieben und durch vorgegeben Winkel im Raum ausrichten.

Das einfügen und Positionieren klappt einwandfrei. Nur beim Drehen, bzw. ausrichten komme ich nicht weiter.

Mir ist ehrlich gesagt nicht ganz klar was Inventor beim Drehen macht. Ich habe mit dem Matrix-Befehl "SetToRotation" herumgespielt.
Wenn ich das Bauteil nur um eine Achse drehen will funktioniert es einwandfrei.

Wenn ich das Bauteil mittels VBA um den xAchsen-Vektor(1,0,0) um 45°drehe und danach den Code nochmals laufen lassen müsste eigentlich eine Gesamtrotation von 90° rauskommen. Allerdings dreht er bei gar nicht weiter.
Anscheinend spielt bei der Rotation bereits die Orientierung des Bauteils ein Rolle.
wie kann ich dann ein bereits verdrehtes Teil einfach weiter drehen?

Vielleicht kann mir einer weiterhelfen...

Gruss Dennis

hier der Code:

Public Sub Rottest()

Dim oTeil As ComponentOccurrence

Dim otransgeom As TransientGeometry
Dim xAchse As Vector
Dim yAchse As Vector
Dim zAchse As Vector
Dim opunkt As Point
Dim oMatrix As Matrix

Dim neueAchse As Vector

Dim pi

pi = 4# * Atn(1#)
    'Referenz auf Applikation
    Dim oApp As Application
    Set oApp = ThisApplication

    'Referenz auf Dokument
    Dim oDoc As AssemblyDocument
    Dim oAsmCompDef As AssemblyComponentDefinition
   
    Set oDoc = oApp.ActiveDocument
    Set oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition
    Set otransgeom = oApp.TransientGeometry
    Set oMatrix = otransgeom.CreateMatrix
   
    Set oTeil = oAsmCompDef.Occurrences.Item(3)
   
   
    'achsen:
    Set xAchse = otransgeom.CreateVector(1, 0, 0)
    Set yAchse = otransgeom.CreateVector(0, 1, 0)
    Set zAchse = otransgeom.CreateVector(0, 0, 1)
   
    Set opunkt = otransgeom.CreatePoint(0, 0, 0)
   
     
   
    Call oMatrix.SetToRotation(90 * pi / 180, yAchse, opunkt)
    oTeil.Transformation = oMatrix

end sub

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Weiter gedreht wird in dem du den neuen (Gesamt)Winkel angibst. Das heißt in deinem Fall, ist das Teil schon um 45° gedreht, muß für eine weitere Drehung um 45° ein Winkel von 90° angegeben werden.

------------------
MfG
RK

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo rkauskh,

vielen Danke für die Antwort.

Das ist aber nur soweit hilfreich, wenn ich genau weiss, wie das Teil ausgerichtet ist.
Wenn es aber nun bereits im Raum verdreht liegt und ich es einfach um eine vorgegeben Achse, um einen bestimmten Winkel drehen möchte funktioniert das aber schon nicht mehr.
In gewisser Weise suche ich einen Befehl der einfach dreht und keine Rücksicht auf die aktuelle Lage nimmt.

Die einzige Idee die ich noch habe ist, die Positionsmatrix des Bauteils auszulesen und durch Matrizenmultiplikation mit einer Rotationsmatrix die neue Rotation durchführe. Naja empfinde ich aber etwas umständlich, hab die Hoffnung dass es etwas einfacher geht....

Gruss Dennis

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Zitat:

---

die Positionsmatrix des Bauteils auszulesen und durch Matrizenmultiplikation mit einer Rotationsmatrix die neue Rotation durchführe

---

Laut Hilfe soll es aber genauso gehen. Hab's ausprobiert, aber mein Versuchsteil dachte nicht daran sich zu drehen. Ich glaub ich hätte in der Schule beim Thema Matrizen doch besser aufpassen sollen. 

------------------
MfG
RK

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

hallo rkauskh,

bin nun endlich mal dazu gekommen, dass mit der Matrizenmultiplikation auszuprobieren:

Also bei mir funktioniert meine Gedachte vorgehensweise. Also Positionsmatrix des Bauteils auslesen und dann mit einer Rotationsmatrix drehen.

Hier ist mein Code.
Um den Code zu verwenden folgende Vorgehensweis: Neue Baugruppe, ein Bauteil reinladen (dieses am besten in den Ursprung legen, keine Abhängigkeiten vergeben). Bauteil selektieren und Code ausführen.
Jedes mal wenn der Code ausgeführt wird, wird das Bauteil um 30° um die x-Achse der Baugruppe gedreht.

Public Sub Rot_x()
'Rotation um x-Achse

Dim pi

pi = 4# * Atn(1#)

    'Referenz auf Applikation
    Dim oApp As Application
    Set oApp = ThisApplication

    'Referenz auf Dokument
    Dim oDoc As AssemblyDocument
    Set oDoc = oApp.ActiveDocument
   
    Dim oTransGeom As TransientGeometry
    Set oTransGeom = oApp.TransientGeometry

    Dim oPosMatrix As Matrix
    Dim oRotMatrix As Matrix

    Set oPosMatrix = oTransGeom.CreateMatrix
    Set oRotMatrix = oTransGeom.CreateMatrix

   
    Dim ss As SelectSet
    Set ss = oDoc.SelectSet
   
   
    'Bauteil aus Selektion:
    Dim oCompOcc As ComponentOccurrence
    Set oCompOcc = ss.Item(1)
   

    'Winkel 30°:
    Dim theta As Double
    theta = 30 * pi / 180

    'Postionsmatrix vom Bauteil:
    Set oPosMatrix = oCompOcc.Transformation

    'RotationsMatrix erzeugen:
    Set oRotMatrix = rot_x_Matrix(theta)
   
    'Matrizenmultiplikation:
    Call oRotMatrix.PostMultiplyBy(oPosMatrix)
   
   
    'Bauteil anhand Matrix positionieren:
    oCompOcc.Transformation = oRotMatrix
       

End Sub

Function rot_x_Matrix(theta As Double) As Matrix
'Rotation um x-Achse

Dim oMatrix As Matrix

    Set oMatrix = ThisApplication.TransientGeometry.CreateMatrix

    '1. Spalte
    oMatrix.Cell(1, 1) = 1
    oMatrix.Cell(2, 1) = 0
    oMatrix.Cell(3, 1) = 0
    oMatrix.Cell(4, 1) = 0
   
    '2. Spalte
    oMatrix.Cell(1, 2) = 0
    oMatrix.Cell(2, 2) = Cos(theta)
    oMatrix.Cell(3, 2) = Sin(theta)
    oMatrix.Cell(4, 2) = 0

    '3. Spalte
    oMatrix.Cell(1, 3) = 0
    oMatrix.Cell(2, 3) = -Sin(theta)
    oMatrix.Cell(3, 3) = Cos(theta)
    oMatrix.Cell(4, 2) = 0

    '4.Spalte
    oMatrix.Cell(1, 4) = 0
    oMatrix.Cell(2, 4) = 0
    oMatrix.Cell(3, 4) = 0
    oMatrix.Cell(4, 4) = 1
   
    Set rot_x_Matrix = oMatrix

End Function

Gruss Dennis

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Danke für den Code, vielleicht versteh ich damit ja mal wie das mit Matrizen funktioniert.   

------------------
MfG
RK

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP