finish

parsav,all,
/Clear,start
parres,new,
!/input,Buttons,mac

!/UIS,MSGPOP,3
/VIEW,1,,,1 
/Prep7

Stahl=3
MP,EX,Stahl,210000 
MP,PRXY,Stahl,0.3  


ET,1,SOLID185
KEYOPT,1,6,1

ET,3,MPC184
KEYOPT,3,1,1    
!____________________________________________
!!!!!!!!!!!!!Modell erstellen!!!!!Anfang
    laang=500
    laang_block=laang-5
    breit=10/2
    hoch=15/2

BLOCK,0,laang_block,-breit,breit,-hoch,hoch, 


alls
type,1
esize,5
mat,Stahl
vmesh,all
alls

nsel,s,loc,x,0
cm,Lager,node

nsel,s,loc,x,laang_block
cm,Last_slave,node


!Lasteinleitung
nsel,all 

*get,node_max,node,,NUM,MAX
Last=1+node_max
nsel,none
n,Last,laang
cm,Last,node


!________Balkenspinne fur Lasteinleitung
CMSEL,S,Last_slave,node

*get,nanz,node,,count
*get,nmax,node,,num,min 	!niedrigste Knotennummer
narb=nmax   	        	!Arbeits-Knoten
*do,i,1,nanz		 	!Schleife mit Nanz durchlaufen
type,3
e,last,narb
narb=ndnext(narb)        	!Arbeitsknoten auf nñchste Knotennummer
*enddo
alls

!FederLager
nsel,all
*get,node_max,node,,NUM,MAX
FederLager_1=1+node_max
nsel,none
n,FederLager_1,laang ,5
cm,FederLager_1,node         !242


nsel,none
FederLager_2=2+node_max
!n,FederLager_2,laang ,5
!cm,FederLager_2,node         !242



!Federanbindung
nsel,all
*get,node_max,node,,NUM,MAX
FederBalken=1+node_max
nsel,none
n,FederBalken,laang ,5
cm,FederBalken,node           !243


!________Balkenspinne fur !Federanbindung
CMSEL,S,Last_slave,node

*get,nanz,node,,count
*get,nmax,node,,num,min 	!niedrigste Knotennummer
narb=nmax   	        	!Arbeits-Knoten
*do,i,1,nanz		 	!Schleife mit Nanz durchlaufen
type,3
e,FederBalken,narb
narb=ndnext(narb)        	!Arbeitsknoten auf nñchste Knotennummer
*enddo
alls  
!!!!!!!!!!!!!Modell erstellen!!!!!Ende  
!____________________________________________
   



!   Federelemente Combin39  zur Erstellung der zweiten Feder Uy  
ET,5,39
KEYOPT,5,3,2              !uy 


!sehr weiche Feder-für den ersten Lastschritt
 Steif_1=0.1
R,3,0.0,0.0,1.0,Steif_1,2.0,Steif_1*2
alls
!harte Feder-für den zweiten Lastschritt-Nennsteifigkeit
Steif_2=50
R,4,0.0,0.0,1.0,Steif_2   ,2.0,Steif_2*2
alls

!Definition der "zweiten Feder" mit geringer Steifigkeit für ersten Rechenschritt 
TYPE,5
REAL,3
ESEL,none
cmsel,s,FederLager_1,node       $   cmsel,a,FederBalken,node  
e,FederLager_1,FederBalken
CM,erste_Feder_Y,ELEM     

ESEL,none
alls
Finish

/Solu

ANTYPE,0
NSUBST,10,1000,10
OUTRES,ERASE
OUTRES,ALL,ALL
NLGEOM,on
time,0

alls

cmsel,s,Lager,node 

d,all,all                   !Einspannung des Balkens


nsel,s,,,FederLager_1       !Festsetzen des Knotens für die Zusatzfeder
d,all,all
alls

cmsel,s,Last,node
f,all,fy,500                !Last zur Auslenkung des Hauptfeder (Balken)

alls  

lswrite,1                  !Definieren des ersten Lastschritts



 time,2     

finish

/prep7
alls

cmsel,s,erste_Feder_Y,ELEM       !Selektieren des Federelements


emodif,all,real,4         !Ändern der Steifigkeit auf Nennsteifigkeit (harte Feder)
!!!!!!!!hier mal REAL 3 einsetzten > viel größere Auslenkung


alls
FINISH 

/Solu
alls
cmsel,s,Last,node

f,all,fy,0.1                 !Verringern der Federkraft von 500N auf 0.1N

alls

lswrite,2                   !Definieren des zweiten Lastschritts

LSSOLVE,1,2,1              !Lösen 

FINISH  
/POST1  

SET,1

cmsel,s,Last,node     $   *get,Last,node,,NUM,MAX 

*get, Auslenk_x_1,node,Last,u,x,
*get, Auslenk_y_1,node,Last,u,y,
*get, Auslenk_z_1,node,Last,u,z,



SET,LAST

cmsel,s,Last,node     $   *get,Last,node,,NUM,MAX 

*get, Auslenk_x_2,node,Last,u,x,
*get, Auslenk_y_2,node,Last,u,y,
*get, Auslenk_z_2,node,Last,u,z,

PLNSOL, u,y, 2,1.0  
alls
  ANTIME,20,0.1, ,1,2,0,2