!aus dem Forum von xsefa
!Schätzing, 6.5.2016


FINISH
/CLEAR
*abbr,xsefa2,/input,xsefa2,txt

tief=6
hoch=2
lang1=6
langboe=9.46
lang2=15.46
breit=5
!----Aufstandsfläche-----
x1=4.6
x2=5.2
y1=hoch
y2=-tief
z1=2.3
z2=2.7
mw=(z2-z1)/2

/PREP7
!*  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,3441.4
MPDATA,PRXY,1,,0.41
TB,DP,1,,,
TBMODIF,1,1,20  
TBMODIF,1,2,25  
TBMODIF,1,3,0   
et,1,solid65
!*  
KEYOPT,1,2,0
KEYOPT,1,3,0
KEYOPT,1,6,0
!*

!----Geometrie--------
block,0,lang2,0,-tief,0,breit  !V1
block,0,lang1,0, hoch,0,breit  !V2
block,0,langboe,0,hoch,0,breit !V3
vdele,3
v,22,14,15,20,12,11            !V3
block,x1,x2,y1,y2,0,breit
block,x1,x2,y1,y2,z1,z2        !Aufstandsfläche
block,0,lang2,-tief,hoch,0,breit/2 !nur für Symmetriefläche
vovlap,all
vdele,16
numcmp,volu

!-----Vernetzung--------------
esize,mw*2    !Elementgröße
vsweep,all
!A70 und 80: Aufstandsfläche
eplot

! ------------------------------------------
! Belastung xxx kN auf die Aufstandsfläche
! ------------------------------------------
SFA,70,1,PRES,400
sfa,80,1,pres,400
! ------------------------------------------
! Randbedingungen
! ------------------------------------------
nsel,s,loc,x,0
nsel,a,loc,x,lang2
d,all,UX,0

nsel,s,loc,z,0
nsel,a,loc,z,breit
d,all,UZ,0

nsel,s,loc,y,-tief
d,all,UY,0

!acel,,9.81 Erdbeschleunigung: ja oder nein?!

allsel
!---------Lösung------
/solu
nsubst,10
outres,all,all
!solcontrol,on
solve
!---------Auswertung----------
/post1
/VIEW,1,1,2,3
/plopts,minm,0
plns,s,int

/eof

!---Darstellung in einer Symmetrieebene
nsel,s,loc,z,0,breit/2
esln,s,1
/dscale,1,1  !wahre Verschiebung
plns,u,sum

!-----neu skaliert--------
/cont,,9,0,,0.02
plns,u,sum