!Versuch einer Regelung
!Störquelle ist Wärmeeintrag 
!an der oberen Stirnfläche 
!eines zylinderförmigen Stiftes
!Stelleingriff durch Wärmeeintrag
!am oberen Umfang des Stiftes
!mit Regelung

finish  $/clear

*abbr,regelung2,/input,regelung2,txt

!----Parameter------
rad=3e-3   !Radius des Stiftes
hoko=3e-3  !Höhe des Kopfes
howi=6e-3  !Höhe des Widerstandes
hogr=12e-3 !Höhe Grundkörper

tumg=20    !Umgebungstemperatur

/prep7

et,1,plane67,,,1
!----Kupfer----
mp,kxx,1,350
mp,dens,1,8900
mp,c,1,360
!----Eisen----
mp,kxx,2,52
mp,dens,2,7800
mp,c,2,420

!-----Geometrie-----
rectng,0,rad,0,hogr
rectng,0,rad,hogr,hogr+howi
rectng,0,rad,hogr+howi,hogr+howi+hoko
aglue,all
!A1:Grund, A4:Widerstand, A5:Kopf  

!/eof

!----Vernetzung-----
mat,1
esize,1e-3
amesh,5     !Kopf
mat,2
amesh,4     !Widerstand
mat,1
amesh,1     !Grundkörper

!----thermische-Randbedingung---
ic,all,temp,tumg  !Anfangswert
nsel,s,loc,y,0
d,all,temp,tumg
nsel,all
no1=node(rad,hogr+howi,0) !Messpunkt 1
no2=node(rad,hogr,0)      !Messpunkt 2

!----thermische-Last------
!---an der Stirnseite---
pi=4*atan(1)
P_Stirn=3
nsel,s,loc,y,hogr+howi+hoko
sf,all,hflux,P_Stirn/(pi*rad**2)

allsel
!-----Lösung----
/solu
antype,trans

endzeit=30
schritte=15
sw=endzeit/schritte
!Regelziel: Temperaturdifferenz=20
soll=20
P_Folie=1   !Startwert
!----Start-----
time,1e-12
solve

!/eof

*do,i,1,schritte
!--Regelalgorithmus--
diff=temp(no1)-temp(no2)
abw=soll-diff
faktor=0.02
P_Folie=P_Folie+abw*faktor
!---am Umfang (Heizfolie)---
nsel,s,loc,x,rad
nsel,r,loc,y,hogr+howi,hogr+howi+hoko
sf,all,hflux,P_Folie/(2*pi*rad*hoko)
nsel,all
!--------------------------
time,i*sw
solve

*enddo

!-----Auswertung-----
/post1
plns,temp

!----------------------
/post26
nsol,2,no1,temp,,MP1
nsol,3,no2,temp,,MP2
plvar,2,3

diff=temp(no1)-temp(no2)
P_Folie=P_Folie