---

Hallo zusammen! Ich habe folgenden APDL Baustein, der mir Ergebnisdaten in eine Datei schreibt.

ETABLE,,CENT,X
ETABLE,,CENT,Y
ETABLE,,CENT,Z
ETABLE,,U,X
ETABLE,,U,Y
ETABLE,,U,Z

*GET,nrel,ELEM,,COUNT

*DIM,create,ARRAY,nrel,6,1

*VGET,create(1,1),ELEM,,ETAB,CENTX,,2
*VGET,create(1,2),ELEM,,ETAB,CENTY,,2
*VGET,create(1,3),ELEM,,ETAB,CENTZ,,2

*VGET,create(1,4),ELEM,,ETAB,UX,,2
*VGET,create(1,5),ELEM,,ETAB,UY,,2
*VGET,create(1,6),ELEM,,ETAB,UZ,,2

*CFOPEN,'create','dat','c:\ansyswork'
*VWRITE,'CENTX','CENTY','CENTZ','UX','UY','UZ',,,
(a,a,a,a,a,a)
*VWRITE,create(1,1),create(1,2),create(1,3),create(1,4),create(1,5),create(1,6),,,
((f12.3),(f12.3),(f12.3),(f12.3),(f12.3),(f12.3))
*CFCLOS

Jetzt möchte ich vor die Daten noch die jeweilige Elementnummer schreiben, finde dazu aber kein Kommando. Hat jemand eine Idee wie ich das hinbekomme?
Vielen Dank, grammar

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Müsste nur wissen, ob ich davon ausgehen kann, dass Ihr Modell eine lückenlose Nummerierung der Elemente aufweist oder nicht.

Für beides könnte ich schlell eine Lösung programmieren.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

So sollte es erst einmal funktionieren:

ETABLE,,CENT,X
ETABLE,,CENT,Y
ETABLE,,CENT,Z
ETABLE,,U,X
ETABLE,,U,Y
ETABLE,,U,Z

*get,max_element_nr,elem,0,num,max

*DIM,create,ARRAY,max_element_nr,8,1

*vget,create(1,7),elem,,esel,,,2    ! Status der Selektion eines jeden Elementes

*do,laufvar1,1,max_element_nr,1
  *if,create(laufvar1,7),eq,1,then
    create(laufvar1,8)=laufvar1
  *endif
*enddo

*vmask,create(1,7)
*VGET,create(1,1),ELEM,,ETAB,CENTX,,2
*vmask,create(1,7)
*VGET,create(1,2),ELEM,,ETAB,CENTY,,2
*vmask,create(1,7)
*VGET,create(1,3),ELEM,,ETAB,CENTZ,,2

*vmask,create(1,7)
*VGET,create(1,4),ELEM,,ETAB,UX,,2
*vmask,create(1,7)
*VGET,create(1,5),ELEM,,ETAB,UY,,2
*vmask,create(1,7)
*VGET,create(1,6),ELEM,,ETAB,UZ,,2

*CFOPEN,'create','dat'
*VWRITE,'ELEM','CENTX','CENTY','CENTZ','UX','UY','UZ',,,
(a,a,a,a,a,a)
*VWRITE,create(1,8),create(1,1),create(1,2),create(1,3),create(1,4),create(1,5),create(1,6),,,
((f12.3),(f12.3),(f12.3),(f12.3),(f12.3),(f12.3),(f12.3))
*CFCLOS

Für jedes Element, welches nicht selektiert oder definiert ist erscheint jetzt eine Zeile voller Nullen.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Also ich muss zugeben dass ich gar nicht weiss ob die Elemente durchnummeriert sind. Ich habe dies zumindest nicht explizit beim Preprocessing festgelegt.
Also evtl. nicht konsistent durchnummeriert. Ich weiss auch nicht, wie ich mir zu jedem Element die Nummer anzeigen lasse.

Vielleicht hilft das ja um meine Frage besser zu verstehen =)

Danke, Grammar

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ah Sie waren schneller, ich werds gleich mal ausprobieren. Vielen Dank schon mal !!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Funktioniert tadellos ! Herzlichen Dank!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Bitte sehr, immer gern!
Die Zeilen mit den Nullen ließen sich noch „wegprogrammieren“. Wenn es aber so ausreicht …

Weiterhin gutes Gelingen!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Werte_auslesen.txt

… um dies abzuschließen, hier noch eine mögliche „saubere“ Lösung.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP