---

Hallo Me10 user

Wie muss man in einem Makro den Befehl DATE editieren, oder einbinden, damit das Datum folgendermassen erscheint?: 02.12.2003

Wenn man den Befehl im Makro einfügt, erscheint
folgendes: '26-Oct-99 10:26:58'

Ich brauche nur das Datum mit Punkten, nicht mit Bindestrich und ohne die Zeit.

Hat schon jemand mal sowas gebraucht?

Gruss
Marcel

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Marcel,

also einen fertigen Befehl dafür kenn ich auch nicht, aber Du kannst den String doch außeinanderpflücken:

Let Tag (SUBSTR Datumstring 1 2)
Let Monat (SUBSTR Datumstr 4 3)
Let Jahr (SUBSTR Datumstr 8 2)

Ich weiß jetzt bloß nicht, ob die Tage 1 - 9 als "01" oder nur als "1"
kommen, wenn letzteres der Fall ist, könntest Du in einer Schleife nach den Bindestrichen suchen.

Den Monat müßtest Du dann in Zahlen "übersetzen", da gibts bestimmt auch ne elegante Lösung.

Ist jetzt nur mal so schnell hingetippt, muß natürlich noch ausgeschmückt werden.

Gruß
Andreas

[Diese Nachricht wurde von Andreas 253 am 02. Dez. 2003 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Andreas' Lösung war eh schon ausführlich - hier noch eine fertige Lösung (ich glaub, richtig "elegant" kann man das Monat nicht konvertieren - dafür hab ich damals schon deutsches & englicsches ME10 berücksichtigt  ):

 

Code:

---

LET D (DATE)
  LET Tag (SUBSTR D 1 2)
  IF ((SUBSTR Tag 1 1) = ' ')
    LET Tag ('0' + SUBSTR Tag 2 1)
  END_IF
  LET Monat (UPC (SUBSTR D 4 3))
  IF (Monat='JAN')
    LET Monat '01'
  ELSE_IF (Monat='FEB')
    LET Monat '02'
  ELSE_IF (Monat='MAR')
    LET Monat '03'
  ELSE_IF (Monat='APR')
    LET Monat '04'
  ELSE_IF ((Monat='MAI') OR (Monat='MAY'))
    LET Monat '05'
  ELSE_IF (Monat='JUN')
    LET Monat '06'
  ELSE_IF (Monat='JUL')
    LET Monat '07'
  ELSE_IF (Monat='AUG')
    LET Monat '08'
  ELSE_IF (Monat='SEP')
    LET Monat '09'
  ELSE_IF ((Monat='OKT') OR (Monat='OCT'))
    LET Monat '10'
  ELSE_IF (Monat='NOV')
    LET Monat '11'
  ELSE_IF ((Monat='DEZ') OR (Monat='DEC'))
    LET Monat '12'
  ELSE
    LET Monat 'XX'
  END_IF
  {BIS ME10 8.5:}
  LET Jahr (SUBSTR D 8 2)
  {AB ME10 8.7:}
  LET Jahr (SUBSTR D 8 4)
  LET Fertiges_datum (Tag + '.' + Monat + '.' + Jahr)

---

Ab 8.7 wurde die Jahreszahl vierstellig ausgegeben (2000-kompatibel!)

Gruß aus Österreich,
Hannes

------------------
undsedadnawosondasoisdeswossedan undwosondasdadnsa

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP