!rotierender Lichtbogen
!runde Platte ohne Bohrung
!Schätzing, 1997
fini
/clear
*abbr,rot_licht,/input,rot_licht,inp

rand=30e-3   !Plattengröße
rad=10e-3    !Lichtbogenspur
breit=3e-3   !Spurbreite
dick=1e-3    !Plattendicke

!-------------------------------------
/prep7  
et,1,mesh200,6   !Verentzungshilfe
et,2,solid5,8 
!emunit,mks  
mp,kxx,1,84 
mp,rsvx,1,1/17e6
mp,c,1,460  
mp,dens,1,7860 

!----Geometrie--------- 
pcirc,rad-breit,rad
pcirc,rad,rad+breit      
pcirc,,rand,  0, 90
pcirc,,rand, 90,180
pcirc,,rand,180,270
pcirc,,rand,270,360
aovlap,all
numcmp,area
!A1-4:innen, A13-16:außen
!A5-12:Spur

  
/triad,off  
!----vernetzung------
mshape,0
mshkey,1   !mapped
!esize,breit/3
csys,1
lsel,s,loc,x,rad
teiler=12
lesize,all,,,teiler
csys,0
amesh,5,12

mshkey,0
esize,breit
amesh,13,16
amesh,1,4

!----Extrudieren-------
type,2
esize,,1  
vext,all,,,0,0,-dick
aclear,all     !Hilfselemente löschen
!-----------

!/eof

!---Lasten----- 
tunif,20   
sf,all,conv,10,20 
allsel
!-------Lösung------------
/solu   
antype,trans
kbc,1   
outres,,all 
!--hier-nur-ein-Umlauf----
pi=4*atan(1)
winkel=90/teiler
*do,i,1,4*teiler   
xko=rad*cos(i*winkel*pi/180)
yko=rad*sin(i*winkel*pi/180)
nf=node(xko,yko,0)     !N-Fuss
fdele,all
f,nf,heat,250*8
time,i*13.2/1000/24
time,i*50/1000/24

solve
*enddo


!--------Auswertung---------------
/post1
/plopts,minm,0
/cont,,,20,5,1600

*do,i,1,4*teiler    
set,i,1
plns,temp
*enddo