---

Hallo!
Ich muss viele voneinander unabhängige Optionsfelder erstellen. Kann ich das manuelle Ändern des Gruppennamens unter Eigenschaften umgehen? Gibt es dafür ein VBA-Programm? Grüße, rg

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Romy100,

zunächst mal Herzlich Willkommen    auf CAD.de!

Mir ist kein VBA-Programm bekannt - allerdings ist Dein Problem sicherlich in einer Schleife lösbar á la: Nimm alle OptionButtons in diesem Blatt und mache damit...

Schmeiß´ doch mal den Makro-Recorder an, was der so ausspuckt - oder guck bei Herber, da gibt's das Thema schon >> klick <<

------------------
DIN1055.de  |  Lastannahmen für Anwender NEU: Foren zu DIN 1055

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo! Die Geschichte mit dem MakroRecorder habe ich schon versucht. D.h. ich wollte das Ändern des GroupNames mit Makro aufzeichnen, sodass ich den Befehl dafür kenne und sodann in VBA weiterbearbeiten. Das Problem ist allerdings, dass die Änderung des GroupNames nicht aufgezeichnet wird. Hast Du dazu eine Idee?
Grüße r100

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi Romy,

nach diesem Prinzip:

Code:

---

Sub OptionsButtenGruppieren()
    Dim oobElement As OLEObject
    For Each oobElement In ActiveSheet.OLEObjects
        If oobElement.progID = "Forms.OptionButton.1" Then
            If oobElement.Top >= Rows(7).Top And oobElement.Top < Rows(15).Top Then
                    oobElement.Object.GroupName = "Gruppe 11"
            ElseIf oobElement.Top >= Rows(15).Top And oobElement.Top < Rows(21).Top Then
                    oobElement.Object.GroupName = "Gruppe 22"
            End If
        End If
    Next oobElement
End Sub

---

------------------
Bis später,
Karin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank für Eure Beiträge, habe mittlerweile noch einen anderen Hinweis erhalten, den ich Euch auch zur Verfügung stellen möchte:

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub MakeOptButtons()
Dim objOpt As Object
Dim lngRow As Long, lngStart As Long, lngRowCount As Long
Dim intCol As Integer, intStart As Integer, intCount As Integer
Dim lngCalculation As Long

On Error GoTo ErrExit

With Application
  .ScreenUpdating = False
  .EnableEvents = False
  .DisplayAlerts = False
  lngCalculation = .Calculation
  .Calculation = xlCalculationManual
  .Cursor = xlWait
End With

lngStart = 6 ' Startzeile
lngRowCount = 80 ' Anzahl Zeilen

intStart = 2 ' Startspalte
intCount = 8 ' Buttons pro Zeile

For lngRow = lngStart To lngStart + lngRowCount
  For intCol = intStart To intStart + intCount
    Set objOpt = ActiveSheet.OLEObjects.Add(ClassType:="Forms.OptionButton.1", _
      Left:=Cells(lngRow, intCol).Left + 1, Top:=Cells(lngRow, intCol).Top + 1, _
      Width:=Cells(lngRow, intCol).Width - 1, Height:=Cells(lngRow, intCol).Height - 1)
    With objOpt
      .Object.Caption = CStr("")
      .Object.GroupName = ActiveSheet.Name & "_Grp" & lngRow
      .LinkedCell = Cells(lngRow, intCol).Address
      .Object.Value = (intCol = intStart)
    End With
    Set objOpt = Nothing
  Next
Next

ErrExit:

If Err.Number > 0 Then
  MsgBox Err.Number & vbLf & Err.Description, , "Fehler"
  Err.Clear
End If

With Application
  .ScreenUpdating = True
  .EnableEvents = True
  .DisplayAlerts = True
  .Calculation = lngCalculation
  .Cursor = xlDefault
End With

End Sub

Grüße
Romy100

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP