!Temperaturausgleich nach gwen
!bearbeitet: Schätzing, 30.7.07

! Zwei sich beruehrende Wuerfel, die anfangs ein unterschiedliches Temp.-Niveau besitzen,
! was sich aber dann 5 min ausgleichen soll.
! Alle Temperaturen jeden Zeitschrittes sollen von jedem Knoten gespeichert werden.

!Verbindungsfläche beider Würfel liegt in der y-z-Ebene
!Zwischen beiden Würfeln liegt eine wärmeleitende Folie,
!die bis zum Zeitpunkt t0 schlecht leitet und danach gut leitet 

  fini
  /clear
*abbr,temp-aus,/input,temp_aus_2,txt 
*abbr,Status,*stat,temp_node


  t0=1e-3
  tend=5*60
  nstep=60
nstep=10
  dt=(tend-t0)/(nstep)

a=100e-3  !Kantenlänge der Würfel
da=a/10   !Elementkantenlänge
fd=1e-6   !Foliendicke

! ### PREPROCESSOR ################################
 
 /prep7

! --- geometrie ----------------------------------

! Wuerfel A:
  block,-a,0,0,da,0,da
! Folie
  block,0,fd,0,da,0,da
! Wuerfel B:
  block,fd,fd+a,0,da,0,da
vglue,all
numcmp,volu
!V1: WürfelA, V2: Folie, V3:WürfelB
 
! --- Elementtyp und Material ------------------------
  et,1,70
!Material 1  Würfel A Stahl
  mp,kxx,1,52
  mp,dens,1,7850
  mp,c,1,460
!Material 2  Würfel B Stahl
  mp,kxx,2,52
  mp,dens,2,7850
  mp,c,2,460
!Material 3  Folie schlecht leitend Luft
  mp,kxx,3,0.01
  mp,dens,3,1.3
  mp,c,3,1000
!Material 4  Folie gut leitend Kupferpaste
  mp,kxx,4,350
  mp,dens,4,8900
  mp,c,4,380

!----Vernetzung------  
esize,da
mat,1
vmesh,1   !Würfel A
mat,2
vmesh,3   !Würfel B
mat,3
vmesh,2   !Folie

!---Anfangsbedingungen---
esel,s,mat,,1   !Würfel A
nsle
ic,all,temp,20
esel,s,mat,,3   !Folie
nsle
ic,all,temp,20
esel,s,mat,,2   !Würfel B
nsle
ic,all,temp,80

! ### SOLUTION #####################################

/solu
allsel
antype,trans
kbc,1
outres,all,all
time,t0/2
solve
time,t0
solve
 
!*** Berechnung der Temperatur von t0 bis tend
/prep7
esel,s,mat,,3     !Folie
emodif,all,mat,4  !Eigenschaft ändern
/solu
allsel
antype,trans,rest
*do,i,1,nstep
time,t0+dt*i
solve
*enddo


! ### POSTPROCESSOR ################################

   /post1
   plnsol,temp

!/eof

!----Speichern der Knotentemperaturen in einem Array---
allsel
*get,n_anz,node,,count    !Knotenanzahl
*get,n_min,node,,num,min  !kleinste Knotennummer
*dim,temp_node,array,n_anz,nstep+3


!----Platz1---Knotennummer-----
n_arb=n_min   !Arbeitsknoten
*do,i,1,n_anz
temp_node(i,1)=n_arb
n_arb=ndnext(n_arb)
*enddo
!---weitere Plätze-Temperaturen--
!---es existieren nstep+2 Lösungen----
set,first
*do,j,2,nstep+3
  n_arb=n_min   !Arbeitsknoten
  *do,i,1,n_anz
    temp_node(i,j)=temp(n_arb)
    n_arb=ndnext(n_arb)
  *enddo  !i
  set,next
*enddo  !j