!Wärmestrom in nur jeweils einen Knoten
!mit Laufanweisung
!Schätzing, 21.11.2012 15.1.2014

finish
/clear

*abbr,tauer2a,/input,tauer2a,txt


!-----Parameter-----
pb=40e-3	!Plattenbreite: 40mm
pd=10e-3	!Plattendicke: 10mm
pl=150e-3	!Plattenlänge: 300mm
eg=2.5e-3       !Element-Größe
vv=1e-3         !Vorschubgeschwindigkeit  1mm/s
tumg=20         !Umgebungstemperatur

!---Aufruf Preprozessor----

/prep7		!ruft den Peprozessor auf
et,1,solid70	!vereinbart Elementtyp (Quader mit 20 Punkten)
mp,dens,1,8400	!Dichte des alloy617
mp,kxx,1,15
mp,c,1,400


!----Geometrie----
block,0,pl,-pb/2,+pb/2,0,pd	!generiert eine 3-dimensionale Platte

/view,,-1,1,-1
/ang,,-120

!----Vernetzung----
esize,eg	!Festlegung der Maschengröße des Netzes
vmesh,all	!Ausweitung des Netzes auf das gesamte Volumen


!----Randbedingung------
nsel,s,ext
sf,all,conv,200,tumg

allsel
!----Lösung----
/solu		!Aufruf des Lösungsabschnittes
antype,trans	!transiente Analysetyp eingestellt
tunif,tumg
outres,all,last
last=1000       !Wärmestrom
sw=eg/vv        !Schrittweite der Zeit

!---Startschritt-----
time,1e-12      !Zeit nahe Null
solve

!-----Schritte-------
*do,i,1,30
time,i*sw
fdele,all,all
nsel,s,loc,x,(i-1)*eg
nsel,r,loc,y,0
nsel,r,loc,z,0
f,all,heat,last
allsel
solve
*enddo


!-----Auswertung-------
/post1
/plopts,minm,0
/cont,,9,20,,1500
plns,temp


/eof

!---Animation----------
ANDATA,0.5, ,2,1,31,1,0,0