---

Hallo ich möchte über VB(über CommandButton)  einige Werte von Tabelle1 in Tabelle2 Übertragen aber die Zeile in der die Werte in Tabelle2 Übertragen werden müssen sollen von einem Wert in einer Zelle von Tabelle1 bestimmt Werden. Also nicht in Zelle B4 sonder B (Inhalt einer Zelle in Tabelle1) Wie bekomm ich das hin?

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

kannst du mal einige konkrete Beispiele nennen? Damit ich mir auch etwas darunter vorstellen kann.

------------------
Gruß
Nepumuk

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

KopievonSchichtplan.zip

Anbei die Datei, siehe die Programierung auf dem Button: statt [B4] möchte ich die Zeile (4) von Der KW (I3) Abhängig machen.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

versteh ich das richtig, dass das Makro sich 1. in der Zeile 1 den Namen und 2. in der Spalte A die KW suchen soll?

------------------
Gruß
Nepumuk

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Das Makro soll sich eigentlich gar nichts suchen; ich will nur die Position (jetzt B4 im Makro) formelgesteuert haben, also (z.B: [B I3+2]), damit der Text "6:00Uhr-14:00Uhr" in der richtgen Zeile steht. Ich würde die Befehlszeile einfach so oft schreiben wie ich sie bräuchte, also 1x für Sepp 1x für hias........

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

also sei mir nicht böse, aber das ist doch EDV zu Fuß. Versuch es mal mit diesem Makro für den Commandbutton:

Private Sub CommandButton1_Click()
    Dim lngRow As Long
    Dim objKWCell As Range, objNameCell As Range
    On Error Resume Next
    With Worksheets("Übersicht " & Right$(Cells(3, 1).Text, 2))
        If Err.Number <> 0 Then
            On Error GoTo exit_error
            Err.Raise Number:=vbObjectError + 1, _
                Description:="Übersichtstabelle für das Jahr " & _
                Right$(Cells(3, 1).Text, 2) & " nicht gefunden."
        End If
        On Error GoTo exit_error
        For lngRow = 6 To Cells(Rows.Count, 1).End(xlUp).Row
            Set objKWCell = .Columns(1).Find(What:="KW " & Cells(3, 9).Text, _
                LookAt:=xlWhole)
            If Not objKWCell Is Nothing Then
                Set objNameCell = .Rows(1).Find(What:=Cells(lngRow, 1).Text, _
                    LookAt:=xlWhole)
                If Not objNameCell Is Nothing Then
                    .Cells(objKWCell.Row, objNameCell.Column).Value = _
                        Cells(lngRow, 3).Text & " - " & Cells(lngRow, 5).Text
                Else
                    Err.Raise Number:=vbObjectError + 3, _
                        Description:="Name " & Cells(lngRow, 1).Text & _
                        " nicht in der Ubersichtstabelle."
                End If
            Else
                Err.Raise Number:=vbObjectError + 2, _
                    Description:="Kalenderwoche " & Cells(3, 9).Text & _
                    " nicht in der Ubersichtstabelle."
            End If
        Next
    End With
exit_sub:
    Set objKWCell = Nothing
    Set objNameCell = Nothing
    Exit Sub
exit_error:
    MsgBox "Fehler " & CStr(Err.Number) & vbLf & vbLf & _
        Err.Description & vbLf & vbLf & "Prgrammabbruch", 16, "Fehler"
    Resume exit_sub
End Sub

------------------
Gruß
Nepumuk

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Genau so sollŽs sein! 1000 Dank funktioniert einwandfrei auch wenn ich es gar nicht verstehe  wir sind halt doch (nur) Konstrukteure und haben in VB nur ein bisschen Anfängerwissen deswegen auch der simple "zu Fuss" Ansatz. UŽs sind unterwegs (schade das man nur 10 vergeben kann)

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hi,

Danke. Ich bin ja schon froh, dass du den Schreibfehler hier:

MsgBox "Fehler " & CStr(Err.Number) & vbLf & vbLf & _
  Err.Description & vbLf & vbLf & "Prgrammabbruch", 16, "Fehler"

nicht bemängelst. Sollte nämlich "Programmabbruch" lauten. :-)

------------------
Gruß
Nepumuk

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Da es einwandfrei läuft haben wir noch keinen "Prgrammabbruch" 
gehabt.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP