!aus dem Forum von schnase
!Schätzing, 11.6.2012

finish
/clear
*abbr,schnase3,/input,schnase3,txt


/PREP7  
/Title, Vorbetrachtung Magnetkreis


!----Elementtypen------
 
ET,1,PLANE53,,,1              ! Luft 
ET,2,PLANE53,,,1              ! Blech 
ET,3,Plane53,,,1              ! Spule
ET,4,Plane53,,,1              ! Kern (Eisen) 
ET,5,Plane53,,,1              ! Gehäuse(Alu)

!----Material-------

MP,MURX,1,1               ! Permeabilität (Luft)

MP,MURX,2,2000            ! Permeability (Blechstreifen)
MP,MURX,3,1               ! Permeability (Spulen)
MP,MURX,4,1000            ! Permeability (Kern)
MP,Murx,5,1               ! Permeabilitaet (ALU)


!---Geometrie-----
radlu=50e-3    !Radius Luft
radge=20e-3    !Radius Gehäuse
hoge=35e-3     !Höhe Gehäuse
radsp=10e-3    !Radius Spule
hosp=25e-3     !Höhe Spule
radke=5e-3     !Radius Kern
lusp=1e-3      !Luftspalt
radbl=30e-3    !Radius Blech
dibl=0.5e-3    !Dicke Blech

/pnum,Area,1                            !Nummerierung der Areas   
  
rectng,0,radke,0,-hosp
rectng,radke,radsp,0,-hosp
rectng,0,radbl,lusp,lusp+dibl
pcirc,,radlu,-90,90


AOVLAP,ALL                              ! Überschneidende Areas neu aufteilen
NUMCMP,AREA                             ! Compress out unused area numbers
APLOT                                   ! neu plotten
!A1:Kern, A4:Luft, A3:Spule, A2:Blech
!/eof

!----mesh-----

type,2 $mat,2            !Blechstreifen
esize,dibl/2
amesh,2


type,3 $mat,3            !Spule
esize,radke/4
amesh,3

type,4 $mat,4            !Kern
amesh,1

type,1 $mat,1            !restliche Luft
esize,radke 
amesh,4


ESEL,S,MAT,,2         ! Selection des Blech bzw. Material 4   
CM,Blech,ELEM         ! Componente Blech erstellen

FMAGBC,'BLECH'          
ALLSEL,ALL

!----------Stromdichte in den Spulen----------
! Querschnitt einer Spule ist 5x25 mm
! als Stromdichte bei 100 Windungen und 8 A
! 100*8/(0.005*0.025)= 6.4e6  

!----Spule Wert Positiv
esel,s,mat,,3
BFe,all,JS,, , ,6.4e6   


!------Flux Parallel an der Aussenseite-------
allsel
lsel,s,ext
nsll,s,1
d,all,az,0

!-----Lösung-----
allsel
/solu
solve

!----Auswertung-----
/post1
plf2d
/wait,1
plns,b,sum

!/eof

!=============mechanisch===========
/prep7
ET,1,0              ! Luft 
ET,2,PLANE82,,,1    ! Blech 
ET,3,0              ! Spule
ET,4,0              ! Kern (Eisen) 
ET,5,0              ! Gehäuse(Alu)

mp,ex,2,210e9
mp,nuxy,2,0.3
mp,dens,2,7860

!----Randbedingungen-----
esel,s,mat,,2
nsle
nsel,r,loc,x,radbl
d,all,ux,0
d,all,uy,0
nsel,all

!--------------Lösung-------
/solu
esel,s,mat,,2
ldread,forc,,,,,,rmg
solve

!------Auswertung------
/post1
pldi,2
/wait,1
plns,s,eqv

n1=node(0,lusp,0)        !Weg-Messpunkte
*get,yweg,node,n1,u,y    !Durchbiegung
!yweg=-0.0158e-3