!wicklung 3D
!stromdichtegespeist
!Symmetrie-Ausnutzung
!ohne Randelemente
!mit Kern
!Schätzing, 28.3.2011

finish $/clear

*abbr,wick3D_3,/input,wick3D_3,txt


keho=200e-3     !Kern-Höhe
kebr=400e-3     !Kern-Breite
kedi=40e-3      !Kern-Dicke
lusp=30e-3      !Luftspalt
iso=2e-3        !Isolation

wiradin=30e-3  !wicklung1 Radius Innen
wiradin=kedi/sqrt(2)+iso
wiradau=36e-3  !wicklung1 Radius Außen
wiradau=wiradin+50e-3
wiho=6e-3      !wicklung1 Höhe 
wiho=(keho-2*kedi-lusp)/2-2*iso


beradin=60e-3   !Bereich Radius Innen

strdi=1         !Strom-Dichte

mw=4e-3         !Maschenweite
!-------------------------------
/prep7
et,1,solid97,0

mp,murx,1,1        !Luft
mp,murx,2,1        !Wicklung
mp,murx,3,2000     !Kern
mp,murx,4,1        !Luftspalt (für leichtere Selektion)

!-------Geometrie--------
!--------Kern-----------
block,0,kedi/2,0,kedi/2,0,keho/2
block,0,kebr/2,0,kedi/2,keho/2-kedi,keho/2
block,kebr/2-kedi,kebr/2,0,kedi/2,0,keho/2

!-------Luftspalt-----
block,0,kedi*2,0,kedi/2,0,lusp/2
block,0,kedi/2,0,kedi*2,0,lusp/2
block,0,kedi*2,0,kedi*2,0,lusp/2

!--------Wicklung---------
cylind,wiradin,wiradau,lusp/2+iso,lusp/2+iso+wiho,  0, 90

!--------Umgebungsluft---------
block,0,kebr/2,0,keho/2,0,keho/2

vovlap,all
numcmp,volu

!/eof
!V1:Wick   V11:Luft
!V2,6,7,10      :Luftspalt
!V3,4,5,8,9      :Kern

!-----Vernetzung--------------  
!-----wicklung-------
type,1
mat,2
esize,mw
vmesh,1
!-----Luftspalt-------
mat,4
vmesh,2
vmesh,7
vmesh,6
vmesh,10
!------Kern-------
mat,3
vmesh,3,5
vmesh,8,9
!-------umgebungsluft---
mat,1
esize
mshkey,0
mshape,1,3D
vmesh,all

!------Rand----
nsel,s,loc,x,kebr/2
nsel,a,loc,y,keho/2
nsel,a,loc,z,keho/2
d,all,ax,0
d,all,ay,0
d,all,az,0

!------Drehung des Element-Koordintensystems---------
local,11,1   
esel,s,mat,,2
emodif,all,esys,11
csys,0

!----Last-------
esel,s,mat,,2
strdi=1e6
bfe,all,js,1,,strdi
allsel

!--------Symmetrie-------
nsel,s,loc,y,0
dsym,asym,y
nsel,s,loc,x,0
dsym,asym,x


allsel
!-------Lösung---------
/solu
solve
!-------Auswertung-----
/post1
esel,s,mat,,2
plvect,jt

!/eof

allsel
plns,b,sum

/eof

esel,s,mat,,4
plns,b,sum