!Ermittlung der Potentialverteilung
!eines Zylinders mit Riss
!Riss durch doppelte Knoten bei Z=0
!Vernetzung mit Quadern
!Schätzing 11.1.2022
finish $/clear
*abbr,riss2b,/input,riss2b,txt

!-----Parameter-----------
rad=15e-3   !Radius
hoch=30e-3  !Höhe
strom=1000
!-------------------
/prep7
et,1,solid231       !Quader 20 Knoten
mp,rsvx,1,1/56e6    !Kupfer

!----Geometrie------
/VIEW,  1, -0.3, -0.9,  0.28
/ANG,   1,   32

cylind,,rad,-hoch/2,0,  0, 90
cylind,,rad,-hoch/2,0, 90,180
cylind,,rad,-hoch/2,0,180,270
cylind,,rad,-hoch/2,0,270,360

vglue,all
numcmp,volu   !V1-4
esize,2e-3
vmesh,all

!-----Spiegelung------
vsymm,z,all   !V1-8

!--------Verbunden-(nicht Riss)---------
nsel,s,loc,z,0           
nsel,r,loc,x,-rad/2,rad  
nummrg,node              
allsel

!-----Lasten--Stromfluss in Z-Richtung--
nsel,s,loc,z,hoch/2
cp,1,volt,all
*get,node1,node,,num,min
f,node1,amps,strom 
nsel,s,loc,z,-hoch/2
d,all,volt,0
allsel 

!------Lösung-----
/solu
solve
!------Auswertung-----
/post1
/plopts,minm,0
plns,volt

*get,spannung,node,node1,volt
widerst=spannung/strom
!0.8051e-6 mit Riss
!0.7578e-6 ohne Riss