!Ermittlung der Potentialverteilung
!eines Zylinders mit Ellipse-Riss
!Riss durch doppelte Knoten bei Z=0
!Vernetzung mit Quadern
!Schätzing 13.1.2022
finish $/clear
*abbr,riss4b,/input,riss4b,txt

!-----Parameter-----------
rad=15e-3   !Radius
hoch=30e-3  !Höhe
strom=1000
!-------------------
/prep7
et,1,mesh200,6      !rechtecke 8 Knoten
et,2,solid231       !Quader 20 Knoten
mp,rsvx,1,1/56e6    !Kupfer

!----Geometrie------
/VIEW,  1, -0.3, -0.9,  0.28
/ANG,   1,   32

!----Geometrie------
cylind,,rad,0,-hoch/2, 90,180      	 !V1
cylind,,rad,0,-hoch/2,180,270      	 !V2

!---------für Ellipse------
cylind,,rad*0.7,0,-hoch/2           	!V3
vlscale,3,,,,2,,,1,1       	!V6 Ellipse

vovlap,all   
vdele,8,,,1
numcmp,volu 	!A1-4
vplot
cylind,,rad,0,-hoch/2,  0, 90      	 !V5	
cylind,,rad,0,-hoch/2,270,360      	 !V6

vglue,all
numcmp,volu	!V1-6

!---Vernetzung -----------
esize,1e-3
!esize,2e-3
mshape,0,2d
mshkey,1
vmesh,all      
!----Spiegeln-----
vsymm,z,all    
eplot

!-------Riss-A5,9,16,21---------------
asel,s,loc,z,0    	!A:12
asel,u,,,5
asel,u,,,9
asel,u,,,16
asel,u,,,21

nsla,s,1
nummrg,node  
allsel

!-----Lasten--Stromfluss in Z-Richtung--
nsel,s,loc,z,hoch/2
cp,1,volt,all
*get,node1,node,,num,min
f,node1,amps,strom 
nsel,s,loc,z,-hoch/2
d,all,volt,0
allsel 

!------Lösung-----
/solu
solve
!------Auswertung-----
/post1
/plopts,minm,0
plns,volt

/eof

*get,spannung,node,node1,volt
widerst=spannung/strom
!0.8051e-6 mit Riss
!0.7578e-6 ohne Riss

/eof

!-----Auswertung auf Pfad------
path,laengs,2,
ppath,1,node,-rad/3,0,-hoch/2
ppath,2,node,-rad/3,0, hoch/2
pdef,pot,volt,
pdef,feldst,ef,sum
plpath,pot
plpath,feldst

path,quer,2,
ppath,1,node,-rad,0,0
ppath,2,node, rad,0,0
pdef,pot,volt,
pdef,feldst,ef,sum
plpath,pot
plpath,feldst

/pbc,path,,1
eplot