! Konstanten
  lange=20
  breite=6
  dicke=0.1
  emodul=3E4
  elange=breite/8
   
! Elemente: 
    /prep7  
    et, 1,  shell63 
    keyopt,1,1,0 ! 0 -> Biegung + Membran; 1 -> Membran; 2 -> Biegung   
    r,1,dicke
    
! Material  
    mp,   ex,   1,    emodul   
    mp,   ey,   1,    emodul   
    mp,   ez,   1,    emodul   
    mp, nuxy,   1,    0   
    mp, nuyz,   1,    0   
    mp, nuxz,   1,    0   
    
! Geometrie
    csys,0 
    rect,0,lange,0,breite

! Netz
    esize,elange
    alls
    amesh,all

! Randbedinungen (Lager)
    /solu
    alls  $csys,0
    nsel,s,loc,x,0
    d,all,ux,,,,,,uz,roty
    nsel,r,loc,y,breite/2
    d,all,uy
    alls

! Randbedinungen (Knotenkräfte)
    csys,0
    nsel,s,loc,x,lange
    f,all,fz,6
    alls
save 

! Lösung
    antype,static
    solve
save 

!Pfad erstellen 
    /post1
    path,derpfad,2,,300
    ppath,1,,0,breite/2,0,0
    ppath,2,,lange,breite/2,0,0
    pdef,s_x,s,x   $pdef,s_y,s,y    $pdef,s_z,s,z
!     plpath,s_x,s_y,s_z
    /out,pfad,txt
    prpath,s_x,s_y,s_z ! => Ist es möglich diese Liste ohne wiederholte Überschriften 
    /out

save
/eof