!edge für gerade Doppelleitung
!harmonisch gerechnet
!keine Symmetrieausnutzung
!Schätzing 22.2.2006 für Peters
finish
/clear
*abbr,2-Draht,/input,zwei_draht_3D.inp
rad=10e-3      !Radius des Leiters
abst=3*rad     !Abstand der Leiter (Mitte-Mitte)
lang=1000e-3    !Länge des Leiters
radin=abst+2*rad    !umgebende Luft innen
radau=240e-3   !Umgebende Luft außen
strom=1
/prep7
et,1,solid117    !Luft
et,2,solid117,1  !Leiter
mp,murx,1,1	 !Luft (rel. magn. Permeabilität)
mp,murx,2,1	 !Leiter (rel. magn. Permeabilität)
mp,rsvx,2,1/56e6 !Leiter (spez. el. Widerstand
!-----Geometrie---
/view,,1,2,3
cyl4,0,0,radau,  0,, 90
cyl4,0,0,radin,  0,, 90
cyl4, abst/2,0,rad,  0,, 90
cyl4, abst/2,0,rad, 90,,180
aovlap,all
numcmp,area
!A1-2:Leiter  A3:Luft außen  A4:Luft innen
!------Hilfs-Vernetzung-Leiter----
et,3,mesh200,7   !für Flächen
type,3
mat,2
esize,rad/4
mshape,0,3d  
mshkey,1
amesh,1,2
!-------Luft außen----------
csys,1
lsel,s,loc,x,(radau+radin)/2
lesize,all,,,3,1/3
mshape,0,2d
mshkey,1
esize,,9
mat,1
amesh,3
csys,0
!-------Luft innen---------------
esize,rad/4
mshape,2,2d
mshkey,2
amesh,4
!------Symmetrie-------------------
!--normalerweise würde man hier nur ein Viertel rechnen
arsym,x,all
nummrg,node
nummrg,kpoi
arsym,y,all
nummrg,node
nummrg,kpoi
!------Extrusion----------
type,1
mat,1
esize,,4
vext,1,16,1,,,lang
aclear,1,16
!------Leitereigenschaften-ändern--------
vsel,s,,,1,2
vsel,a,,,9,10
vsel,a,,,5,6
vsel,a,,,13,14
eslv
emodif,all,mat,2
emodif,all,type,2

!----Randbedingungen--------------
allsel
nsel,s,ext
d,all,az,0

!----Last1----
esel,s,mat,,2
nsle,s,1
nsel,r,loc,z,0
nsel,r,loc,x,0,radin
cp,1,volt,all
*get,n1,node,,num,min
f,n1,amps,strom
!----Last2----
esel,s,mat,,2
nsle,s,1
nsel,r,loc,z,0
nsel,r,loc,x,0,-radin
cp,2,volt,all
*get,n2,node,,num,min
f,n2,amps,-strom
!------Massepotential-------------------
esel,s,mat,,2
nsle,s,1
nsel,r,loc,z,lang
d,all,volt,0
!------Lösung-----
/solu
allsel

antype,harm
harfrq,0.01   !Gleichstrom
solve

!------Auswertung------
/post1
set,1,1
plns,b,sum
   
allsel
etable,energie,sene
ssum
*get,sumenergie,ssum,,item,energie
ind_H=2*sumenergie/strom/strom
ind_nH=ind_H*1e9
!ind_nH=530 nH/m     ANSYS
!ind_nH=539,444 nH/m analytischer Wert